WoTMUD Archives

A player-run forum for the Wheel of Time MUD
It is currently Tue Nov 20, 2018 3:42 am

All times are UTC - 5 hours [ DST ]




Post new topic Reply to topic  [ 14 posts ]  Go to page Previous  1, 2
Author Message
 Post subject: Re: My scripts
PostPosted: Sun Oct 28, 2018 11:20 am 
Offline

Joined: Tue Apr 07, 2015 8:24 pm
Posts: 132
Location: Seattle
Markus' Receipts and Tickets

Quote:
This script browses through all receipts or tickets in your inventory. Simply type "receipts" or "tickets".

Note: the script ignores coach tickets. If it shows a given horse ticket as, say, 4th on the list, use 4.stable to refer to it rather than 4.ticket, at least when your tickets are mixed with coach tickets.


Code:
#CLASS {Receipts and Tickets}
#ALIAS receipts {
  #T+ {Receipt Triggers}
  %char( 32)
  #VARIABLE ReceiptCounter 1
  look receipt
  }
#ALIAS tickets {
  #T+ {Receipt Triggers}
  %char( 32)
  #VARIABLE ReceiptCounter 1
  look stable
  }
#VARIABLE ReceiptCounter {3}
#CLASS 0
#CLASS {Receipts and Tickets|Receipt Triggers} {disable}
#TRIGGER {^* >} {#SUBSTITUTE {}}
#TRIGGER {look} {#GAG}
#REGEX {It is a (stable ticket|receipt) for (.*) from (.*), already redeemable\.$} {
  #SUBSTITUTE { @ReceiptCounter: %2 - %3}
  #ADD ReceiptCounter 1
  look %concat( @ReceiptCounter, ".", %1)
  }
#REGEX {It is a (stable ticket|receipt) for (.*) from (.*), redeemable in (.*)\.$} {
  #SUBSTITUTE { @ReceiptCounter: %2 - %3 (%4)}
  #ADD ReceiptCounter 1
  look %concat( @ReceiptCounter, ".", %1)
  }
#TRIGGER {You do not see that here.} {
  #SUBSTITUTE { That's all!}
  #T- {Receipt Triggers}
  }
#CLASS 0
#T- {Receipt Triggers}

_________________
House of Medakan zMUD Scripts: Table of Contents

House of Medakan cMUD Scripts: Table of Contents


Last edited by Taziar on Sun Oct 28, 2018 11:30 am, edited 1 time in total.

Top
 Profile  
 
 Post subject: Re: My scripts
PostPosted: Sun Oct 28, 2018 11:21 am 
Offline

Joined: Tue Apr 07, 2015 8:24 pm
Posts: 132
Location: Seattle
Markus' StatusBar 1.6

Quote:
This script displays the status of your target, notice, mood, posture, sneak and saidin/saidar in a bar at the bottom of the screen.

Since posture, sneak and the Source are all optional and not all WoTMUD characters have them, they will not be visible unless in use.

Notice status and Mood will always be shown.


Code:
#CLASS {StatusBar 1.6}
#ALIAS NoticeOff {#VARIABLE NoticeStatusColor dimgray}
#ALIAS NoticeOn {#VARIABLE NoticeStatusColor 65280}
#ALIAS MoodWimpy {
  #VARIABLE MoodStatus Wimpy
  #VARIABLE MoodStatusColor lightblue
  }
#ALIAS MoodNormal {
  #VARIABLE MoodStatus Normal
  #VARIABLE MoodStatusColor steelblue
  }
#ALIAS MoodBrave {
  #VARIABLE MoodStatus Brave
  #VARIABLE MoodStatusColor goldenrod
  }
#ALIAS MoodBerserk {
  #VARIABLE MoodStatus BERSERK
  #VARIABLE MoodStatusColor red
  }
#ALIAS PostureDefensive {
  #VARIABLE PostureStatus Defens
  #VARIABLE PostureStatusColor lightblue
  }
#ALIAS PostureNormal {
  #VARIABLE PostureStatus Normal
  #VARIABLE PostureStatusColor steelblue
  }
#ALIAS PostureOffensive {
  #VARIABLE PostureStatus Offens
  #VARIABLE PostureStatusColor goldenrod
  }
#ALIAS PostureNone {#VARIABLE PostureStatusColor black}
#ALIAS SneakOff {#VARIABLE SneakStatusColor black}
#ALIAS SneakOn {#VARIABLE SneakStatusColor white}
#ALIAS SourceOff {#VARIABLE SourceStatusColor {black}}
#ALIAS SourceOn {#VARIABLE SourceStatusColor {white}}
#VARIABLE MoodStatus {Wimpy}
#VARIABLE MoodStatusColor {lightblue}
#VARIABLE NoticeStatusColor {dimgray}
#VARIABLE SneakStatusColor {black}
#VARIABLE PostureStatusColor {black}
#VARIABLE PostureStatus {Defens}
#VARIABLE SourceStatusColor {black}
#TRIGGER "ResetStatusBarOnLogon" {^You were rented for} {
  NoticeOff
  SneakOff
  MoodWimpy
  PostureNone
  SourceOff
  }
#TRIGGER {You stop paying increased attention to your surroundings.$} {NoticeOff}
#TRIGGER {You start paying increased attention to your surroundings.$} {NoticeOn}
#TRIGGER {^- NOTICE} {NoticeOn}
#TRIGGER {You sit down and rest your tired bones.$} {NoticeOff}
#TRIGGER {You sit down.$} {NoticeOff}
#TRIGGER {You go to sleep.$} {NoticeOff}
#TRIGGER {^Your mood is: Wimpy. You will flee below} {MoodWimpy}
#TRIGGER {^Your mood is: Normal. You will flee below} {MoodNormal}
#TRIGGER {^Your mood is: Brave. You will flee below} {MoodBrave}
#TRIGGER {^Your mood is: Berserk. You will flee below} {MoodBerserk}
#TRIGGER {Mood changed to: Wimpy$} {MoodWimpy}
#TRIGGER {Mood changed to: Normal$} {MoodNormal}
#TRIGGER {Mood changed to: Brave$} {MoodBrave}
#TRIGGER {Mood changed to: Berserk$} {MoodBerserk}
#TRIGGER {^- SNEAK} {SneakOn}
#TRIGGER {^{o|*} S} {SneakOn} "" {nocr|prompt}
#TRIGGER {Ok, you stop sneaking.$} {SneakOff}
#TRIGGER {You start riding %w.$} {SneakOff}
#TRIGGER {Posture changed to: Defensive$} {PostureDefensive}
#TRIGGER {Posture changed to: Normal$} {PostureNormal}
#TRIGGER {Posture changed to: Offensive$} {PostureOffensive}
#TRIGGER {Your posture is: Defensive.$} {PostureDefensive}
#TRIGGER {Your posture is: Normal.$} {PostureNormal}
#TRIGGER {Your posture is: Offensive.$} {PostureOffensive}
#TRIGGER {You feel the flows of said?? coursing through your body.$} {SourceOn}
#TRIGGER {^- SOURCE} {SourceOn}
#TRIGGER {^You are dead!%sSorry...$} {SourceOff
MoodWimpy
SneakOff
NoticeOff}
#ONINPUT {^release$} {SourceOff} "" {notrig}
#ONINPUT {^releas$} {SourceOff} "" {notrig}
#ONINPUT {^relea$} {SourceOff} "" {notrig}
#ONINPUT {^rele$} {SourceOff} "" {notrig}
#ONINPUT {^rel$} {SourceOff} "" {notrig}
#STATUS {<font fixedsys 11><color white black> @target</color><color @NoticeStatusColor black> NOTICE </color><color @MoodStatusColor black>@MoodStatus </color><color @PostureStatusColor black>@PostureStatus </color><color @SneakStatusColor black>SNEAK </color><color @SourceStatusColor black>SAI                                                   </color></font>}
#CLASS 0

_________________
House of Medakan zMUD Scripts: Table of Contents

House of Medakan cMUD Scripts: Table of Contents


Last edited by Taziar on Sun Oct 28, 2018 11:29 am, edited 1 time in total.

Top
 Profile  
 
 Post subject: Re: My scripts
PostPosted: Sun Oct 28, 2018 11:27 am 
Offline

Joined: Tue Apr 07, 2015 8:24 pm
Posts: 132
Location: Seattle
Markus' Targeting

Quote:
This is a rather simple targetting script. It's intended as a basic example that should be easy to adapt and expand upon to suit your needs.

Changing your target: tar name. For example:

tar dark
tar seanchan
tar markus

Afterwards you can do the following things:

z - kill target (for normal spamming)
x - kill h.target (costs mvs but has better chance to hit a hidden)
dd - diag h.target (for detection without losing mvs; won't stop a stab though!)
c - charge h.target
bs - backstab h.target
v - bash, or bash target

Also:

vv - switches between 'bash' and 'bash target'.


Code:
#CLASS {Targetting}
#ALIAS z {kill @target}
#ALIAS x {kill h.@target}
#ALIAS dd {diag h.@target}
#ALIAS c {charge h.@target}
#ALIAS bs {backstab h.@target}
#ALIAS tar {
  #VAR target {%1}
  #SAY Target set to @target.
  }
#ALIAS vv {
  #IF (%alias( v) == "bash") {#ALIAS v {bash @target}} {#ALIAS v {bash}}
  #ALIAS v
  }
#ALIAS v {bash @target}
#VAR target {Ewok}
#CLASS 0

_________________
House of Medakan zMUD Scripts: Table of Contents

House of Medakan cMUD Scripts: Table of Contents


Top
 Profile  
 
 Post subject: Re: My scripts
PostPosted: Sun Oct 28, 2018 11:29 am 
Offline

Joined: Tue Apr 07, 2015 8:24 pm
Posts: 132
Location: Seattle
Markus' Travel

Quote:
This a fairly simple Travel script. How it works:

---------------------
Summary of commands
---------------------

loc - locate object, for instance 'loc key'
life - locate life, for instance 'life horse'

tcode label N - store a travelcode numbered N under a label of your choice
tcode label travelcode - store a directly copy-pasted travelcode under a label of your choice

trav label - travel to a stored code
trav - randiport

twipe - manually delete all stored codes (normally you shouldn't use this; instead type 'time' upon month change)

----------------------
Detailed description
----------------------

After using one of the locating aliases you should see a numbered list of results, such as:

a wild stallion - [VFZqciAwIDUxZmQ5YTBmYWQgODQ=] - somewhere northwest of here. (1)
a wild stallion - [VFZpcyAwIGMxOTgwOGU3ZTMgNjA=] - somewhere northwest of here. (2)
a gray palfrey - [TFhZY20gMCAwMDVkYzY3YzQxIDcx] - somewhere very far northwest of here. (3)
a black warhorse - [V1dobiAwIDAzZTA0YjNjMWUgNjQ=] - somewhere very far north of here. (4)
a dun mare - [UWNicSAwIDE5ZmY2YjJlOTMgNzk=] - somewhere far north of here. (5)
a dun mare - [UWNicSAwIDE5ZmY2YjJlOTMgODQ=] - somewhere far north of here. (6)
a draft horse - [UWNicSAwIDE5ZmY2YjJlOTMgOQ==] - somewhere far north of here. (7)
a draft horse - [UWNicSAwIDE5ZmY2YjJlOTMgNDA=] - somewhere far north of here. (8)

To store a code, use the command tcode. The syntax is 'tcode label number'. 'number' is from the above list, and 'label' is a name of your choice. For example, to set a code for the palfrey and refer to it as 'horse':

tcode horse 3

You may also explicitely copy-paste the code, which is useful if you got the code from, say, another player:

tcode horse TFhZY20gMCAwMDVkYzY3YzQxIDcx

After that type one of the following (either works, so whichever you prefer) to Travel to that location:

travhorse
trav horse

Additionally, the script keeps track of the month and year. If the month changes, type 'time' and your codes will be wiped. Note: the script does NOT automatically do this when the month changes. You have to type 'time'.

You may also manually wipe the codes with the command 'twipe', but this is not recommended. Normally you should rely on 'time' instead.


Code:
#CLASS {Travel}
#ALIAS life {
  channel 'locate life' %1
  #VARIABLE TcodeListed {}
  #VARIABLE TcodeListedNum {0}
  }
#ALIAS loc {
  channel 'locate object' %1
  #VARIABLE TcodeListed {}
  #VARIABLE TcodeListedNum {0}
  }
#ALIAS tcode {
  #IF (%numparam( ) = 2) {
    #IF (%len( %2) < 3) {#IF (%len( %item( @TcodeListed, %2))>2) {%exec( tcode %1 %item( @TcodeListed, %2))}} {
      #ALIAS trav%1 {channel 'travel' %2} {Travel|Travel Codes}
      #WAIT 2
      #SAY
      #ALIAS trav%1
      }
    }
  }
#ALIAS twipe {#DELCLASS "Travel Codes"}
#ALIAS trav {
  #IF (%numparam( )>0) {trav%1} {
    channel 'travel'
    #SAY RANDIPORTING
    #COLOR red
    }
  }
#VARIABLE TcodeListed {UVpobncgNSA0ZjMwY2QwYzI2IDU2}
#VARIABLE TcodeListedNum {1}
#REGEX {(\[)(.*)(\] - somewhere .* here)} {
  #VARIABLE TCodeListedNum {%eval( @TCodeListedNum + 1)}
  #SUBSTITUTE {%1%2%3 (@TCodeListedNum)}
  #VARIABLE TCodeListed {%additem( %2, @TCodeListed)}
  }
#CLASS 0
#CLASS {Travel|Month Change}
#VARIABLE CurrentMonthYear {Danu966}
#VARIABLE RememberedMonthYear {Danu966}
#TRIGGER {It is * o'clock *, on the * day of the month of (*), year (*).$} {
  #VARIABLE CurrentMonthYear {%1%2}
  #IF (@CurrentMonthYear <> @RememberedMonthYear) {
    twipe
    #VARIABLE RememberedMonthYear {@CurrentMonthYear}
    #WAIT 200
    #SAY
    #SAY MONTH CHANGE! WIPING CODES
    #COLOR red
    }
  }
#CLASS 0

_________________
House of Medakan zMUD Scripts: Table of Contents

House of Medakan cMUD Scripts: Table of Contents


Top
 Profile  
 
Display posts from previous:  Sort by  
Post new topic Reply to topic  [ 14 posts ]  Go to page Previous  1, 2

All times are UTC - 5 hours [ DST ]


Who is online

Users browsing this forum: No registered users and 1 guest


You cannot post new topics in this forum
You cannot reply to topics in this forum
You cannot edit your posts in this forum
You cannot delete your posts in this forum

Search for:
Jump to:  
cron
Powered by phpBB® Forum Software © phpBB Group