WoTMUD Archives

A player-run forum for the Wheel of Time MUD
It is currently Mon Aug 10, 2020 1:48 am

All times are UTC - 5 hours [ DST ]




Post new topic Reply to topic  [ 1 post ] 
Author Message
 Post subject: Various Scripts
PostPosted: Thu Jul 26, 2012 1:37 pm 
Offline

Joined: Thu Jul 26, 2012 12:58 pm
Posts: 1
#CLASS {BashCounter}
#TRIGGER {As * avoids your bash, you topple over and fall to the ground!} {#ADD missed 1;#ADD bashes 1;#MATH bashpercent (100*@landed)/@bashes;#SAY You have missed @missed andlanded @landed bashes for a @bashpercent~% land rate this session.}
#TRIGGER {Your bash at * sends %w sprawling!} {#ADD landed 1;#ADD bashes 1;#MATH bashpercent (100*@landed)/@bashes;#SAY You have missed @missed and landed @landed bashes for a @bashpercent~% land rate this session.}
#TRIGGER {Welcome to the Wheel of Time!%sType 'help' for information.} {newsession}
#ALIAS newsession {#VAR missed 0;#VAR landed 0;#VAR bashes 0}
#CLASS 0

#class {doors}
#ALIAS d1 {#VAR door %1;#ECHO %1 is now set as your primary door.}
#ALIAS d2 {#VAR door2 %1;#ECHO %1 is now set as your secondary door.}
#ALIAS d3 {#VAR door3 %1;#ECHO %1 is now set as your temporary door.}
#ALIAS p1 {pick @door}
#ALIAS p2 {pick @door2}
#ALIAS p3 {pick @door3}
#TRIGGER {The %1 seems to be closed.} {d3 %1}
#TRIGGER {You skillfully discover a hidden %1.} {d3 %1}
#TRIGGER {The %1 is open.} {d3 %1}
#TRIGGER {The %1 is closed.} {d3 %1}
#TRIGGER {The %1 is quite visible.} {d3 %1}
#ALIAS {o} {open @door}
#ALIAS {i} {close @door}
#ALIAS {9} {open @door2}
#ALIAS {8} {close @door2}
#KE {F3} {open @door3}
#KE {F4} {close @door3}
#ALIAS doors {#IF (%null( %doorname( ,n))) {} {#ECHO N: %doorname( ,n)};#IF (%null( %doorname( ,e))) {} {#ECHO E: %doorname( ,e)};#IF (%null( %doorname( ,s))) {} {#ECHO S: %doorname( ,s)};#IF (%null( %doorname( ,w))) {} {#ECHO W: %doorname( ,w)};#IF (%null( %doorname( ,u))) {} {#ECHO U: %doorname( ,u)};#IF (%null( %doorname( ,d))) {} {#ECHO D: %doorname( ,d)}}
#class 0

#CLASS {Mount}
#ALIAS setmount {#VAR mount}
#ALIAS p {dism}
#ALIAS 0 {lead @mount}
#ALIAS r {ride @mount}
#ALIAS dh {diag @mount}
#ALIAS eqmount {p;0;get saddle pack;get bridle pack;get shoes pack;get donning pack;eq @mount saddle;eq @mount bridle;eq @mount shoes;eq @mount donning;r}
#ALIAS uneqmount {p;0;remove saddle @mount;remove bridle @mount;remove shoes @mount;remove donning @mount}
#TRIGGER {You equip a %w with a donning.} {#VAR donning 1;#VAR wagonready 0}
#TRIGGER {You remove a donning from a %w.} {#VAR donning 0}
#TRIGGER {You equip a %w with a hitching harness.} {#VAR wagonready 1}
#TRIGGER {You remove a hitching harness from a %w.} {#VAR wagonready 0}
#ALIAS hitchwagon {#IF wagonready=1 {p;0;hitch wagon @mount;r}{#IF donning=1 {p;0;remove donning @mount;get harness pack;put donning pack;eq @mount harness;hitch wagon @mount;r} {p;0;get harness pack;eq @mount harness;hitch wagon @mount;r}}}
#ALIAS unhitchwagon {p;0;unhitch @mount wagon;remove harness @mount;put harness pack;r}
#TRIGGER {You equip a %w with a saddlebag.} {#VAR saddlebag 1}
#TRIGGER {You equip a %w with a worn saddlebag.} {#VAR saddlebag 1}
#TRIGGER {You remove a saddlebag from a %w.} {#VAR saddlebag 0}
#TRIGGER {You remove a worn saddlebag from a %w.} {#VAR saddlebag 0}
#ALIAS sbag {#IF saddlebag=1 {p;0;remove saddlebag @mount;r}{p;0;equip @mount saddlebag;r}}
#ALIAS rr {ride 2.horse}
#CLASS 0

Note: This script assumes all tack is kept in "pack" if you want it somewhere else change it! Also be careful if you have a saddlebag on when you stable. The stablehand drops the saddlebag on the ground, but gives you the saddle. It is easy to loose saddlebags and the eq in them this way!

#CLASS {Rations}
#ALIAS rationloc {#VAR rationlocation}
#ALIAS setwater {#VAR watercontainer}
#ALIAS setfood {#VAR food}
#ALIAS wsource {#VAR watersource}
#ALIAS drinkw {get @watercontainer @rationlocation;drink @watercontainer;put @watercontainer @rationlocation}
#ALIAS refill {get @watercontainer @rationlocation;drink @watercontainer;fill water water;put @watercontainer @rationlocation}
#ALIAS food {get @food @rationlocation;eat @food}
#TRIGGER {You are hungry.} {#VAR hunger 1}
#TRIGGER {You are full.} {#VAR hunger 0}
#TRIGGER {You are thirsty.} {#VAR thirst 1}
#TRIGGER {You don't feel thirsty any more.} {#VAR thirst 0}
#ALIAS rations {#IF hunger=1 {#IF thirst=1 {drinkw;food} {food}} {#IF thirst=1 {drinkw}}}
#CLASS 0

Note: The triggers in this script DO NOT trigger an in game action (i.e. no eating or drinking or anything that will interrupt a timer.) they just set variable (true/false) values so that when the player enters the command "rations" they will eat and drink only IF they are hungry and thirsty.

#CLASS {SimpleTarget}
#ALIAS st {#VAR target}
#ALIAS s2 {#VAR target2}
#ALIAS y {kill @target}
#ALIAS h {kill @target2}
#ALIAS yy {kill h.@target}
#ALIAS hh {kill h.@target2}
#ALIAS g {kill seanchan}
#ALIAS gg {kill h.seanchan}
#ALIAS v {kill dark}
#alias vv {kill h.dark}
#ALIAS bt {bash @target}
#ALIAS ct {charge @target}
#ALIAS t {track @target}
#ALIAS tt {track @target2}
#ALIAS tm {track mount}
#ALIAS lt {look @target}
#ALIAS l2 {look @target2}
#ALIAS lg {look seanchan}
#ALIAS lv {look dark}
#ALIAS {f} {cmw;flee}
#ALIAS {cb} {change mood brave}
#ALIAS {cn} {change mood normal}
#ALIAS {cw} {change mood wimpy}
#ALIAS {cw} {change wimpy}
#ALIAS zerk {change mood berserk}
#ALIAS coin {
get all.purse all
get all.pouch all
get all.bag all
get all.pack all
get all.coin all
put all.coin pack
}
#ALIAS gac {get all corpse}
#CLASS 0

Note: Targeting is set up for an LS player. Change dark or seanchan to human if you are not a DS/LS player. If you want to put coin in something other than pack change it.

#CLASS {Mend}
#ALIAS mw {p;0;sit;get stone pouch;hold stone;remove @weapon;mend @weapon}
#ALIAS mendcomplete {wield @weapon;stand;r;remove stone;put stone pouch}
#TRIGGER {You finish mending a *} {mendcomplete}
#CLASS 0

Note: In mending if you use a pack/ purse etc to store your stone change it.

#CLASS {Throwing}
#ALIAS setflyer {#VAR flyer}
#ALIAS setdart {#VAR dart}
#ALIAS retrievedart {
get @dart
wield @dart
}
#ALIAS getdart {
get @dart corpse
wield @dart
sheath
wield @weapon
}
#ONINPUT {throwat %1} {
setflyer %1
remove @weapon
draw
throw %1
} "" {notrig}
#TRIGGER {* @dart * falls to the ground.} {retrievedart}
#TRIGGER {Your blood freezes as you hear a @flyer's death cry.} {
getdart
#UNV flyer
}
#TRIGGER {Even you can't throw that far up in the sky!} {
sheath
wield @weapon
say It is too far up. We need to flee it.
}
#CLASS 0

#CLASS {GroupTellSmob}
#ALIAS addg {#if !%ismember( %0, @Party) {#var Party %additem( %0, @Party)};#echo %1 has beenadded to your grouptell.}
#ALIAS resetgroup {#UNV Party}
#ALIAS gt {#LOO %numitems( @Party) {tell %item( @Party, %i) GT: %0}}
#ALIAS remg {#var Party %delitem( %0, @Party);#echo %1 has been removed from your grouptell.}
#ALIAS groupcheck {#say @{Party}}
#TRIGGER {GT:} {#cw bold,blue}
#TRIGGER {%1 is now a member of your group.} {addg %1;#echo %1 has been added to grouptell.}
#TRIGGER {%1 stops following you.} {remg %1;#echo %1 has been removed from grouptell.}
#TRIGGER {You have disbanded the group.} {resetgroup;#echo Grouptell reset.}
#TRIGGER {You are now a member of %1's group.} {addg %1;#set groupleader %1;#echo %1 is set asgroup leader}
#TRIGGER {%1 now follows @groupleader.} {addg %1}
#TRIGGER {%1 stops following @groupleader.} {remg %1}
#CLASS 0

Note: This script is made for Smobbers, the GT cycle rate is too slow for PK, but it keeps the smob group off globals and away from D-Friend and MSN spies. Yes i am paranoid, you should be too! IF you are not the group leader you need to add the grouped players that were grouped before you manually with the command "addg xxx". Once a group is formed "gt xxx" will tell every member "GT: xxx" it is worth testing. This is especially useful for Groupleader "OUT/OFF" orders and special orders like "DON'T bash lich!"

Some Miscelleaneous aliases

#ALIAS c {call}
#ALIAS rat {
not
ki rat
not
}


Top
 Profile  
 
Display posts from previous:  Sort by  
Post new topic Reply to topic  [ 1 post ] 

All times are UTC - 5 hours [ DST ]


Who is online

Users browsing this forum: No registered users and 2 guests


You cannot post new topics in this forum
You cannot reply to topics in this forum
You cannot edit your posts in this forum
You cannot delete your posts in this forum

Search for:
Jump to:  
cron
Powered by phpBB® Forum Software © phpBB Group