House of Medakan zMUD Scripts

[Taziar]

Custom Script: Ominas' Diagnose Condition
This script takes the pattern received by the diagnose, examine, or look command and gives the corresponding condition.

Note: shows (Healthy) for equipment in excellent condition when examined...

Example: diag Taziar
Taziar has a few scratches. (Scratched)

Code: Select all

#CLASS {DiagnoseCondition}
#TRIGGER {^(*) is in excellent condition.$} {#SUB {%1 is in excellent condition. ~(Healthy~)}}
#TRIGGER {^(*) has a few scratches.$} {#SUB {%1 has a few scratches. ~(Scratched~)}}
#TRIGGER {^(*) has some small wounds and bruises.} {#SUB {%1 has some small wounds and bruises. ~(Hurt~)}}
#TRIGGER {^(*) has quite a few wounds.} {#SUB {%1 has quite a few wounds. ~(Wounded~)}}
#TRIGGER {^(*) has some big nasty wounds and scratches.} {#SUB {%1 has some big nasty wounds and scratches. ~(Battered~)}}
#TRIGGER {^(*) looks pretty hurt.} {#SUB {%1  looks pretty hurt. ~(Beaten~)}}
#TRIGGER {^(*) is in awful condition.} {#SUB {%1 is in awful condition. ~(Critical~)}}
#TRIGGER {^(*) is lying here, stunned.} {#SUB {%1 is lying here, stunned. ~(Stunned!~)}}
#TRIGGER {^(*) is bleeding awfully from big wounds.} {#SUB {%1 is bleeding awfully from big wounds. ~(INCAPACITATED!!~)}}
#CLASS 0

Back to: Table of Contents

[Taziar]

Custom Script: Mangler's Alt Tracker
Original post on wotmod.org forums is here

Alt Tracker stores names grouped by main characters, all alts entered are associated with one main character.
You can use the commands below to see a list of all character names you have stored.
Anytime you Type whois <name> and you have that name saved it will automatically show you either associated main character or all of their alts.

Type helpAltTracker to view help file in client.

Type altAdd <mainName> <altName> to add an alt name to a main character name file.
-Example: Type altAdd Austin Kirtha to add Kirtha to Austin's alt file.

Type altNames for a list of all current characters and alts on file.

Type whoi <name> or whois <name> if that character has an alt you know it will display it.

Type altRemove <name> to remove a character name from the file.

Code: Select all

#CLASS {AltTracker}
#ALIAS helpAltTracker {
	#SHOW {""}
	#SHOW {""}
	#SAY {"-----Alt Tracker Help File-----"}
	#SHOW {""}
	#SHOW {"Type altAdd <mainName> <altName> to add an alt name to character name file."}
	#SHOW {"Example: Type altAdd Austin Kirtha to add Kirtha to Austin's alt file."}
	#SHOW {""}
	#SHOW {"Type altNames for a list of all current characters and alts on file."}
	#SHOW {""}
	#SHOW {"Type whois <name> as normal, if that character has an alt you know it will display it."}
	#SHOW {""}
	#SHOW {"Type altRemove <name> to remove a character name from the file."}
	#SHOW {""}
	}
#ALIAS altAdd {
	#IF (%ismember(%proper(%1),@altCharName)) {#SHOW {""}} {
			#ADDITEM altCharName %proper(%1)
			#VAR %concat("alt",%proper(%1)) {} {_nodef} "AltTracker|AltFiles"
			#SHOW {""}
			#SAY {%proper(%1) was added to the main character file.}
			}
	#IF (%ismember(%proper(%2),@altCharAlt)) {
		#SAY {%proper(%2) is already a listed alt of a main character.}
		} {#IF (%len(%2) > 1) {#ADDITEM altCharAlt %proper(%2)}
			#IF (%len(%2) > 1) {#ADDITEM %concat("alt",%proper(%1)) %proper(%2)}
			#IF (%len(%2) > 1) {#SAY {%proper(%2) is now an alt of %proper(%1).}}
			}
	}
#ALIAS altNames {
	#SHOW {""}
	#SHOW {""}
	#FORALL @altCharName {
		#VAR altNameLoop {%concat("@","alt",%i)}
		#SHOW {%i "--->" @altNameLoop}
		}
	}
#ALIAS altRemove {
	#SHOW {""}
	#IF (%ismember(%proper(%1),@altCharName)) {
		#DELITEM altCharName %proper(%1)
		#UNVAR %concat("alt",%proper(%1)) "AltTracker|AltFiles"
		#SAY {%proper(%1) was removed from the main character file.}
		}
	#IF (%ismember(%proper(%1),@altCharAlt)) {
		#DELITEM altCharAlt %proper(%1)
		#SAY {%proper(%1) was removed from the alt character file.}
		}
	#FORALL @altCharName {
		#DELITEM %concat("alt",%i) %proper(%1)
		#DELITEM %concat("alt",%i) %null
		}
	}
#ALIAS altWhois {
	#IF (%ismember(%proper(@altNameWhois),@altCharName)) {
		#VAR altNameWho %concat("@","alt",@altNameWhois)
		#ALARM +.5 {
			#SHOW {""}
			#SAY {Known alts: %expandlist(@altNameWho," ")}
			}
		}
	#IF (%ismember(%proper(@altNameWhois),@altCharAlt)) {
		altWhoMain
		}
	}
#ALIAS altWhoMain {
	#FORALL @altCharName {
		#ADDITEM altNameFind {%concat("@",alt,%i)}
		#VAR altNameFindLiteral {%concat(~"~@,alt,%i~")}
		#IF (%ismember(%proper(@altNameWhois),@altNameFind)) {
			#ALARM +.5 {
				#SHOW {""}
				#SAY {%proper(@altNameWhois) is an alt of %remove("@alt",@altNameFindLiteral).}
				#VAR altNameFind {}
				}
			#ABORT 1
			}
		#DELITEM altNameFind {%concat("@","alt",%i)}
		}
	}
#ONINPUT {^whoi &%waltNameWhois$} {altWhois}
#ONINPUT {^whois &%waltNameWhois$} {altWhois}
#VAR altNameLoop {}
#VAR altNameWho {}
#VAR altNameWhois {}
#VAR altNameFind {}
#VAR altNameFindLiteral {}
#CLASS 0
#CLASS {AltTracker|AltFiles}
#VAR altCharName {}
#VAR altCharAlt {}
#CLASS 0

Back to: Table of Contents

[Taziar]

Custom Script: Deedlit's Status Bar
Original post on wotmod.org forums is here

Simply type sc, sco, scor, or score to activate (and should never false trigger because it turns itself off and only triggers on numbers).

Code: Select all

#CLASS {DeedlitBar}
#VAR deedsHP {}
#VAR deedsSP {}
#VAR deedsMV {}
#VAR deedsMaxHP {}
#VAR deedsMaxSP {}
#VAR deedsMaxMV {}
#ONINPUT {^(sc|sco|scor|score)$} {
	#T+ {deedsTrigger}
	#T+ {deedsTrigger2}
	#T+ {deedsTrigger3}
	} "" {regex}
#TRIGGER "deedsTrigger" {You have &%ddeedsHP~(&%ddeedsMaxHP~) hit and &%ddeedsMV~(&%ddeedsMaxMV~) movement points.$} {} "" {case}
#TRIGGER "deedsTrigger2" {You have &%ddeedsHP~(&%ddeedsMaxHP~) hit, &%ddeedsSP~(&%ddeedsMaxSP~) saidar and &%ddeedsMV~(&%ddeedsMaxMV~) movement points.$} {} "" {case}
#TRIGGER "deedsTrigger3" {^This ranks you as} {
	#T- {deedsTrigger}
	#T- {deedsTrigger2}
	#T- {deedsTrigger3}
	} "" {case}
#STATUS {<font fixedsys 11><color white black> HP: @deedsHP~(@deedsMaxHP~) </color></font>} "" "DeedlitBarHitPoints"
#STATUS {<font fixedsys 11><color white black> SP: @deedsSP~(@deedsMaxSP~) </color></font>} "" "DeedlitBarSpellPoints"
#STATUS {<font fixedsys 11><color white black> MV: @deedsMV~(@deedsMaxMV~) </color></font>} "" "DeedlitBarMovePoints"
#STATUS {<font fixedsys 11><color black black></color></font>} "" "DeedlitBarEnd"
#CLASS 0

Back to: Table of Contents

[Taziar]

Type helpColorWheel to view help file in client.



Example: showColor6



Direct download link: ColorWheelHoM.txt

Active Triggers: 0/0

Code: Select all

#CLASS {ColorWheel}
#ALIAS helpColorWheel {
	#PRIORITY {
		#SAY {%crlf " -----Color Wheel Help File-----"}
		#SAY {"        [Updated: 3/9/2018]"}
		#SHOW {" Shows 140 supported color names on a black background."}
		#SHOW {" Note: black color name is shown as white due to background conflict."}
		#SHOW {""}
		#SHOW {" Multiple column options for varying screen sizes:"}
		#SHOW {""}
		#SHOW {" Type showColor3 to view color list in 3 columns."}
		#SHOW {" Note: 51 characters across with 46 total lines."}
		#SHOW {""}
		#SHOW {" Type showColor4 to view color list in 4 columns."}
		#SHOW {" Note: 69 characters across with 35 total lines."}
		#SHOW {""}
		#SHOW {" Type showColor5 to view color list in 5 columns."}
		#SHOW {" Note: 81 characters across with 28 total lines."}
		#SHOW {""}
		#SHOW {" Type showColor6 to view color list in 6 columns."}
		#SHOW {" Note: 96 characters across with 24 total lines."}
		#SHOW {""}
		}
	}
#ALIAS showColor3 {
	#SHOW {""}
	#SHOW {@colorMXP3(aliceblue,ghostwhite,navajowhite)}
	#SHOW {@colorMXP3(antiquewhite,gold,navy)}
	#SHOW {@colorMXP3(aqua,goldenrod,oldlace)}
	#SHOW {@colorMXP3(aquamarine,gray,olive)}
	#SHOW {@colorMXP3(azure,green,olivedrab)}
	#SHOW {@colorMXP3(beige,greenyellow,orange)}
	#SHOW {@colorMXP3(bisque,honeydew,orangered)}
	#SHOW {@colorMXP3(black,hotpink,orchid)}
	#SHOW {@colorMXP3(blanchedalmond,indianred,palegoldenrod)}
	#SHOW {@colorMXP3(blue,indigo,palegreen)}
	#SHOW {@colorMXP3(blueviolet,ivory,paleturquoise)}
	#SHOW {@colorMXP3(brown,khaki,palevioletred)}
	#SHOW {@colorMXP3(burlywood,lavender,papayawhip)}
	#SHOW {@colorMXP3(cadetblue,lavenderblush,peachpuff)}
	#SHOW {@colorMXP3(chartreuse,lawngreen,peru)}
	#SHOW {@colorMXP3(chocolate,lemonchiffon,pink)}
	#SHOW {@colorMXP3(coral,lightblue,plum)}
	#SHOW {@colorMXP3(cornflowerblue,lightcoral,powderblue)}
	#SHOW {@colorMXP3(cornsilk,lightcyan,purple)}
	#SHOW {@colorMXP3(crimson,lightgoldenrodyellow,red)}
	#SHOW {@colorMXP3(cyan,lightgreen,rosybrown)}
	#SHOW {@colorMXP3(darkblue,lightgrey,royalblue)}
	#SHOW {@colorMXP3(darkcyan,lightpink,saddlebrown)}
	#SHOW {@colorMXP3(darkgoldenrod,lightsalmon,salmon)}
	#SHOW {@colorMXP3(darkgray,lightseagreen,sandybrown)}
	#SHOW {@colorMXP3(darkgreen,lightskyblue,seagreen)}
	#SHOW {@colorMXP3(darkkhaki,lightslategray,seashell)}
	#SHOW {@colorMXP3(darkmagenta,lightsteelblue,sienna)}
	#SHOW {@colorMXP3(darkolivegreen,lightyellow,silver)}
	#SHOW {@colorMXP3(darkorange,lime,skyblue)}
	#SHOW {@colorMXP3(darkorchid,limegreen,slateblue)}
	#SHOW {@colorMXP3(darkred,linen,slategray)}
	#SHOW {@colorMXP3(darksalmon,magenta,snow)}
	#SHOW {@colorMXP3(darkseagreen,maroon,springgreen)}
	#SHOW {@colorMXP3(darkslateblue,mediumaquamarine,steelblue)}
	#SHOW {@colorMXP3(darkslategray,mediumblue,tan)}
	#SHOW {@colorMXP3(darkturquoise,mediumorchid,teal)}
	#SHOW {@colorMXP3(darkviolet,mediumpurple,thistle)}
	#SHOW {@colorMXP3(deeppink,mediumseagreen,tomato)}
	#SHOW {@colorMXP3(deepskyblue,mediumslateblue,turquoise)}
	#SHOW {@colorMXP3(dimgray,mediumspringgreen,violet)}
	#SHOW {@colorMXP3(dodgerblue,mediumturquoise,wheat)}
	#SHOW {@colorMXP3(firebrick,mediumvioletred,white)}
	#SHOW {@colorMXP3(floralwhite,midnightblue,whitesmoke)}
	#SHOW {@colorMXP3(forestgreen,mintcream,yellow)}
	#SHOW {@colorMXP3(fuchsia,mistyrose,yellowgreen)}
	#SHOW {@colorMXP3(gainsboro,moccasin,black)}
	#SHOW {""}
	}
#ALIAS showColor4 {
	#SHOW {""}
	#SHOW {@colorMXP4(aliceblue,darkslategray,lightsalmon,palevioletred)}
	#SHOW {@colorMXP4(antiquewhite,darkturquoise,lightseagreen,papayawhip)}
	#SHOW {@colorMXP4(aqua,darkviolet,lightskyblue,peachpuff)}
	#SHOW {@colorMXP4(aquamarine,deeppink,lightslategray,peru)}
	#SHOW {@colorMXP4(azure,deepskyblue,lightsteelblue,pink)}
	#SHOW {@colorMXP4(beige,dimgray,lightyellow,plum)}
	#SHOW {@colorMXP4(bisque,dodgerblue,lime,powderblue)}
	#SHOW {@colorMXP4(black,firebrick,limegreen,purple)}
	#SHOW {@colorMXP4(blanchedalmond,floralwhite,linen,red)}
	#SHOW {@colorMXP4(blue,forestgreen,magenta,rosybrown)}
	#SHOW {@colorMXP4(blueviolet,fuchsia,maroon,royalblue)}
	#SHOW {@colorMXP4(brown,gainsboro,mediumaquamarine,saddlebrown)}
	#SHOW {@colorMXP4(burlywood,ghostwhite,mediumblue,salmon)}
	#SHOW {@colorMXP4(cadetblue,gold,mediumorchid,sandybrown)}
	#SHOW {@colorMXP4(chartreuse,goldenrod,mediumpurple,seagreen)}
	#SHOW {@colorMXP4(chocolate,gray,mediumseagreen,seashell)}
	#SHOW {@colorMXP4(coral,green,mediumslateblue,sienna)}
	#SHOW {@colorMXP4(cornflowerblue,greenyellow,mediumspringgreen,silver)}
	#SHOW {@colorMXP4(cornsilk,honeydew,mediumturquoise,skyblue)}
	#SHOW {@colorMXP4(crimson,hotpink,mediumvioletred,slateblue)}
	#SHOW {@colorMXP4(cyan,indianred,midnightblue,slategray)}
	#SHOW {@colorMXP4(darkblue,indigo,mintcream,snow)}
	#SHOW {@colorMXP4(darkcyan,ivory,mistyrose,springgreen)}
	#SHOW {@colorMXP4(darkgoldenrod,khaki,moccasin,steelblue)}
	#SHOW {@colorMXP4(darkgray,lavender,navajowhite,tan)}
	#SHOW {@colorMXP4(darkgreen,lavenderblush,navy,teal)}
	#SHOW {@colorMXP4(darkkhaki,lawngreen,oldlace,thistle)}
	#SHOW {@colorMXP4(darkmagenta,lemonchiffon,olive,tomato)}
	#SHOW {@colorMXP4(darkolivegreen,lightblue,olivedrab,turquoise)}
	#SHOW {@colorMXP4(darkorange,lightcoral,orange,violet)}
	#SHOW {@colorMXP4(darkorchid,lightcyan,orangered,wheat)}
	#SHOW {@colorMXP4(darkred,lightgoldenrodyellow,orchid,white)}
	#SHOW {@colorMXP4(darksalmon,lightgreen,palegoldenrod,whitesmoke)}
	#SHOW {@colorMXP4(darkseagreen,lightgrey,palegreen,yellow)}
	#SHOW {@colorMXP4(darkslateblue,lightpink,paleturquoise,yellowgreen)}
	#SHOW {""}
	}
#ALIAS showColor5 {
	#SHOW {""}
	#SHOW {@colorMXP5(aliceblue,darkolivegreen,indigo,mediumpurple,purple)}
	#SHOW {@colorMXP5(antiquewhite,darkorange,ivory,mediumseagreen,red)}
	#SHOW {@colorMXP5(aqua,darkorchid,khaki,mediumslateblue,rosybrown)}
	#SHOW {@colorMXP5(aquamarine,darkred,lavender,mediumspringgreen,royalblue)}
	#SHOW {@colorMXP5(azure,darksalmon,lavenderblush,mediumturquoise,saddlebrown)}
	#SHOW {@colorMXP5(beige,darkseagreen,lawngreen,mediumvioletred,salmon)}
	#SHOW {@colorMXP5(bisque,darkslateblue,lemonchiffon,midnightblue,sandybrown)}
	#SHOW {@colorMXP5(black,darkslategray,lightblue,mintcream,seagreen)}
	#SHOW {@colorMXP5(blanchedalmond,darkturquoise,lightcoral,mistyrose,seashell)}
	#SHOW {@colorMXP5(blue,darkviolet,lightcyan,moccasin,sienna)}
	#SHOW {@colorMXP5(blueviolet,deeppink,lightgoldenrodyellow,navajowhite,silver)}
	#SHOW {@colorMXP5(brown,deepskyblue,lightgreen,navy,skyblue)}
	#SHOW {@colorMXP5(burlywood,dimgray,lightgrey,oldlace,slateblue)}
	#SHOW {@colorMXP5(cadetblue,dodgerblue,lightpink,olive,slategray)}
	#SHOW {@colorMXP5(chartreuse,firebrick,lightsalmon,olivedrab,snow)}
	#SHOW {@colorMXP5(chocolate,floralwhite,lightseagreen,orange,springgreen)}
	#SHOW {@colorMXP5(coral,forestgreen,lightskyblue,orangered,steelblue)}
	#SHOW {@colorMXP5(cornflowerblue,fuchsia,lightslategray,orchid,tan)}
	#SHOW {@colorMXP5(cornsilk,gainsboro,lightsteelblue,palegoldenrod,teal)}
	#SHOW {@colorMXP5(crimson,ghostwhite,lightyellow,palegreen,thistle)}
	#SHOW {@colorMXP5(cyan,gold,lime,paleturquoise,tomato)}
	#SHOW {@colorMXP5(darkblue,goldenrod,limegreen,palevioletred,turquoise)}
	#SHOW {@colorMXP5(darkcyan,gray,linen,papayawhip,violet)}
	#SHOW {@colorMXP5(darkgoldenrod,green,magenta,peachpuff,wheat)}
	#SHOW {@colorMXP5(darkgray,greenyellow,maroon,peru,white)}
	#SHOW {@colorMXP5(darkgreen,honeydew,mediumaquamarine,pink,whitesmoke)}
	#SHOW {@colorMXP5(darkkhaki,hotpink,mediumblue,plum,yellow)}
	#SHOW {@colorMXP5(darkmagenta,indianred,mediumorchid,powderblue,yellowgreen)}
	#SHOW {""}
	}
#ALIAS showColor6 {
	#SHOW {""}
	#SHOW {@colorMXP6(aliceblue,darkgray,gold,lightskyblue,oldlace,seashell)}
	#SHOW {@colorMXP6(antiquewhite,darkgreen,goldenrod,lightslategray,olive,sienna)}
	#SHOW {@colorMXP6(aqua,darkkhaki,gray,lightsteelblue,olivedrab,silver)}
	#SHOW {@colorMXP6(aquamarine,darkmagenta,green,lightyellow,orange,skyblue)}
	#SHOW {@colorMXP6(azure,darkolivegreen,greenyellow,lime,orangered,slateblue)}
	#SHOW {@colorMXP6(beige,darkorange,honeydew,limegreen,orchid,slategray)}
	#SHOW {@colorMXP6(bisque,darkorchid,hotpink,linen,palegoldenrod,snow)}
	#SHOW {@colorMXP6(black,darkred,indianred,magenta,palegreen,springgreen)}
	#SHOW {@colorMXP6(blanchedalmond,darksalmon,indigo,maroon,paleturquoise,steelblue)}
	#SHOW {@colorMXP6(blue,darkseagreen,ivory,mediumaquamarine,palevioletred,tan)}
	#SHOW {@colorMXP6(blueviolet,darkslateblue,khaki,mediumblue,papayawhip,teal)}
	#SHOW {@colorMXP6(brown,darkslategray,lavender,mediumorchid,peachpuff,thistle)}
	#SHOW {@colorMXP6(burlywood,darkturquoise,lavenderblush,mediumpurple,peru,tomato)}
	#SHOW {@colorMXP6(cadetblue,darkviolet,lawngreen,mediumseagreen,pink,turquoise)}
	#SHOW {@colorMXP6(chartreuse,deeppink,lemonchiffon,mediumslateblue,plum,violet)}
	#SHOW {@colorMXP6(chocolate,deepskyblue,lightblue,mediumspringgreen,powderblue,wheat)}
	#SHOW {@colorMXP6(coral,dimgray,lightcoral,mediumturquoise,purple,white)}
	#SHOW {@colorMXP6(cornflowerblue,dodgerblue,lightcyan,mediumvioletred,red,whitesmoke)}
	#SHOW {@colorMXP6(cornsilk,firebrick,lightgoldenrodyellow,midnightblue,rosybrown,yellow)}
	#SHOW {@colorMXP6(crimson,floralwhite,lightgreen,mintcream,royalblue,yellowgreen)}
	#SHOW {@colorMXP6(cyan,forestgreen,lightgrey,mistyrose,saddlebrown,black)}
	#SHOW {@colorMXP6(darkblue,fuchsia,lightpink,moccasin,salmon,black)}
	#SHOW {@colorMXP6(darkcyan,gainsboro,lightsalmon,navajowhite,sandybrown,black)}
	#SHOW {@colorMXP6(darkgoldenrod,ghostwhite,lightseagreen,navy,seagreen,black)}
	#SHOW {""}
	}
#FUNCTION colorSpace {%repeat(" ",%eval(%2 - %len(%1)))</color>}
#FUNCTION colorMXP3 {<color %if(%1=black,white,%1) black> %1@colorSpace(%1,15)<color %2 black>%2@colorSpace(%2,21)<color %3 black>%3@colorSpace(%3,14)}
#FUNCTION colorMXP4 {<color %if(%1=black,white,%1) black> %1@colorSpace(%1,15)<color %2 black>%2@colorSpace(%2,21)<color %3 black>%3@colorSpace(%3,18)<color %4 black>%4@colorSpace(%4,14)}
#FUNCTION colorMXP5 {<color %if(%1=black,white,%1) black> %1@colorSpace(%1,15)<color %2 black>%2@colorSpace(%2,15)<color %3 black>%3@colorSpace(%3,21)<color %4 black>%4@colorSpace(%4,18)<color %5 black>%5@colorSpace(%5,12)}
#FUNCTION colorMXP6 {<color %if(%1=black,white,%1) black> %1@colorSpace(%1,15)<color %2 black>%2@colorSpace(%2,15)<color %3 black>%3@colorSpace(%3,21)<color %4 black>%4@colorSpace(%4,18)<color %5 black>%5@colorSpace(%5,14)<color %6 black>%6@colorSpace(%6,12)}
#CLASS 0

[Taziar]

Type helpTracking to view help file in client.



Type helpTrackColor to view tracking color specific help file in client.



Type helpTrackCase to view case specific help file in client.



Direct download link: TrackingHoM.txt

Active Triggers: 1/8
Input Triggers: 1

Code: Select all

#CLASS {Tracking}
#ALIAS helpTracking {
	#PRIORITY {
		#SAY {%crlf "-----Tracking Help File-----"}
		#SAY {"     [Updated: 7/19/2018]"}
		#SHOW {" Places directional characters around direction word to aid in quick visualization of tracks."}
		#SHOW {""}
		#SHOW {" Colors specific text in both auto track and manual track lines."}
		#SHOW {"  Type helpTrackColor for track color specific commands list."}
		#SHOW {"   Track color help file shows current color selections."}
		#SHOW {""}
		#SHOW {" Changes the upper and lower case of specific text in track lines."}
		#SHOW {"  Type helpTrackCase for caps specific commands list."}
		#SHOW {"   Track case help file shows current case selections."}
		#SHOW {""}
		}
	}
#ALIAS helpTrackColor {
	#PRIORITY {
		#SAY {%crlf" -----Track Color Help File-----"}
		#SHOW {" Auto track example: There are some "@trackMXPcolorBloody(@trackColorBloody,bloody traces,@trackColorHuman,human,@trackColorCharacter,>>,@trackColorDirection,east)}
		#SHOW {""}
		#SHOW {" Manual track example: Some obvious recent tracks of "@trackMXPcolorType(@trackColorPlayer,%char,@trackColorCharacter,<<,@trackColorDirection,west)}
		#SHOW {""}
		#SHOW {" Type trackColor <type> <color> [bcolor] to set color for specified track type."}
		#SHOW {"  Note: trackColor entered without parameters will display list of available types."}
		#SHOW {""}
		#SHOW {" Available types:"}
		#SHOW {"   "@trackMXPhelp(@trackColorBloody,"bloody      (text color for bloody traces)")}
		#SHOW {"   "@trackMXPhelp(@trackColorCharacter,"character   (text color of symbols that encompass track direction)")}
		#SHOW {"   "@trackMXPhelp(@trackColorDirection,"direction   (text color of the cardinal directions {north|south|east|west|up|down})")}
		#SHOW {"   "@trackMXPhelp(@trackColorDreadlord,"dreadlord   (text color when tracking a dreadlord)")}
		#SHOW {"   "@trackMXPhelp(@trackColorHuman,"human       (text color when tracking a human)")}
		#SHOW {"   "@trackMXPhelp(@trackColorMount,"mount       (text color when tracking a ridden mount)")}
		#SHOW {"   "@trackMXPhelp(@trackColorMyrddraal,"myrddraal   (text color when tracking a myrddraal)")}
		#SHOW {"   "@trackMXPhelp(@trackColorPlayer,"player      (text color when tracking player names)")}
		#SHOW {"   "@trackMXPhelp(@trackColorTrolloc,"trolloc     (text color when tracking a trolloc)")}
		#SHOW {""}
		#SHOW {" Note: optional background color syntax for above commands trackColor <type> <color> <bcolor>"}
		#SHOW {"  Example: trackColor dreadlord firebrick black (for firebrick on a black background)"}
		#SHOW {""}
		}
	}
#ALIAS helpTrackCase {
	#PRIORITY {
		#SAY {%crlf "-----Track Case Help File-----"}
		#SHOW {"Auto track example: There are some "@trackMXPcolorBloody(@trackColorBloody,BLOODY TRACES,@trackColorHuman,HUMAN,@trackColorCharacter,>>,@trackColorDirection,EAST)}
		#SHOW {""}
		#SHOW {"Manual track example: Some obvious recent tracks of "@trackMXPcolorType(@trackColorPlayer,%upper(%char),@trackColorCharacter,<<,@trackColorDirection,WEST)}
		#SHOW {""}
		#SHOW {" Type trackCase <type> to toggle the upper and lower cases for track types."}
		#SHOW {" Note: trackCase entered without a type will display list of available types."}
		#SHOW {""}
		#SHOW {" Available types:"}
		#SHOW {"  "%if(@trackCaseBloody,BLOODY,bloody)"    (toggle the upper and lower case of bloody traces)"}
		#SHOW {"  "%if(@trackCaseDirection,DIRECTION,direction)" (toggle the upper and lower case of the cardinal directions)"}
		#SHOW {"  "%if(@trackCaseDreadlord,DREADLORD,dreadlord)" (toggle the upper and lower case of dreadlord)"}
		#SHOW {"  "%if(@trackCaseHuman,HUMAN,human)"     (toggle the upper and lower case of human)"}
		#SHOW {"  "%if(@trackCaseMount,MOUNT,mount)"     (toggle the upper and lower case of ridden mount)"}
		#SHOW {"  "%if(@trackCaseMyrddraal,MYRDDRAAL,myrddraal)" (toggle the upper and lower case of myrddraal)"}
		#SHOW {"  "%if(@trackCasePlayer,PLAYER,player)"    (toggle the upper and proper case of a players name)"}
		#SHOW {"  "%if(@trackCaseTrolloc,TROLLOC,trolloc)"   (toggle the upper and lower case of trolloc)"}
		#SHOW {""}
		}
	}
#ALIAS trackColor {
	#SHOW {""}
	#IF (%null(%1)) {
		#SAY {" Usage: trackColor <type> <color> [bcolor] [background color optional]"}
		#SHOW {""}
		#SHOW {"Available types:"}
		#SHOW {"   "@trackMXPhelp(@trackColorBloody),%if(@trackCaseBloody,BLOODY,bloody))}
		#SHOW {"   "@trackMXPhelp(@trackColorCharacter),"Character (<< ^^ >> vv ++ --)")}
		#SHOW {"   "@trackMXPhelp(@trackColorDirection),%if(@trackCaseDirection,DIRECTION,direction))}
		#SHOW {"   "@trackMXPhelp(@trackColorDreadlord),%if(@trackCaseDreadlord,DREADLORD,dreadlord))}
		#SHOW {"   "@trackMXPhelp(@trackColorHuman),%if(@trackCaseHuman,HUMAN,human))}
		#SHOW {"   "@trackMXPhelp(@trackColorMount),%if(@trackCaseMount,MOUNT,mount))}
		#SHOW {"   "@trackMXPhelp(@trackColorMyrddraal),%if(@trackCaseMyrddraal,MYRDDRAAL,myrddraal))}
		#SHOW {"   "@trackMXPhelp(@trackColorPlayer),%if(@trackCasePlayer,PLAYER,player))}
		#SHOW {"   "@trackMXPhelp(@trackColorTrolloc),%if(@trackCaseTrolloc,TROLLOC,trolloc))}
		#SHOW {""}
		} {
		#IF (%class(%concat("trackColor",%1))=-1) {
			#SAY {%1 is an invalid type selection...}
			} {
			#IF (%null(%2)) {
				#SAY {What color is that?...}
				} {
				#IF (%colorname(%2)=536870911 AND %color(%2)=0) {
					#VAR %concat("trackColor",%1) {}
					#SAY {" "%2 is an invalid color. %concat("trackColor",%proper(%1)) variable cleared.}
					} {
					#IF (%null(%3)) {
						#VAR %concat("trackColor",%1) {%2}
						#SHOW {%proper(%1) color set: @trackMXPcolor(%2)}
						} {
						#IF (%colorname(%3)=536870911 AND %color(%3)=0) {
							#VAR %concat("trackColor",%1) {}
							#SAY {" "%3 is an invalid color. %concat("trackColor",%proper(%1)) variable cleared.}
							} {
							#VAR %concat("trackColor",%1) {%2 %3}
							#SHOW {%proper(%1) color set: @trackMXPcolor(%2 %3)}
							}
						}
					}
				}
			}
		}
	}
#ALIAS trackCase {
	#IF (%null(%1)) {
		#SAY {" Usage: trackCase <type>"}
		#SHOW {""}
		#SHOW {"  Available types:"}
		#SHOW {"   "@trackMXPhelp(@trackColorBloody),%if(@trackCaseBloody,BLOODY,bloody))}
		#SHOW {"   "@trackMXPhelp(@trackColorDirection),%if(@trackCaseDirection,DIRECTION,direction))}
		#SHOW {"   "@trackMXPhelp(@trackColorDreadlord),%if(@trackCaseDreadlord,DREADLORD,dreadlord))}
		#SHOW {"   "@trackMXPhelp(@trackColorHuman),%if(@trackCaseHuman,HUMAN,human))}
		#SHOW {"   "@trackMXPhelp(@trackColorMount),%if(@trackCaseMount,MOUNT,mount))}
		#SHOW {"   "@trackMXPhelp(@trackColorMyrddraal),%if(@trackCaseMyrddraal,MYRDDRAAL,myrddraal))}
		#SHOW {"   "@trackMXPhelp(@trackColorPlayer),%if(@trackCasePlayer,PLAYER,player))}
		#SHOW {"   "@trackMXPhelp(@trackColorTrolloc),%if(@trackCaseTrolloc,TROLLOC,trolloc))}
		#SHOW {""}
		} {
		#IF (%class(%concat("trackCase",%1))=-1) {
			#SAY {%-1 is an invalid type selection...}
			} {
			#IF (%eval(%concat("@","trackCase",%1))) {
				#VAR %concat("@","trackCase",%1) {0} {_nodef} "Tracking"
				} {
				#VAR %concat("@","trackCase",%1) {1} {_nodef} "Tracking"
				}
			#IF (%lower(%1)="bloody") {
				#IF (@trackCaseBloody) {
					#SAY {BLOODY TRACES are now upper case.}
					} {
					#SAY {bloody traces are now lower case.}
					}
				} {
				#IF (%lower(%1)="direction") {
					#IF (@trackCaseDirection) {
						#SAY {NORTH|EAST|SOUTH|WEST|UP|DOWN are now upper case.}
						} {
						#SAY {north|east|south|west|up|down are now lower case.}
						}
					} {
					#IF (%lower(%1)="mount") {
						#IF (@trackCaseMount) {
							#SAY {RIDDEN MOUNT is now upper case.}
							} {
							#SAY {ridden mount is now lower case.}
							}
						} {
						#IF (%lower(%1)="player") {
							#IF (@trackCasePlayer) {
								#SAY {PLAYER NAME is now upper case.}
								} {
								#SAY {Player Name is now proper case.}
								}
							} {
							#IF (%eval(%concat("@","trackCase",%1))) {
								#SAY {%upper(%1) is now upper case.}
								} {
								#SAY {%lower(%1) is now lower case.}
								}
							}
						}
					}
				}
			}
		}
	}
#FUNCTION trackMXPcolor {<color %1>%1</color>}
#FUNCTION trackMXPcolorBloody {<color %1>%2</color> of a <color %3>%4</color> leaving <color %5>%6</color><color %7>%8</color><color %5>%6</color>}
#FUNCTION trackMXPcolorRidden {<color %1>%2</color> "(ridden)" leaving <color %3>%4</color><color %5>%6</color><color %3>%4</color>}
#FUNCTION trackMXPcolorType {<color %1>%2</color> leaving <color %3>%4</color><color %5>%6</color><color %3>%4</color>}
#FUNCTION trackMXPhelp {<color %1>%2</color>}
#VAR trackBloodyList {dreadlord|human|myrddraal|trolloc}
#VAR trackBloodySub {}
#VAR trackCaseBloody {0}
#VAR trackCaseDirection {1}
#VAR trackCaseDreadlord {0}
#VAR trackCaseHuman {0}
#VAR trackCaseMount {0}
#VAR trackCaseMyrddraal {0}
#VAR trackCasePlayer {0}
#VAR trackCaseTrolloc {0}
#VAR trackCharacterDirectional {}
#VAR trackCharacterDown {~"--~"}
#VAR trackCharacterEast {~">>~"}
#VAR trackCharacterNorth {~"^^~"}
#VAR trackCharacterSouth {~"vv~"}
#VAR trackCharacterUp {~"++~"}
#VAR trackCharacterWest {~"<<~"}
#VAR trackColorBloody {red}
#VAR trackColorCharacter {darkorchid}
#VAR trackColorDirection {steelblue}
#VAR trackColorDreadlord {firebrick}
#VAR trackColorHuman {steelblue}
#VAR trackColorMount {blue}
#VAR trackColorMyrddraal {firebrick}
#VAR trackColorPlayer {firebrick}
#VAR trackColorTracks {}
#VAR trackColorTrolloc {red}
#VAR trackColorType {}
#VAR trackDirectionSub {}
#VAR trackNameSub {}
#VAR trackPlayerList {Dreadlord|Human|Myrddraal|Trolloc}
#VAR trackPlayerSub {}
#VAR trackPromptCount {0}
#VAR trackTracesSub {}
#VAR trackTypeList {dreadlord|human|myrddraal|ridden mount|trolloc}
#VAR trackTypeSub {}
#TRIGGER "trackExitsTrigger" {^~[ obvious exits: *~]$} {
	#T+ {trackAutoTrigger}
	#T+ {trackAutoBloodyTrigger}
	#T+ {trackAutoPromptTrigger}
	} "" {case}
#TRIGGER "trackAutoPromptTrigger" {{*|o} * >} {
	#T- {trackAutoPromptTrigger}
	#T- {trackAutoTrigger}
	#T- {trackAutoBloodyTrigger}
	} "" {case|disable|nocr|prompt}
#TRIGGER "trackAutoTrigger" {^(There are some tracks of a) ({@trackTypeList}) leaving (%w).$} {
	#PRIORITY {
		#IF (%2="ridden mount") {
			#IF (@trackCaseMount) {
				#VAR trackTypeSub {RIDDEN MOUNT}
				} {
				#VAR trackTypeSub {ridden mount}
				}
			#VAR trackColorType {@trackColorMount}
			} {
			#IF (%eval(%concat("@trackCase",%2))) {
				#VAR trackTypeSub {%upper(%2)}
				} {
				#VAR trackTypeSub {%2}
				}
			#IF (%ismember(%2,@trackTypeList)) {
				#VAR trackColorType {%eval(%concat("@trackColor",%2))}
				} {
				#VAR trackColorType {}
				}
			}
		#IF (@trackCaseDirection) {
			#VAR trackDirectionSub {%upper(%3)}
			} {
			#VAR trackDirectionSub {%3}
			}
		#VAR trackCharacterDirectional {%eval(%concat("@trackCharacter",%3))}
		#SUB {%1 @trackMXPcolorType(@trackColorType,@trackTypeSub,@trackColorCharacter,@trackCharacterDirectional,@trackColorDirection,@trackDirectionSub)}
		}
	} "" {case|disable}
#TRIGGER "trackAutoBloodyTrigger" {^(There are some) bloody traces of a ({@trackBloodyList}) leaving (%w).$} {
	#PRIORITY {
		#IF (@trackCaseBloody) {
			#VAR trackTracesSub {BLOODY TRACES}
			} {
			#VAR trackTracesSub {bloody traces}
			}
		#IF (%eval(%concat("@trackCase",%2))) {
			#VAR trackBloodySub {%upper(%2)}
			} {
			#VAR trackBloodySub {%2}
			}
		#IF (%ismember(%2,@trackBloodyList)) {
			#VAR trackColorType {%eval(%concat("@trackColor",%2))}
			} {
			#VAR trackColorType {}
			}
		#IF (@trackCaseDirection) {
			#VAR trackDirectionSub {%upper(%3)}
			} {
			#VAR trackDirectionSub {%3}
			}
		#VAR trackCharacterDirectional {%eval(%concat("@trackCharacter",%3))}
		#SUB {%1 @trackMXPcolorBloody(@trackColorBloody,@trackTracesSub,@trackColorType,@trackBloodySub,@trackColorCharacter,@trackCharacterDirectional,@trackColorDirection,@trackDirectionSub)}
		}
	} "" {case|disable}
#ONINPUT {^{tr|tra|trac|track}*$} {
	#T+ {Tracking|TrackManual}
	#VAR trackPromptCount {0}
	} "" {}
#CLASS 0
#CLASS {Tracking|TrackManual} {disable}
#TRIGGER "trackManualPrompt" {{*|o} * >} {
	#VAR trackPromptCount {%eval(@trackPromptCount+1)}
	#IF (@trackPromptCount>1) {
		#T- {Tracking|TrackManual}
		} {}
	} "" {case|nocr|prompt}
#TRIGGER "trackBloodyTrigger" {^(Some*) bloody traces of a ([A-Z]%w) leaving (%w).$} {
	#PRIORITY {
		#IF (@trackCaseBloody) {
			#VAR trackTracesSub {BLOODY TRACES}
			} {
			#VAR trackTracesSub {bloody traces}
			}
		#IF (%ismember(%2,@trackBloodyList)) {
			#VAR trackColorType {%eval(%concat("@trackColor",%2))}
			} {
			#VAR trackColorType {}
			}
		#IF (%eval(%concat("@trackCase",%2))) {
			#VAR trackBloodySub {%upper(%2)}
			} {
			#VAR trackBloodySub {%2}
			}
		#IF (@trackCaseDirection) {
			#VAR trackDirectionSub {%upper(%3)}
			} {
			#VAR trackDirectionSub {%3}
			}
		#VAR trackCharacterDirectional {%eval(%concat("@trackCharacter",%3))}
		#SUB {%1 @trackMXPcolorBloody(@trackColorBloody,@trackTracesSub,@trackColorType,@trackBloodySub,@trackColorCharacter,@trackCharacterDirectional,@trackColorDirection,@trackDirectionSub)}
		}
	} "" {case}
#TRIGGER "trackNameTrigger" {^(Some *tracks of) ([A-Z]%w) leaving (%w).$} {
	#PRIORITY {
		#IF (@trackCaseDirection) {
			#VAR trackDirectionSub {%upper(%3)}
			} {
			#VAR trackDirectionSub {%3}
			}
		#IF (@trackCasePlayer) {
			#VAR trackNameSub {%upper(%2)}
			} {
			#VAR trackNameSub {%proper(%2)}
			}
		#VAR trackCharacterDirectional {%eval(%concat("@trackCharacter",%3))}
		#SUB {%1 @trackMXPcolorType(@trackColorPlayer,@trackNameSub,@trackColorCharacter,@trackCharacterDirectional,@trackColorDirection,@trackDirectionSub)}
		}
	} "" {case}
#TRIGGER "trackRiddenTrigger" {^(Some * {a|an}) (*) ~(ridden~) leaving (%w).$} {
	#PRIORITY {
		#IF (@trackCaseMount) {
			#VAR trackTypeSub {%upper(%2)}
			} {
			#VAR trackTypeSub {%2}
			}
		#IF (@trackCaseDirection) {
			#VAR trackDirectionSub {%upper(%3)}
			} {
			#VAR trackDirectionSub {%3}
			}
		#VAR trackCharacterDirectional {%eval(%concat("@trackCharacter",%3))}
		#SUB {%1 @trackMXPcolorRidden(@trackColorMount,@trackTypeSub,@trackColorCharacter,@trackCharacterDirectional,@trackColorDirection,@trackDirectionSub)}
		}
	} "" {case}
#TRIGGER "trackPlayerTrigger" {^(Some *tracks of a) ([A-Z]%w) leaving (%w).$} {
	#PRIORITY {
		#IF (%ismember(%2,@trackPlayerList)) {
			#VAR trackColorType {%eval(%concat("@trackColor",%2))}
			} {
			#IF (%eval(%concat("@trackCase",%2))) {
				#VAR trackPlayerSub {%upper(%2)}
				} {
				#VAR trackPlayerSub {%2}
				}
			#IF (@trackCaseDirection) {
				#VAR trackDirectionSub {%upper(%3)}
				} {
				#VAR trackDirectionSub {%3}
				}
			#VAR trackCharacterDirectional {%eval(%concat("@trackCharacter",%3))}
			#SUB {%1 @trackMXPcolorType(@trackColorType,@trackPlayerSub,@trackColorCharacter,@trackCharacterDirectional,@trackColorDirection,@trackDirectionSub)}
			}
		}
	} "" {case}
#CLASS 0

[Taziar]

Type helpScan to view help file in client.



Direct download link: ScanHoM.txt

Active Triggers: 1/3
Input Triggers: 1

Code: Select all

#CLASS {Scan}
#ALIAS helpScan {
	#PRIORITY {
		#SAY {%crlf " -----Scan Help File-----"}
		#SAY {"    [Updated: 7/27/2018]"}
		#SHOW {" Sets color of directional words in both manual and auto-scan lines."}
		#SHOW {""}
		#SHOW {" Type: scanColor <color> [bcolor] [background color optional]"}
		#SHOW {""}
		#SHOW {"  Current scan color: "@scanMXPcolor(@scanColor)}
		#SHOW {""}
		}
	}
#ALIAS scanColor {
	#IF (%null(%1)) {
		#SHOW {""}
		#SAY {" Usage: scanColor <color> [bcolor] [background color optional]"}
		#SHOW {""}
		#SHOW {"  Current scan color:"}
		#SHOW {"   "@scanMXPcolor(@scanColor)}
		#SHOW {""}
		} {
		#IF (%colorname(%1)=536870911 AND %color(%1)=0) {
			#VAR scanColor {}
			#SAY {" "%1 is an invalid color. Scan color variable cleared.}
			} {
			#IF (%null(%2)) {
				#VAR scanColor {%1}
				#SHOW {Scan color set: @scanMXPcolor(%1)}
				} {
				#IF (%colorname(%2)=536870911 AND %color(%2)=0) {
					#VAR scanColor {}
					#SAY {" "%2 is an invalid color. Scan color variable cleared.}
					} {
					#VAR scanColor {%concat(%1,",",%2)}
					#SHOW {Scan color set: @scanMXPcolor(%2 %3)}
					}
				}
			}
		}
	}
#FUNCTION scanMXPcolor {<color %1>%1</color>}
#VAR scanColor {darkorange}
#VAR scanPromptCount {0}
#VAR scanDirectionList {Down:|East:|North:|South:|Up:|West:}
#TRIGGER "scanDirectionTrigger" {({@scanDirectionList})(*)$} {
	#PCOL {@scanColor} %x1
	#IF (%ismember( %word( "%2", 1), @scanDirectionList)) {
		#PSUB {} %x2
		#SHOW {%2}
		}
	} "" {case|disable}
#TRIGGER "scanExitsTrigger" {^~[ obvious exits: * ~]$} {
	#T+ {scanDirectionTrigger}
	#T+ {scanPromptTrigger}
	} "" {case}
#TRIGGER "scanPromptTrigger" {{*|o} * >} {
	#IF (@scanPromptCount=0) {
		#T- {scanDirectionTrigger}
		#T- {scanPromptTrigger}
		#VAR scanPromptCount {0}
		} {
		#VAR scanPromptCount {%eval(@scanPromptCount-1)}
		}
	} "" {case|disable|nocr|prompt}
#ONINPUT {^scan} {
	#VAR scanPromptCount {%eval(@scanPromptCount+1)}
	#T+ {scanDirectionTrigger}
	#T+ {scanPromptTrigger}
	} "" {}
#CLASS 0

[Taziar]

Type helpPractice to view help file in client.



Direct download link: PracticeHoM.txt

Active Triggers: 2/15
Input Trigger: 1

Code: Select all

#CLASS {Practice}
#ALIAS helpPractice {
	#PRIORITY {
		#SAY {%crlf "-----Practice Help File-----"}
		#SAY {"      [Updated: 7/18/18]"}
		#SHOW {" Practice %'s automatically save when viewing practices at any trainer or training a skill."}
		#SHOW {" Saves pracs for each character and automatically resets when a practice reset is detected."}
		#SHOW {""}
		#SHOW {" Type showPracs to view list of current practices and prac points remaining of current character."}
		#SHOW {"  Note: will show practiced weaves and spell points remaining if character is a channeler."}
		#SHOW {""}
		#SHOW {" Type savePracs to save a .txt file of current character's current practices."}
		#SHOW {""}
		#SHOW {" Type resetPracs to reset practice data."}
		#SHOW {"  Note: will automatically reset saved pracs when a practice reset is detected."}
		#SHOW {""}
		#SHOW {" All .txt files are saved in the same directory containing zMUD.exe"}
		#SHOW {""}
		}
	}
#ALIAS showPracs {
	#SHOW {%crlf You have %eval(%concat("@pracRemaining",%char)) practice points remaining.}
	#IF (%null(%eval(%concat("@pracSpellRemaining",%char)))) {} {
		#SHOW {You have %eval(%concat("@pracSpellRemaining",%char)) spell points remaining.}
		}
	#SHOW {"You are skilled in the following:"}
	#SAY {"-------Warrior Pracs-------"}
	#FORALL @pracListWarrior {
		#IF (%eval(%concat("@prac",%char,%i))>0) {
			#SHOW {%i %repeat(" ",%eval(20-%len(%i))) ~(%eval(%concat("@prac",%char,%i))~%~)}
			} {}
		}
	#SAY {"--------Rogue Pracs--------"}
	#FORALL @pracListRogue {
		#IF (%eval(%concat("@prac",%char,%i))>0) {
			#SHOW {%i %repeat(" ",%eval(20-%len(%i))) ~(%eval(%concat("@prac",%char,%i))~%~)}
			} {}
		}
	#SAY {"-------Hunter Pracs--------"}
	#FORALL @pracListHunter {
		#IF (%eval(%concat("@prac",%char,%i))>0) {
			#SHOW {%i %repeat(" ",%eval(20-%len(%i))) ~(%eval(%concat("@prac",%char,%i))~%~) %if((%ismember(%i,@pracListHunterLevels)),Level @pracLevelFunc(%eval(%concat("@prac",%char,%i))),"")}
			} {}
		}
	#IF (%null(%eval(%concat("@pracSpellRemaining",%char)))) {} {
		#SAY {"------Channeler Pracs------"}
		}
	#IF (%null(%eval(%concat("@pracSpellRemaining",%char)))) {} {
		#SAY {"---------Elements----------"}
		}
	#IF (%null(%eval(%concat("@pracSpellRemaining",%char)))) {} {
		#FORALL @pracListElement {
			#IF (%eval(%concat("@prac",%char,%i))>0) {
				#SHOW {%i %repeat(" ",%eval(20-%len(%i))) ~(%eval(%concat("@prac",%char,%i))~%~) Level @pracLevelFunc(%eval(%concat("@prac",%char,%i)))}
				} {}
			}
		}
	#IF (%null(%eval(%concat("@pracSpellRemaining",%char)))) {} {
		#SAY {"----------Weaves-----------"}
		}
	#IF (%null(%eval(%concat("@pracSpellRemaining",%char)))) {} {
		#FORALL @pracListWeaves {
			#IF (%eval(%concat("@prac",%char,%i))>0) {
				#SHOW {%i %repeat(" ",%eval(20-%len(%i))) ~(%eval(%concat("@prac",%char,%i))~%~)}
				} {}
			}
		}
	}
#ALIAS savePracs {
	#FILE 1 %concat("prac",%char,"Data.txt")
	#WRITE 1 {}
	#WRITE 1 {%char %time(c)}
	#WRITE 1 {}
	#WRITE 1 {-------Warrior Pracs-------}
	#FORALL @pracListWarrior {
		#IF (%eval(%concat("@prac",%char,%i))>0) {
			#WRITE 1 {%i %repeat(" ",%eval(20-%len(%i))) %eval(%concat("@prac",%char,%i))}
			}
		} {}
	#WRITE 1 {--------Rogue Pracs--------}
	#FORALL @pracListRogue {
		#IF (%eval(%concat("@prac",%char,%i))>0) {
			#WRITE 1 {%i %repeat(" ",%eval(20-%len(%i))) %eval(%concat("@prac",%char,%i))}
			}
		} {}
	#WRITE 1 {-------Hunter Pracs--------}
	#FORALL @pracListHunter {
		#IF (%eval(%concat("@prac",%char,%i))>0) {
			#WRITE 1 {%i %repeat(" ",%eval(20-%len(%i))) %eval(%concat("@prac",%char,%i)) %if((%ismember(%i,@pracListHunterLevels)),Level @pracLevelFunc(%eval(%concat("@prac",%char,%i))),"")}
			}
		} {}
	#IF (%null(%concat("@pracSpellRemaining",%char))) {} {
		#WRITE {"------Channeler Pracs------"}
		}
	#IF (%null(%concat("@pracSpellRemaining",%char))) {} {
		#WRITE {"---------Elements----------"}
		}
	#IF (%null(%concat("@pracSpellRemaining",%char))) {} {
		#FORALL @pracListElement {
			#IF (%eval(%concat("@prac",%char,%i))>0) {
				#SHOW {%i %repeat(" ",%eval(20-%len(%i))) ~(%eval(%concat("@prac",%char,%i))~%~) Level @pracLevelFunc(%eval(%concat("@prac",%char,%i)))}
				} {}
			}
		}
	#IF (%null(%concat("@pracSpellRemaining",%char))) {} {
		#WRITE {"----------Weaves-----------"}
		}
	#IF (%null(%concat("@pracSpellRemaining",%char))) {} {
		#FORALL @pracListWeaves {
			#IF (%eval(%concat("@prac",%char,%i))>0) {
				#SHOW {%i %repeat(" ",%eval(20-%len(%i))) ~(%eval(%concat("@prac",%char,%i))~%~)}
				} {}
			}
		}
	#CLOSE 1
	}
#ALIAS resetPracs {
	#PRIORITY {
		#VAR %concat("pracRemaining",%char) {0} {_nodef} {Practice|%concat(%char,"PracticeVariables")}
		#FORALL @pracListRogue {
			#VAR %concat("prac",%char,%proper(%i)) {0} {_nodef} {Practice|%concat(%char,"PracticeVariables")}
			}
		#FORALL @pracListWarrior {
			#VAR %concat("prac",%char,%proper(%i)) {0} {_nodef} {Practice|%concat(%char,"PracticeVariables")}
			}
		#FORALL @pracListHunter {
			#VAR %concat("prac",%char,%proper(%i)) {0} {_nodef} {Practice|%concat(%char,"PracticeVariables")}
			}
		#IF (%null(%concat("@pracSpellRemaining",%char))) {} {
			#VAR %concat("pracSpellRemaining",%char) {0} {_nodef} {Practice|%concat(%char,"PracticeVariables")}
			}
		#IF (%null(%concat("@pracSpellRemaining",%char))) {} {
			#FORALL @pracListElement {
				#VAR %concat("prac",%char,%proper(%i)) {0} {_nodef} {Practice|%concat(%char,"PracticeVariables")}
				}
			}
		#IF (%null(%concat("@pracSpellRemaining",%char))) {} {
			#FORALL @pracListWeaves {
				#VAR %concat("prac",%char,%proper(%i)) {0} {_nodef} {Practice|%concat(%char,"PracticeVariables")}
				}
			}
		#SAY {%crlf Practice data for %char is reset.}
		}
	}
#FUNCTION pracLevelFunc {%eval(%1/14)}
#VAR pracListRogue {steal|pick|hide|sneak|dodge|attack|backstab|palm|shortBlades|projectiles}
#VAR pracListWarrior {bash|kick|rescue|shieldParry|charge|longBlades|mediumBlades|fencingBlades|axes|clubs|staves|lances|spears|javelins|polearms|flails|bows|chains|crossbows|slings|whips}
#VAR pracListHunter {search|track|ride|wisdomLore|swim|notice|camouflage|rangerSneak|coverTracks|survival}
#VAR pracListHunterLevels {ride|wisdomlore|survival}
#VAR pracListElement {earth|air|fire|water|spirit}
#VAR pracListWeaves {armor|blind|callLightning|changeWeather|chill|contagion|createFog|createFood|createPhantomObject|createWater|cureBlindness|cureCriticalWounds|cureFear|cureLightWounds|curePoison|cureSeriousWounds|deafen|earthquake|elementalStaff|fear|fireball|flameStrike|freeze|gate|hailstorm|hammerOfAir|heal|hurricane|iceSpikes|incinerate|lightBall|locateLife|locateObject|poison|refresh|removeContagion|removeWarding|senseWarding|shield|silence|sleep|sliceWeaves|slow|sonicBoom|strength|swordOfFlame|travel|wardObject|wardingVsDamage|wardingVsEvil|whirlpool}
#VAR pracSkillInput {}
#TRIGGER "pracResetGuardian" {^Your skills have been reset by the Guardian!$} {
	resetPracs
	} "" {case}
#TRIGGER "pracResetTrigger" {^You've forgotten everything you've learned!$} {
	resetPracs
	} "" {case}
#ONINPUT "pracInput" {^{pr|pra|prac|pract|practi|practic|practice}(*)$} {
	#VAR pracSkillInput {%replace(%1," ","")}
	#T+ {Practice|PracticeTriggers}
	}
#CLASS 0
#CLASS {Practice|PracticeTriggers} {disable}
#TRIGGER "pracRemainingTrigger" {You have got (%d) practice sessions left.$} {
	#VAR %concat("pracRemaining",%char) {%1} {_nodef} {Practice|%concat(%char,"PracticeVariables")}
	} "" {case}
#TRIGGER "pracSpellRemainingTrigger" {You have got (%d) spell practice sessions left.$} {
	#VAR %concat("pracSpellRemaining",%char) {%1} {_nodef} {Practice|%concat(%char,"PracticeVariables")}
	} "" {case}
#TRIGGER "pracChannelerTrigger" {You have got (%d) practice sessions, and (%d) spell practice sessions left.$} {
	#VAR %concat("pracRemaining",%char) {%1} {_nodef} {Practice|%concat(%char,"PracticeVariables")}
	#VAR %concat("pracSpellRemaining",%char) {%2} {_nodef} {Practice|%concat(%char,"PracticeVariables")}
	} "" {case}
#TRIGGER "pracSkillTrigger" {^You now have (%d)~% knowledge of this skill and (%d) practice sessions left.$} {
	#IF (%class(%concat("prac",%char,@pracSkillInput))) {
		#VAR %concat("prac",%char,@pracSkillInput) {%1} {_nodef} {Practice|%concat(%char,"PracticeVariables")}
		#VAR %concat("pracRemaining",%char) {%2} {_nodef} {Practice|%concat(%char,"PracticeVariables")} 
		} {}
	} "" {case}
#TRIGGER "pracSpellTrigger" {^You now have (%d)~% knowledge of this weave and (%d) spell practice sessions left.$} {
	#IF (%class(%concat("prac",%char,@pracSkillInput))) {
		#VAR %concat("prac",%char,@pracSkillInput) {%1} {_nodef} {Practice|%concat(%char,"PracticeVariables")}
		#VAR %concat("pracSpellRemaining",%char) {%2} {_nodef} {Practice|%concat(%char,"PracticeVariables")} 
		} {}
	} "" {case}
#TRIGGER "pracTrigger1" {^(%w)%s~((%trim(*))~%~)$} {
	#VAR %concat("prac",%char,%1) {%2} {_nodef} {Practice|%concat(%char,"PracticeVariables")}
	} "" {}
#TRIGGER "pracTrigger2" {^(%w)%s(%w)%s~((%trim(*))~%~)$} {
	#VAR %concat("prac",%char,%1,%2) {%3} {_nodef} {Practice|%concat(%char,"PracticeVariables")}
	} "" {}
#TRIGGER "pracTrigger3" {^(%w)%s(%w)%s(%w)%s~((%trim(*))~%~)$} {
	#VAR %concat("prac",%char,%1,%2,%3) {%4} {_nodef} {Practice|%concat(%char,"PracticeVariables")}
	} "" {}
#TRIGGER "pracTrigger4" {^(%w)%sLevel%s(%d)%s~((%trim(*))~%~)$} {
	#VAR %concat("prac",%char,%1) {%3} {_nodef} {Practice|%concat(%char,"PracticeVariables")}
	} "" {case}
#TRIGGER "pracTrigger5" {^(%w)%s(%w)%sLevel%s(%d)%s~((%trim(*))~%~)$} {
	#VAR %concat("prac",%char,%1,%2) {%4} {_nodef} {Practice|%concat(%char,"PracticeVariables")}
	} "" {case}
#TRIGGER "pracTrigger6" {~* Press ~<Return~> to continue, q to quit ~*~>} {
	#GAG
	#CR
	#GAG -1
	} "" {case|prompt|nocr}
#TRIGGER "pracTrigger7" {{o|*} * >} {
	#ALARM "pracPromptAlarm" {+2} {#T- {Practice|PracticeTriggers}}
	} "" {case|prompt|nocr}
#CLASS 0
#CLASS {Practice|PracticeConnect} {enable}
#TRIGGER "pracConnectTrigger" {%s The Wheel Of Time MUD} {
	#T- {Practice|PracticeConnect}
	#IF (%class(Practice|%concat(%char,PracticeVariables))=-1) {
		#PRIORITY {
			#CLASS {Practice|%concat(%char,PracticeVariables)} {disable}
			#CLASS 0
			#VAR %concat("pracRemaining",%char) {0} {_nodef} {Practice|%concat(%char,"PracticeVariables")}
			#FORALL @pracListRogue {
				#VAR %concat("prac",%char,%proper(%i)) {0} {_nodef} {Practice|%concat(%char,"PracticeVariables")}
				}
			#FORALL @pracListWarrior {
				#VAR %concat("prac",%char,%proper(%i)) {0} {_nodef} {Practice|%concat(%char,"PracticeVariables")}
				}
			#FORALL @pracListHunter {
				#VAR %concat("prac",%char,%proper(%i)) {0} {_nodef} {Practice|%concat(%char,"PracticeVariables")}
				}
			#VAR %concat("pracSpellRemaining",%char) {} {_nodef} {Practice|%concat(%char,"PracticeVariables")}
			#FORALL @pracListElement {
				#VAR %concat("prac",%char,%proper(%i)) {0} {_nodef} {Practice|%concat(%char,"PracticeVariables")}
				}
			#FORALL @pracListWeaves {
				#VAR %concat("prac",%char,%proper(%i)) {0} {_nodef} {Practice|%concat(%char,"PracticeVariables")}
				}
			}		
		} {#T+ {Practice|%concat(%char,PracticeVariables)}}
	} "" {case}
#CLASS 0

[Taziar]

Type helpDoors to view help file in client.



Direct download link: DoorsHoM.txt

Active Triggers: 9/9 (8/9 with door name in exit line function off)

Code: Select all

#CLASS {Doors}
#ALIAS helpDoors {
	#PRIORITY {
		#SAY {%crlf " -----Doors Help File-----"}
		#SAY {"     [Updated: 10/20/2018]"}
		#SHOW {" The @doorName variable is automatically filled with trigger events."}
		#SHOW {"  Hint: set macros for open @doorName and close @doorName to spam a door."}
		#SHOW {""}
		#SHOW {"  Type <command> to complete action:"}
		#SHOW {"    cd to close  @doorName"}
		#SHOW {"    kd to knock  @doorName"}
		#SHOW {"    ld to lock   @doorName"}
		#SHOW {"    od to open   @doorName"}
		#SHOW {"    pd to pick   @doorName"}
		#SHOW {"    ud to unlock @doorName"}
		#SHOW {""}
		#SHOW {"  Type <command> <direction> to use door name saved in map properties for that direction."}
		#SHOW {"   Example: cd n to close %doorname north"}
		#SHOW {""}
		#SHOW {" Recognized directions: n e s w u d"}
		#SHOW {"  Note: anything not a recognized direction will be ignored and <command> @doorName used instead."}
		#SHOW {"   Example: cd sw (incorrect directional) will send command: close @doorName"}
		#SHOW {""}
		#SHOW {" Type showDoorExits to toggle door name in exit line function on/off."}
		#SHOW {"  Example: [ obvious exits: E W ] [ E: chamberdoor ]"}
		#SHOW {"   Default: on"}
		#SHOW {""}
		#SHOW {" Type setDoor <direction> to create @doorName in that direction on your map."}
		#SHOW {"  Example: setDoor n to create a door north of current map location named @doorName."}
		#SHOW {""}
		#SHOW {" Type setDoor <direction> <door name> to create door in direction with given name."}
		#SHOW {"  Example: <setDoor s gate> to create a door south of current map location named gate."}
		#SHOW {"   Note: the #DOOR command sets door name the same on both sides of door,"}
		#SHOW {"    must manually adjust room properties for doors with different named sides."}
		#SHOW {""}
		}
	}
#ALIAS setDoor {
	#IF (%ismember(%1,@doorDirection)) {
		#MENU {Mapper|File|Map Creation Mode}
		#IF (%len(%2)) {#DOOR %1 %2} {#DOOR %1 @doorName}
		#MENU {Mapper|File|Follow Mode}
		}
	}
#ALIAS cd {
	#IF (%ismember(%lower(%1),@doorDirection)) {
		#IF (%null(%doorname(,%1))) {
			#SAY {%crlf Door name not saved in map properties for that direction... %crlf}
			} {
			close %doorname(,%1) %item(@doorDirectionInput,%ismember(%lower(%1),@doorDirection))
			#IF (@doorName=%doorname(,%1)) {} {
				#VAR doorName {%doorname(,%1)}
				#SAY {%crlf doorName is now set as: @doorName %crlf}
				}
			}
		} {
		close @doorName
		}
	}
#ALIAS kd {
	#IF (%ismember(%lower(%1),@doorDirection)) {
		#IF (%null(%doorname(,%1))) {
			#SAY {%crlf Door name not saved in map properties for that direction... %crlf}
			} {
			knock %doorname(,%1) %item(@doorDirectionInput,%ismember(%lower(%1),@doorDirection))
			#IF (@doorName=%doorname(,%1)) {} {
				#VAR doorName {%doorname(,%1)}
				#SAY {%crlf doorName is now set as: @doorName %crlf}
				}
			}
		} {
		knock @doorName
		}
	}
#ALIAS ld {
	#IF (%ismember(%lower(%1),@doorDirection)) {
		#IF (%null(%doorname(,%1))) {
			#SAY {%crlf Door name not saved in map properties for that direction... %crlf}
			} {
			lock %doorname(,%1) %item(@doorDirectionInput,%ismember(%lower(%1),@doorDirection))
			#IF (@doorName=%doorname(,%1)) {} {
				#VAR doorName {%doorname(,%1)}
				#SAY {%crlf doorName is now set as: @doorName %crlf}
				}
			}
		} {
		lock @doorName
		}
	}
#ALIAS od {
	#IF (%ismember(%lower(%1),@doorDirection)) {
		#IF (%null(%doorname(,%1))) {
			#SAY {%crlf Door name not saved in map properties for that direction... %crlf}
			} {
			open %doorname(,%1) %item(@doorDirectionInput,%ismember(%lower(%1),@doorDirection))
			#IF (@doorName=%doorname(,%1)) {} {
				#VAR doorName {%doorname(,%1)}
				#SAY {%crlf doorName is now set as: @doorName %crlf}
				}
			}
		} {
		open @doorName
		}
	}
#ALIAS pd {
	#IF (%ismember(%lower(%1),@doorDirection)) {
		#IF (%null(%doorname(,%1))) {
			#SAY {%crlf Door name not saved in map properties for that direction... %crlf}
			} {
			pick %doorname(,%1) %item(@doorDirectionInput,%ismember(%lower(%1),@doorDirection))
			#IF (@doorName=%doorname(,%1)) {} {
				#VAR doorName {%doorname(,%1)}
				#SAY {%crlf doorName is now set as: @doorName %crlf}
				}
			}
		} {
		pick @doorName
		}
	}
#ALIAS ud {
	#IF (%ismember(%lower(%1),@doorDirection)) {
		#IF (%null(%doorname(,%1))) {
			#SAY {%crlf Door name not saved in map properties for that direction... %crlf}
			} {
			unlock %doorname(,%1) %item(@doorDirectionInput,%ismember(%lower(%1),@doorDirection))
			#IF (@doorName=%doorname(,%1)) {} {
				#VAR doorName {%doorname(,%1)}
				#SAY {%crlf doorName is now set as: @doorName %crlf}
				}
			}
		} {
		unlock @doorName
		}
	}
#VAR showDoorExits {1}
#VAR doorName {}
#VAR doorExitsName {}
#VAR doorDirection {d|e|n|s|u|w}
#VAR doorDirectionInput {down|east|north|south|up|west}
#VAR doorRoomName {}
#TRIGGER "doorSeemsTrigger" {The &doorName seems to be closed.} {
	#SAY {doorName is now set as: @doorName}
	} "" {case}
#TRIGGER "doorHiddenTrigger" {You skillfully discover a hidden &{doorName}.} {
	#SAY {doorName is now set as: @doorName}
	} "" {case}
#TRIGGER "doorClosedTrigger" {The &doorName is closed.} {
	#SAY {doorName is now set as: @doorName}
	} "" {case}
#TRIGGER "doorOpenTrigger" {The &doorName is open.} {
	#SAY {doorName is now set as: @doorName}
	} "" {case}
#TRIGGER "doorObviouslyTrigger" {The &doorName is obviously open.} {
	#SAY {doorName is now set as: @doorName}
	} "" {case}
#TRIGGER "doorVisableTrigger" {The &doorName is quite visible.} {
	#SAY {doorName is now set as: @doorName}
	} "" {case}
#TRIGGER "doorNameTrigger" {^%e[36m([A-Z]*)%e[0m$} {
	#VAR doorRoomName {%1}
	} "" {case|color}
#TRIGGER "doorNamePrompt" {^{*|o} * > %e[36m([A-Z]*)%e[0m$} {
	#VAR doorRoomName {%1}
	} "" {case|color}
#TRIGGER "doorExitsTrigger" {^(~[ obvious exits: *~])$} {
	#PRIORITY {
		#FORALL @doorDirection {
			#IF (%null(%doorname(,%i))) {} {#ADDITEM doorExitsName %concat(%upper(%i):," ",%doorname(,%i))}
			}
		#IF (%null(@doorExitsName)) {} {
			#IF (%roomname=@doorRoomName) {
				#SUB {%1 [ %replace(@doorExitsName,"|"," ") ]}
				}
			}
		#VAR doorExitsName {}
		}
	} "" {case|notrig}
#CLASS 0

[Taziar]

Type helpCharacters to view help file in client.



Direct download link: CharactersHoM.txt

Active Triggers: 0/1

Code: Select all

#CLASS {Characters}
#ALIAS helpCharacters {
	#PRIORITY {
		#SAY {%crlf "-----Characters Help File-----"}
		#SAY {"    [Updated: 7/5/2018]"}
		#SHOW {" Characters script creates and enables individual character classes on connection."}
		#SHOW {" Default keypad macro variables are created in Characters class folder."}
		#SHOW {"  All macro variables in both the Characters class folder and individual character"}
		#SHOW {"   folders will need to be set to each individual character's preferences."}
		#SHOW {""}
		#SHOW {" Type setKey <KEY> <command> to setup a macro."}
		#SHOW {"  Hint: setKey <KEY> without <command> will show current <command> for that <KEY>."}
		#SHOW {"   Examples: setKey DIV bash"}
		#SHOW {"             setKey MULT channel 'ice spikes' "@target4""}
		#SHOW {""}
		#SHOW {" Shared Keys (macros): DEC|KEY0|KEY1|KEY2|KEY3|KEY4|KEY5|KEY6|KEY7|KEY8|KEY9"}
		#SHOW {"  Note: shared keys are used by all characters."}
		#SHOW {""}
		#SHOW {" F-Keys (macros): F1|F2|F3|F4|F5|F6|F7|F8|F9|F10|F11|F12"}
		#SHOW {"  Note: all F-Keys are shared and used by all characters."}
		#SHOW {""}
		#SHOW {" Insert Key (INS): Displays zone page for the WoTMUD Wiki of the current zone in mapper."}
		#SHOW {"  Note: this function is compatible only when using the WoTMUD Wiki zMap."}
		#SHOW {""}
		#SHOW {" Individual Character Keys (macros): ADD|DIV|END|HOME|MULT|PGDN|PGUP|SUB"}
		#SHOW {"  Note: setKey command sets individual keys for current character only."}
		#SHOW {""}
		}
	}
#ALIAS setKey {
	#IF (%null(%1)) {
		#SAY {%crlf " Usage: setKey <KEY> <command>"}
		} {
		#IF (%ismember(%upper(%1),@charKeyList)) {
			#IF (%null(%2)) {
				#SAY {%crlf %upper(%1) is currently set to: %eval(%concat("@char","%1"))}
				} {
				#VAR %concat(char,%1) {%-2}
				#SAY {%crlf %upper(%1) set to: %eval(%concat("@char","%1"))}
				}
			} {#SAY {%crlf Invalid <KEY>! Type helpCharacters...}}
		}
	}
#VAR charKeyList {ADD|DEC|DIV|END|F1|F2|F3|F4|F5|F6|F7|F8|F9|F10|F11|F12|HOME|KEY0|KEY1|KEY2|KEY3|KEY4|KEY5|KEY6|KEY7|KEY8|KEY9|MULT|PGDN|PGUP|SUB}
#VAR charKey0 {find}
#VAR charKey1 {where}
#VAR charKey2 {south}
#VAR charKey3 {down}
#VAR charKey4 {west}
#VAR charKey5 {look}
#VAR charKey6 {east}
#VAR charKey7 {flee}
#VAR charKey8 {north}
#VAR charKey9 {up}
#VAR charF1 {}
#VAR charF10 {}
#VAR charF11 {}
#VAR charF12 {}
#VAR charF2 {}
#VAR charF3 {}
#VAR charF4 {}
#VAR charF5 {}
#VAR charF6 {}
#VAR charF7 {}
#VAR charF8 {}
#VAR charF9 {}
#VAR charDEC {notice}
#KEY DEC {@charDEC}
#KEY F1 {@charF1}
#KEY F10 {@charF10}
#KEY F11 {@charF11}
#KEY F12 {@charF12}
#KEY F2 {@charF2}
#KEY F3 {@charF3}
#KEY F4 {@charF4}
#KEY F5 {@charF5}
#KEY F6 {@charF6}
#KEY F7 {@charF7}
#KEY F8 {@charF8}
#KEY F9 {@charF9}
#KEY INS {#URL %concat("http://wotmud.wikia.com/wiki/",%zonename())}
#KEY KEY0 {@charKEY0}
#KEY KEY1 {@charKEY1}
#KEY KEY2 {@charKEY2}
#KEY KEY3 {@charKEY3}
#KEY KEY4 {@charKEY4}
#KEY KEY5 {@charKEY5}
#KEY KEY6 {@charKEY6}
#KEY KEY7 {@charKEY7}
#KEY KEY8 {@charKEY8}
#KEY KEY9 {@charKEY9}
#CLASS 0
#CLASS {Characters|CharacterConnect} {enable}
#TRIGGER "charConnectTrigger" {%s The Wheel Of Time MUD} {
	#T- {Characters|CharacterConnect}
	#IF (%class(Characters|%char)=-1) {
		#CLASS {Characters|%char} {disable}
		#CLASS 0
		#KEY ADD {@charADD} {Characters|%char}
		#KEY DIV {@charDIV} {Characters|%char}
		#KEY END {@charDIV} {Characters|%char}
		#KEY HOME {@charMULT} {Characters|%char}
		#KEY MULT {@charMULT} {Characters|%char}
		#KEY PGDN {@charADD} {Characters|%char}
		#KEY PGUP {@charSUB} {Characters|%char}
		#KEY SUB {@charSUB} {Characters|%char}
		#VAR charADD {} {_nodef} {Characters|%char}
		#VAR charDIV {} {_nodef} {Characters|%char}
		#VAR charEND {} {_nodef} {Characters|%char}
		#VAR charHOME {} {_nodef} {Characters|%char}
		#VAR charMULT {} {_nodef} {Characters|%char}
		#VAR charPGDN {} {_nodef} {Characters|%char}
		#VAR charPGUP {} {_nodef} {Characters|%char}
		#VAR charSUB {} {_nodef} {Characters|%char}
		} {#T+ {Characters|%char}}
	} "" {case}
#CLASS 0

[Taziar]

Type helpScoreStatTime to view help file in client.



Direct download link: ScoreStatTimeHoM.txt

Active Triggers: 0/54
Input Triggers: 6

Code: Select all

#CLASS {ScoreStatTime}
#ALIAS helpScoreStatTime {
	#PRIORITY {
		#SAY {%crlf " -----ScoreStatTime Help File-----"}
		#SAY {"        [Updated: 8/31/2018]"}
		#SHOW {" Saves score, stat, time, and equipment info in character notes."}
		#SHOW {"  Note: also saves character's rent info if Rent script is detected."}
		#SHOW {""}
		#SHOW {" Saves estimated reroll date in character comments."}
		#SHOW {"  Note: Character deletion date saved in character comments if under level 30."}
		#SHOW {""}
		#SHOW {" Type showBMI to toggle BMI:<BMI> at end of weight line (on/off)."}
		#SHOW {"  Note: BMI statistics shown are truncated."}
		#SHOW {"   Example: a BMI of 0.390059173107147 will show as BMI:0.39"}
		#SHOW {""}
		#SHOW {" Type showStatSum to toggle SUM:<statsum> at end of stats line (on/off)."}
		#SHOW {"  Example: Your base abilities are: Str:17 Int:11 Wil:6 Dex:19 Con:19 Sum:72."}
		#SHOW {""}
		#SHOW {" Type showTime to toggle time messages in time command output (on/off)."}
		#SHOW {"  Example: It has been 7 days, 17 hours since "%char" last connected. (game time)"}
		#SHOW {""}
		#SHOW {" Type showTotalDefense to toggle Total Defense:<defense> at end of bonus line (on/off)."}
		#SHOW {"  Example: Offensive bonus: 151, Dodging bonus: 82, Parrying bonus: 20, Total defense: 102"}
		#SHOW {""}
		#SHOW {" Type showEXP to toggle EXP since last score command line (on/off)."}
		#SHOW {"  Example: You have gained 510 experience points since your last score command."}
		#SHOW {"   Note: will not display line if experience gained is zero or less."}
		#SHOW {""}
		#SHOW {" Typing rent or quit will send time command to save data then rent/quit."}
		#SHOW {""}
		#SHOW {" Type linkless to save data and disconnect if linkless renting."}
		#SHOW {""}
		}
	}
#ALIAS showBMI {
	#IF (@showBMI) {
		#VAR showBMI {0}
		#SAY {%crlf "BMI information is turned off."}
		} {
		#VAR showBMI {1}
		#SAY {%crlf "BMI information is turned on."}
		}
	}
#ALIAS showEXP {
	#IF (@showEXP) {
		#VAR showEXP {0}
		#SAY {%crlf "EXP line function is turned off."}
		#T- {scoreEXPmath}
		} {
		#VAR showEXP {1}
		#SAY {%crlf "EXP line function is turned on."}
		#T+ {scoreEXPmath}
		}
	}
#ALIAS showStatSum {
	#IF (@showStatSum) {
		#VAR showStatSum {0}
		#SAY {%crlf "StatSum information is turned off."}
		} {
		#VAR showStatSum {1}
		#SAY {%crlf "StatSum information is turned on."}
		}
	}
#ALIAS showTime {
	#IF (@showTimeDisplay) {
		#VAR showTimeDisplay {0}
		#SAY {%crlf "Time message information is turned off."}
		} {
		#VAR showTimeDisplay {1}
		#SAY {%crlf "Time message information is turned on."}
		}
	}
#ALIAS showTotalDefense {
	#IF (@showTotalDefense) {
		#VAR showTotalDefense {0}
		#SAY {%crlf "TotalDefense information is turned off."}
		} {
		#VAR showTotalDefense {1}
		#SAY {%crlf "TotalDefense information is turned on."}
		}
	}
#ALIAS timeSetPastData {
	#VAR timePastAMPM {@timeAMPM}
	#VAR timePastMonth {@timeMonth}
	#VAR timePastHour {@timeHour}
	#VAR timePastDay {@timeDay}
	#VAR timePastYear {@timeYear}
	#VAR %concat(%char,"AMPM") {@timeAMPM} {_nodef} {ScoreStatTime|%concat(%char,"ScoreStatTimeVariables")}
	#VAR %concat(%char,"Month") {@timeMonth} {_nodef} {ScoreStatTime|%concat(%char,"ScoreStatTimeVariables")}
	#VAR %concat(%char,"Hour") {@timeHour} {_nodef} {ScoreStatTime|%concat(%char,"ScoreStatTimeVariables")}
	#VAR %concat(%char,"Day") {@timeDay} {_nodef} {ScoreStatTime|%concat(%char,"ScoreStatTimeVariables")}
	#VAR %concat(%char,"Year") {@timeYear} {_nodef} {ScoreStatTime|%concat(%char,"ScoreStatTimeVariables")}
	}
#ALIAS timeCalculations {
	#MATH timeEvalYears {(@timeYear*8736)}
	#MATH timeEvalMonths {(%ismember(@timeMonth,@timeMonthNames)*672)}
	#MATH timeEvalDays {(@timeDay*24)}
	#IF (@timeAMPM=pm)  {#MATH timeEvalHours {@timeHour+12}} {#MATH timeEvalHours {@timeHour}}
	#IF (@timeHour=12) {#IF (@timeAMPM=am) {#VAR timeEvalHours {0}} {#VAR timeEvalHours {12}}} {}
	#MATH timeCurrentTotal {(@timeEvalYears+@timeEvalMonths+@timeEvalDays+@timeEvalHours)}
	#MATH timeEvalPastYears {(@timePastYear*8736)}
	#MATH timeEvalPastMonths {(%ismember(@timePastMonth,@timeMonthNames)*672)}
	#MATH timeEvalPastDays {(@timePastDay*24)}
	#IF (@timePastAMPM=pm)  {#MATH timeEvalPastHours {@timePastHour+12}} {#MATH timeEvalPastHours {@timePastHour}}
	#IF (@timePastHour=12) {#IF (@timePastAMPM=am) {#VAR timeEvalPastHours {0}} {#VAR timeEvalPastHours {12}}} {}
	#MATH timePastTotal {(@timeEvalPastYears+@timeEvalPastMonths+@timeEvalPastDays+@timeEvalPastHours)}
	#MATH timeTotalHours {(@timeCurrentTotal-@timePastTotal)}
	#IF (@timeTotalHours > 8736) {
		#MATH timeDisplayYear {%format(0,%float(@timeTotalHours/8736))}
		#MATH timeTotalMonths {(@timeTotalHours-(@timeDisplayYear*8736))}
		} {
		#VAR timeDisplayYear {0}
		#VAR timeTotalMonths {@timeTotalHours}
		}
	#IF (@timeTotalMonths > 672) {
		#MATH timeDisplayMonth {%format(0,%float(@timeTotalMonths/672))}
		#MATH timeTotalDays {(@timeTotalMonths-(@timeDisplayMonth*672))}
		} {
		#VAR timeDisplayMonth {0}
		#VAR timeTotalDays {@timeTotalMonths}
		}
	#IF (@timeTotalDays > 24) {
		#MATH timeDisplayDay {%format(0,%float(@timeTotalDays/24))}
		#MATH timeDisplayHour {(@timeTotalDays-(@timeDisplayDay*24))}
		} {
		#VAR timeDisplayDay {0}
		#VAR timeDisplayHour {@timeTotalDays}
		}
	}
#ALIAS timeConnection {
	#T+ {timeTrigger}
	#T+ {ScoreStatTime|CharacterNotes|TimeNotes}
	#VAR timePastAMPM {%eval(%concat("@",%char,"AMPM"))} {_nodef} {ScoreStatTime}
	#VAR timePastMonth {%eval(%concat("@",%char,"Month"))} {_nodef} {ScoreStatTime}
	#VAR timePastHour {%eval(%concat("@",%char,"Hour"))} {_nodef} {ScoreStatTime}
	#VAR timePastDay {%eval(%concat("@",%char,"Day"))} {_nodef} {ScoreStatTime}
	#VAR timePastYear {%eval(%concat("@",%char,"Year"))} {_nodef} {ScoreStatTime}
	#SEND {time}
	}
#ALIAS timeDisconnect {
	#T+ {timeTrigger}
	#T+ {ScoreStatTime|CharacterNotes|TimeNotes}
	#VAR showTimeMessage {0}
	#VAR showTimeDisconnect {1}
	#TEMP "disconnectTEMP" {^The official forums are now at * enjoy!$} {
		#VAR %concat(%char,"AMPM") {@timeAMPM} {_nodef} {ScoreStatTime|%concat(%char,"ScoreStatTimeVariables")}
		#VAR %concat(%char,"Month") {@timeMonth} {_nodef} {ScoreStatTime|%concat(%char,"ScoreStatTimeVariables")}
		#VAR %concat(%char,"Hour") {@timeHour} {_nodef} {ScoreStatTime|%concat(%char,"ScoreStatTimeVariables")}
		#VAR %concat(%char,"Day") {@timeDay} {_nodef} {ScoreStatTime|%concat(%char,"ScoreStatTimeVariables")}
		#VAR %concat(%char,"Year") {@timeYear} {_nodef} {ScoreStatTime|%concat(%char,"ScoreStatTimeVariables")}
		} "ScoreStatTime" {case}
	#SEND {time}
	}
#ALIAS linkless {
	#TEMP "linklessTEMP" {^~(Server: * EST, up for *~)$} {
		#DISCONNECT
		#IF (%class(Rent)=1) {saveRentNotes} {}
		saveCharacterNotes
		} "ScoreStatTime" {case}
	timeDisconnect
	}
#VAR scoreEXP1 {0} {0}
#VAR scoreEXP2 {0} {0}
#VAR scoreEXPresult {0} {0}
#VAR scoreLevel {} {}
#VAR scoreQP1 {0} {0}
#VAR scoreQP2 {0} {0}
#VAR scoreQPresult {0} {0}
#VAR serverCalTemp {}
#VAR serverDay {}
#VAR serverDisplayDay {}
#VAR serverDisplayDays {0} {0}
#VAR serverDisplayMonth {}
#VAR serverDisplayMonths {0} {0}
#VAR serverMonth {}
#VAR serverMonthDays {31|28|31|30|31|30|31|31|30|31|30|31}
#VAR serverMonthNames {Jan|Feb|Mar|Apr|May|Jun|Jul|Aug|Sep|Oct|Nov|Dec}
#VAR serverRerollMonth {}
#VAR serverRerollMonths {0} {0}
#VAR serverRerollYear {}
#VAR serverYear {}
#VAR showBMI {1}
#VAR showEXP {1}
#VAR showStatSum {1}
#VAR showTimeConnection {1} {1}
#VAR showTimeDeletion {0} {0}
#VAR showTimeDisconnect {0} {0}
#VAR showTimeDisplay {1}
#VAR showTimeMessage {0} {0}
#VAR showTotalDefense {1}
#VAR statAge {} {}
#VAR statBMI {} {}
#VAR statCON {} {}
#VAR statCarryWeight {} {}
#VAR statClass {} {}
#VAR statDEX {} {}
#VAR statDodge {} {}
#VAR statFeet {} {}
#VAR statGender {} {}
#VAR statHeightBMI {} {}
#VAR statINT {} {}
#VAR statInches {} {}
#VAR statOffensive {} {}
#VAR statParry {} {}
#VAR statRace {} {}
#VAR statSTR {} {}
#VAR statSUM {} {}
#VAR statTotalBMI {} {}
#VAR statTotalDefense {} {}
#VAR statTotalHeight {} {}
#VAR statWIL {} {}
#VAR statWeight {} {}
#VAR statWeightBMI {} {}
#VAR statWeightCondition {} {}
#VAR statWeightTotalBMI {} {}
#VAR statWornWeight {} {}
#VAR timeAMPM {}
#VAR timeCurrentTotal {0}
#VAR timeDay {0}
#VAR timeDisplayDay {0}
#VAR timeDisplayHour {0}
#VAR timeDisplayMonth {0}
#VAR timeDisplayYear {0}
#VAR timeEvalDays {0}
#VAR timeEvalHours {0}
#VAR timeEvalMonths {0}
#VAR timeEvalPastDays {0}
#VAR timeEvalPastHours {0}
#VAR timeEvalPastMonths {0}
#VAR timeEvalPastYears {0}
#VAR timeEvalYears {0}
#VAR timeHour {0}
#VAR timeMonth {}
#VAR timeMonthNames {Taisham|Jumara|Saban|Aine|Adar|Saven|Amadaine|Tammaz|Maigdhal|Choren|Shaldine|Nesan|Danu}
#VAR timePastAMPM {} {}
#VAR timePastDay {0} {0}
#VAR timePastHour {0} {0}
#VAR timePastMonth {} {}
#VAR timePastTotal {0} {0}
#VAR timePastYear {0} {0}
#VAR timeTotalDays {0}
#VAR timeTotalHours {0}
#VAR timeTotalMonths {0}
#VAR timeTotalYears {0}
#VAR timeYear {0}
#TRIGGER "scoreTrigger" {^This ranks you as [A-Z]%w * ~(Level &%dscoreLevel~).$} {
	#T- {scoreTrigger}
	} "" {case|disable}
#TRIGGER "scorePointsTrigger" {^You have scored &%dscoreEXP1 experience points and &%dscoreQP1 quest points.$} {
	#T- {scorePointsTrigger}
	#T+ {scoreEXPtrigger}
	#VAR scoreEXPresult {%eval(@scoreEXP1-@scoreEXP2)}
	#VAR scoreEXP2 {@scoreEXP1}
	#VAR scoreQPresult {%eval(@scoreQP1-@scoreQP2)}
	#VAR scoreQP2 {@scoreQP1}
	} "" {case|disable}
#TRIGGER "scoreEXPtrigger" {^You need * exp to} {
	#T- {scoreEXPtrigger}
	#PRIORITY {
		#IF (@scoreEXP2=@scoreEXPresult AND @scoreQP2=@scoreQPresult) {
			#SAY {Current experience and quest points saved!}
			} {
			#IF (@scoreEXPresult>0 AND @scoreQPresult=0) {
				#SAY {You have gained @scoreEXPresult experience points since your last score command.}
				} {}
			#IF (@scoreEXPresult=0 AND @scoreQPresult>0) {
				#SAY {You have gained @scoreQPresult quest points since your last score command.}
				} {}
			#IF (@scoreEXPresult>0 AND @scoreQPresult>0) {
				#SAY {You have gained @scoreEXPresult experience points and @scoreQPresult quest points since your last score command.}
				} {}
			}
		}
	} "" {case|disable}
#TRIGGER "statTrigger" {You are a &%dstatAge year old &%wstatGender &%wstatRace &%w{statClass}.} {
	#T- {statTrigger}
	#T+ {statAbilitiesTrigger}
	#T+ {statBonusTrigger}
	#T+ {statBMITrigger}
	#T+ {statBMI2Trigger}
	} "" {case|disable}
#TRIGGER "statAbilitiesTrigger" {^Your base abilities are: Str:&%dstatSTR Int:&%dstatINT Wil:&%dstatWIL Dex:&%dstatDEX Con:&%dstatCON} {
	#T- {statAbilitiesTrigger}
	#MATH statSUM {@statSTR+@statINT+@statWIL+@statDEX+@statCON}
	#IF (@showStatSum) {#SUB {Your base abilities are: Str:@statSTR Int:@statINT Wil:@statWIL Dex:@statDEX Con:@statCON Sum:@statSUM}}
	} "" {case|disable}
#TRIGGER "statBonusTrigger" {^Offensive bonus: &%dstatOffensive, Dodging bonus: &%dstatDodge, Parrying bonus: &%dstatParry} {
	#T- {statBonusTrigger}
	#MATH statTotalDefense {@statDodge+@statParry}
	#IF (@showTotalDefense) {#SUB {Offensive bonus: @statOffensive, Dodging bonus: @statDodge, Parrying bonus: @statParry, Total defense: @statTotalDefense}}
	} "" {case|disable}
#TRIGGER "statBMITrigger" {^Your height is &%dstatFeet feet, &%dstatInches inches, and you weigh &statWeight lbs.} {
	#T- {statBMITrigger}
	#MATH statTotalHeight {(@statFeet*12)+@statInches}
	#MATH statHeightBMI {@statTotalHeight*@statTotalHeight}
	#MATH statWeightBMI {@statWeight*10}
	#MATH statBMI {%float(@statWeightBMI)/%float(@statHeightBMI)}
	#IF (@showBMI) {#SUB {Your height is @statFeet feet, @statInches inches, and you weigh @statWeight lbs. Base BMI:%copy(@statBMI,1,4)}}
	} "" {case|disable}
#TRIGGER "statBMI2Trigger" {^You are carrying &statCarryWeight lbs and wearing &statWornWeight lbs, &statWeightCondition.} {
	#T- {statBMI2Trigger}
	#MATH statWeightTotalBMI {(@statWeight+@statWornWeight)*10}
	#MATH statTotalBMI {%float(@statWeightTotalBMI)/%float(@statHeightBMI)}
	#IF (@showBMI) {#SUB {You are carrying @statCarryWeight lbs and wearing @statWornWeight lbs, @statWeightCondition Total BMI:%copy(@statTotalBMI,1,4)}}
	} "" {case|disable}
#TRIGGER "timeTrigger" {It is &%dtimeHour o'clock &%wtimeAMPM, on the &%d{timeDay}{st|nd|rd|th} day of the month of &%wtimeMonth, year &%dtimeYear.} {
	#T- {timeTrigger}
	#T+ {timeDisplayTrigger}
	#T+ {serverTrigger}
	timeCalculations
	timeSetPastData
	} "" {case|disable}
#TRIGGER "timeDisplayTrigger" {^The official forums are now at * enjoy!$} {
	#IF (@showTimeDisplay) {} {#ABORT 1}
	#IF (@showTimeMessage) {
		#SAY {It has been %if(@timeDisplayYear>1,@timeDisplayYear years~," ","")%if(@timeDisplayYear=1,1 year~," ","")%if(@timeDisplayMonth>1,@timeDisplayMonth months~," ","")%if(@timeDisplayMonth=1,1 month~," ","")%if(@timeDisplayDay>1,@timeDisplayDay days~," ","")%if(@timeDisplayDay=1,1 day~," ","")%if(@timeDisplayHour>0,@timeDisplayHour hour,"0 hours")%if(@timeDisplayHour>1,"s "," ")since your last time command. ~(game time~)}
		} {}
	#IF (@showTimeConnection) {
		#SAY {It has been %if(@timeDisplayYear>1,@timeDisplayYear years~," ","")%if(@timeDisplayYear=1,1 year~," ","")%if(@timeDisplayMonth>1,@timeDisplayMonth months~," ","")%if(@timeDisplayMonth=1,1 month~," ","")%if(@timeDisplayDay>1,@timeDisplayDay days~," ","")%if(@timeDisplayDay=1,1 day~," ","")%if(@timeDisplayHour>0,@timeDisplayHour hour,"0 hours")%if(@timeDisplayHour>1,"s "," ")since %char last connected. ~(game time~)}
		} {}
	#IF (@showTimeDisconnect) {#SAY {%char's disconnection time has been saved.}}
	} "" {case|disable}
#COND {$} {
	#T- {timeDisplayTrigger}
	#IF (@showTimeDisplay) {} {#ABORT 1}
	#IF (@showTimeMessage) {#GAG} {}
	#IF (@showTimeConnection) {#GAG} {}
	#IF (@showTimeDisconnect) {#GAG} {}
	#VAR showTimeMessage {1}
	#VAR showTimeConnection {0}
	#VAR showTimeDisconnect {0}
	}
#TRIGGER "serverTrigger" {^~(Server: %w &%wserverMonth { ||}&%dserverDay %d:%d:%d &%dserverYear EST, last rebooted} {
	#PRIORITY {
		#T- {serverTrigger}
		#VAR serverDisplayDays 0
		#VAR serverDisplayMonths 0
		#IF (@scoreLevel>29) {#VAR showTimeDeletion 0} {#VAR showTimeDeletion 1}
		#IF (@scoreLevel>19 AND @scoreLevel<30) {#VAR serverDisplayMonths 6} {}
		#IF (@scoreLevel>9 AND @scoreLevel<20) {#VAR serverDisplayMonths 3} {}
		#IF (@scoreLevel>4 AND @scoreLevel<10) {#VAR serverDisplayMonths 1} {}
		#IF (@scoreLevel>1 AND @scoreLevel<5) {#VAR serverDisplayDays 7} {}
		#IF (@scoreLevel=1) {#VAR serverDisplayDays 3} {}
		#IF (@serverDisplayMonths>0) {
			#MATH serverDisplayMonth @serverDisplayMonths+%ismember(@serverMonth,@serverMonthNames)
				#IF (@serverDisplayMonth>12) {
					#MATH serverDisplayMonth @serverDisplayMonth-12
					#VAR serverDisplayMonth %item(@serverMonthNames,@serverDisplayMonth)
					} {
					#VAR serverDisplayMonth %item(@serverMonthNames,@serverDisplayMonth)
					}
			#VAR serverDisplayDay @serverDay
			} {
			#VAR serverDisplayMonth @serverMonth
			}
		#IF (@serverDisplayDays>0) {
			#MATH serverDisplayDay @serverDisplayDays+@serverDay
			#IF (@serverDisplayDay>%eval(%item(@serverMonthDays,%ismember(@serverMonth,@serverMonthNames)))) {
				#MATH serverDisplayDay @serverDisplayDay-%eval(%item(@serverMonthDays,%ismember(@serverMonth,@serverMonthNames)))
				#MATH serverDisplayMonth %item(@serverMonthNames,(%ismember(@serverMonth,@serverMonthNames)+1))
				} {
				#MATH serverDisplayDay @serverDisplayDays+@serverDay
				}
			} {}
		#IF (@statAge<200) {
			#MATH serverCalTemp 200-@statAge
			} {
			#MATH serverCalTemp %eval(%eval(%concat(%eval(%copy(@statAge,1,1)+1),00))-@statAge)
			}
		#MATH serverCalTemp @serverCalTemp*10
		#MATH serverRerollMonths @serverCalTemp/30
		#VAR serverRerollYear 0
		#WHILE (@serverRerollMonths>11) {
			#MATH serverRerollYear @serverRerollYear+1
			#MATH serverRerollMonths @serverRerollMonths-12
			}
		#MATH serverRerollMonth @serverRerollMonths+%ismember(@serverMonth,@serverMonthNames)
		#IF (@serverRerollMonth>12) {
			#MATH serverRerollYear @serverRerollYear+1
			#MATH serverRerollMonth @serverRerollMonth-12
			} {}
		#VAR serverRerollMonth %item(@serverMonthNames,@serverRerollMonth)
		#MATH serverRerollYear @serverRerollYear+@serverYear
		#IF (@showTimeDeletion) {
			#SAY {%char will delete in %if(@serverDisplayMonths=1,@serverDisplayMonths month,%if(@serverDisplayMonths>1,@serverDisplayMonths months,@serverDisplayDays days)) on @serverDisplayMonth @serverDisplayDay if not logged in before this date.}
			} {}
		#IF (@scoreLevel<30) {
			#CALL %charcomment(%char will delete on @serverDisplayMonth @serverDisplayDay.)
			} {
			#CALL %charcomment(%char will reroll in @serverRerollMonth @serverRerollYear.)
			}
		}
	} "" {case|disable}
#ONINPUT "sstQuitInput" {^quit$} {
	#TEMP "quitTEMP" {^~(Server: * EST, last rebooted *~)$} {
		#IF (%class(Rent)=1) {saveRentNotes} {}
		quitCharacterNotes
		} "ScoreStatTime" {case}
	timeDisconnect
	}
#ONINPUT "sstRentInput" {^{ren|rent}$} {
	#TEMP "rentTEMP" {^~(Server: * EST, last rebooted *~)$} {
		#IF (%class(Rent)=1) {saveRentNotes} {}
		saveCharacterNotes
		} "ScoreStatTime" {case}
	timeDisconnect
	}
#ONINPUT "sstSaveInput" {^{sav|save}$} {
	#IF (%class(Rent)=1) {saveRentNotes} {}
	saveCharacterNotes
	}
#ONINPUT "sstSleepWellWake" {sleep well and wake} {
	#IF (%class(Rent)=1) {saveRentNotes} {}
	saveCharacterNotes
	}
#ONINPUT "sstScoreInput" {^{sc|sco|scor|score}$} {
	#T+ {scoreTrigger}
	#T+ {scorePointsTrigger}
	#T+ {ScoreStatTime|CharacterNotes|ScoreNotes}
	}
#ONINPUT "sstStatInput" {^stat$} {
	#T+ {statTrigger}
	#T+ {ScoreStatTime|CharacterNotes|StatNotes}
	}
#ONINPUT "sstTimeInput" {^{ti|tim|time}$} {
	#T+ {timeTrigger}
	#T+ {ScoreStatTime|CharacterNotes|TimeNotes}
	}
#CLASS 0
#CLASS {ScoreStatTime|CharacterNotes}
#ALIAS saveRentNotes {
	#VAR rentNotesList {-----Available Rents for %char-----}
	#LOOP 1,%numitems(@rentRoomNumbers) {
		#VAR rentNotesTemp {%item(@rentRoomNumbers,%i)}
		#IF (%len(%eval(%concat("@",%char,@rentNotesTemp)))==0) {} {
			#VAR rentNotesList {%additem("lineBreak",@rentNotesList)}
			#ADDITEM rentNotesList {%item(@rentRoomZone,%i) - %item(@rentRoomNames,%i)}
			#LOOP 1,%numitems(%eval(%concat("@",%char,@rentNotesTemp))) {
				#VAR rentNotesList {%additem(%if(%len(%j)>1," ","   ")%j. %item(%eval(%concat("@",%char,@rentNotesTemp)),%j),@rentNotesList)}
				}
			}
		}
	}
#ALIAS saveCharacterNotes {
#CALL {%charnotes(%concat(Rent location: %roomname()%crlf %crlf,%replace(%replace(@scoreNoteslist,"|",%lf),"lineBreak",%crlf),%replace(%replace(@statNotesList,"|",%lf),"lineBreak",%crlf),%replace(%replace(@timeNotesList,"|",%lf),"lineBreak",%crlf),%replace(%replace(@eqNotesList,"|",%lf),"lineBreak",%crlf),%replace(%replace(@rentNotesList,"|",%lf),"lineBreak",%cr)))}
	}
#ALIAS quitCharacterNotes {
	#CALL {%charnotes(%concat(%replace(%replace(@scoreNoteslist,"|",%lf),"lineBreak",%crlf),%replace(%replace(@statNotesList,"|",%lf),"lineBreak",%crlf),%replace(%replace(@timeNotesList,"|",%lf),"lineBreak",%crlf),Equipment notes for %char were deleted due to using the quit command!,%crlf,%crlf,%replace(%replace(@rentNotesList,"|",%lf),"lineBreak",%cr)))}
	}
#VAR eqNotesList {}
#VAR rentNotesList {}
#VAR rentNotesTemp {}
#VAR scoreNotesList {}
#VAR statNotesList {}
#VAR timeNotesList {}
#TRIGGER "eqNotesTrigger" {You are using:$} {
	#T+ {ScoreStatTime|CharacterNotes|EquipmentNotes}
	#VAR eqNotesList {}
	} "" {case}
#CLASS 0
#CLASS {ScoreStatTime|CharacterNotes|ScoreNotes} {enable}
#TRIGGER "scoreNote1" {(You have %d~(%d~) hit*movement points.)$} {
	#VAR scoreNotesList {}
	#VAR scoreNotesList {%additem("%1",@scoreNotesList)}
	} "" {case}
#TRIGGER "scoreNote2" {^(You have scored %d experience points and %d quest points.)$} {#VAR scoreNotesList {%additem("%1",@scoreNotesList)}} "" {case}
#TRIGGER "scoreNote3" {^(You need %d exp to *.)$} {#VAR scoreNotesList {%additem("%1",@scoreNotesList)}} "" {case}
#TRIGGER "scoreNote4" {^(You have acquired %d alt qps to date.)$} {#VAR scoreNotesList {%additem("%1",@scoreNotesList)}} "" {case}
#TRIGGER "scoreNote5" {^(You have amassed %d Turn points to date.)$} {#VAR scoreNotesList {%additem("%1",@scoreNotesList)}} "" {case}
#TRIGGER "scoreNote6" {^(You have played %d days and %d hours ~(real time~).)$} {#VAR scoreNotesList {%additem("%1",@scoreNotesList)}} "" {case}
#TRIGGER "scoreNote7" {^(This ranks you as [A-Z]%w * ~(Level %d~).)$} {
	#T- {ScoreStatTime|CharacterNotes|ScoreNotes}
	#VAR scoreNotesList {%additem("%1",@scoreNotesList)}
	#VAR scoreNotesList {%additem("lineBreak",@scoreNotesList)}
	} "" {case}
#CLASS 0
#CLASS {ScoreStatTime|CharacterNotes|StatNotes} {enable}
#TRIGGER "statNote1" {(You are a %d year old *.)$} {
	#VAR statNotesList {}
	#VAR statNotesList {%additem("%1",@statNotesList)}
	} "" {case}
#TRIGGER "statNote2" {^(Your height is %d feet, %d inches, and you weigh * lbs.*)$} {#VAR statNotesList {%additem("%1",@statNotesList)}} "" {case}
#TRIGGER "statNote3" {^(You are carrying * lbs and wearing * lbs, *.*)$} {#VAR statNotesList {%additem("%1",@statNotesList)}} "" {case}
#TRIGGER "statNote4" {^(Your base abilities are: Str:%d Int:%d Wil:%d Dex:%d Con:%d*.*)$} {#VAR statNotesList {%additem("%1",@statNotesList)}} "" {case}
#TRIGGER "statNote5" {^(Offensive bonus: %d, Dodging bonus: %d, Parrying bonus: *)$} {#VAR statNotesList {%additem("%1",@statNotesList)}} "" {case}
#TRIGGER "statNote6" {^(Your mood is: %w. You will flee below: %d Hit Points)$} {#VAR statNotesList {%additem("%1",@statNotesList)}} "" {case}
#TRIGGER "statNote7" {^(Your posture is: %w.)$} {#VAR statNotesList {%additem("%1",@statNotesList)}} "" {case}
#TRIGGER "statNote8" {^(You are wanted by:*)$} {#VAR statNotesList {%additem("%1",@statNotesList)}} "" {case}
#TRIGGER "statNote9" {^(Your armor absorbs about * on average.)$} {
	#T- {ScoreStatTime|CharacterNotes|StatNotes}
	#VAR statNotesList {%additem("%1",@statNotesList)}
	#VAR statNotesList {%additem("lineBreak",@statNotesList)}
	} "" {case}
#CLASS 0
#CLASS {ScoreStatTime|CharacterNotes|TimeNotes} {enable}
#TRIGGER "timeNote1" {(It is * day of the month of %w, year %d.)$} {
	#VAR timeNotesList {}
	#VAR timeNotesList {%additem("%1",@timeNotesList)}
	} "" {case}
#TRIGGER "timeNote2" {(~(Server: * EST, up for *~))$} {
	#T- {ScoreStatTime|CharacterNotes|TimeNotes}
	#VAR timeNotesList {%additem("%1",@timeNotesList)}
	#VAR timeNotesList {%additem("lineBreak",@timeNotesList)}
	} "" {case}
#CLASS 0
#CLASS {ScoreStatTime|CharacterNotes|EquipmentNotes}
#TRIGGER "eqNote1" {^(~<used as light>*)$} {#VAR eqNotesList {%additem("%1",@eqNotesList)}} "" {case}
#TRIGGER "eqNote2" {^(~<held>*)$} {#VAR eqNotesList {%additem("%1",@eqNotesList)}} "" {case}
#TRIGGER "eqNote3" {^(~<worn on finger>*)$} {#VAR eqNotesList {%additem("%1",@eqNotesList)}} "" {case}
#TRIGGER "eqNote4" {^(~<worn on head>*)$} {#VAR eqNotesList {%additem("%1",@eqNotesList)}} "" {case}
#TRIGGER "eqNote5" {^(~<worn around neck>*)$} {#VAR eqNotesList {%additem("%1",@eqNotesList)}} "" {case}
#TRIGGER "eqNote6" {^(~<worn on body>*)$} {#VAR eqNotesList {%additem("%1",@eqNotesList)}} "" {case}
#TRIGGER "eqNote7" {^(~<worn about body>*)$} {#VAR eqNotesList {%additem("%1",@eqNotesList)}} "" {case}
#TRIGGER "eqNote8" {^(~<slung on back>*)$} {#VAR eqNotesList {%additem("%1",@eqNotesList)}} "" {case}
#TRIGGER "eqNote9" {^(~<worn on arms>*)$} {#VAR eqNotesList {%additem("%1",@eqNotesList)}} "" {case}
#TRIGGER "eqNote10" {^(~<worn on hands>*)$} {#VAR eqNotesList {%additem("%1",@eqNotesList)}} "" {case}
#TRIGGER "eqNote11" {^(~<worn around wrist>*)$} {#VAR eqNotesList {%additem("%1",@eqNotesList)}} "" {case}
#TRIGGER "eqNote12" {^(~<worn as shield>*)$} {#VAR eqNotesList {%additem("%1",@eqNotesList)}} "" {case}
#TRIGGER "eqNote13" {^(~<wielded>*)$} {#VAR eqNotesList {%additem("%1",@eqNotesList)}} "" {case}
#TRIGGER "eqNote14" {^(~<wielded two-handed>*)$} {#VAR eqNotesList {%additem("%1",@eqNotesList)}} "" {case}
#TRIGGER "eqNote15" {^(~<worn about waist>*)$} {#VAR eqNotesList {%additem("%1",@eqNotesList)}} "" {case}
#TRIGGER "eqNote16" {^(~<worn on belt>*)$} {#VAR eqNotesList {%additem("%1",@eqNotesList)}} "" {case}
#TRIGGER "eqNote17" {^(~<worn on legs>*)$} {#VAR eqNotesList {%additem("%1",@eqNotesList)}} "" {case}
#TRIGGER "eqNote18" {^(~<worn on feet>*)$} {#VAR eqNotesList {%additem("%1",@eqNotesList)}} "" {case}
#TRIGGER "eqNotesPrompt" {^{o|*} * >} {
	#T- {ScoreStatTime|CharacterNotes|EquipmentNotes}
	#VAR eqNotesList {%additem("lineBreak",@eqNotesList)}
	} "" {nocr|prompt}
#CLASS 0
#CLASS {ScoreStatTime|ScoreStatTimeConnect} {enable}
#TRIGGER "scoreStatTimeConnectTrigger" {%s The Wheel Of Time MUD} {
	#PRIORITY {
		#IF (%class(ScoreStatTime|%concat(%char,ScoreStatTimeVariables))=-1) {
			#CLASS {ScoreStatTime|%concat(%char,ScoreStatTimeVariables)} {disable}
			#CLASS 0
			#VAR %concat(%char,"AMPM") {} {_nodef} {ScoreStatTime|%concat(%char,"ScoreStatTimeVariables")}
			#VAR %concat(%char,"Month") {} {_nodef} {ScoreStatTime|%concat(%char,"ScoreStatTimeVariables")}
			#VAR %concat(%char,"Hour") {0} {_nodef} {ScoreStatTime|%concat(%char,"ScoreStatTimeVariables")}
			#VAR %concat(%char,"Day") {0} {_nodef} {ScoreStatTime|%concat(%char,"ScoreStatTimeVariables")}
			#VAR %concat(%char,"Year") {0} {_nodef} {ScoreStatTime|%concat(%char,"ScoreStatTimeVariables")}
			} {#T+ {ScoreStatTime|%concat(%char,ScoreStatTimeVariables)}}
		}
	}
#TRIGGER "scoreStatTimeWelcomeTrigger" {^Welcome to the Wheel of Time!  Type 'help' for information.$} {
	#T- {ScoreStatTime|ScoreStatTimeConnect}
	#T+ {scoreTrigger}
	#IF (@showEXP) {#T+ {scorePointsTrigger}} {#T- {scorePointsTrigger}}
	#T+ {statTrigger}
	#SEND {score}
	#SEND {stat}
	timeConnection
	} "" {case}
#TRIGGER "scoreStatTimeReconnectTrigger" {^Reconnecting.$} {
	#T- {ScoreStatTime|ScoreStatTimeConnect}
	#T+ {scoreTrigger}
	#IF (@showEXP) {#T+ {scorePointsTrigger}} {#T- {scorePointsTrigger}}
	#T+ {statTrigger}
	#SEND {score}
	#SEND {stat}
	timeConnection
	} "" {case}
#TRIGGER "scoreStatTimeAlreadyTrigger" {^You take over your own body, already in use!$} {
	#T- {ScoreStatTime|ScoreStatTimeConnect}
	#T+ {scoreTrigger}
	#IF (@showEXP) {#T+ {scorePointsTrigger}} {#T- {scorePointsTrigger}}
	#T+ {statTrigger}
	#SEND {score}
	#SEND {stat}
	timeConnection
	} "" {case}
#CLASS 0