WoTMUD Archives

A player-run forum for the Wheel of Time MUD
It is currently Mon Dec 10, 2018 8:52 am

All times are UTC - 5 hours [ DST ]




Post new topic Reply to topic  [ 39 posts ]  Go to page 1, 2, 3, 4  Next
Author Message
PostPosted: Wed Mar 22, 2017 2:18 pm 
Offline

Joined: Tue Apr 07, 2015 8:24 pm
Posts: 132
Location: Seattle
House of Medakan zMUD Scripts
The following scripts are the newest release versions and are meant to replace any previous HoM zMUD version.
Any bugs, comments, or suggestions please mail Taziar here at Archives.

Script Installation Tutorial
Character name must be input into the character name field in the character tab,
located in properties of the icon you connect to the mud with from the zMUD character window.
Without this many of these script functions will fail because of the %char function.
Verify in client by inputting #SHOW {%char} into the command line and pressing enter.
Will display current connected character name if setup correctly.


If using the layout feature each individual icon needs its own unique .lay file.

Table of Contents

Custom zMUD Scripts (scripts written on request)

_________________
House of Medakan zMUD Scripts: Table of Contents

House of Medakan cMUD Scripts: Table of Contents


Last edited by Taziar on Sat Oct 20, 2018 2:05 pm, edited 175 times in total.

Top
 Profile  
 
 Post subject: Re: HoM zMUD Scripts
PostPosted: Tue Apr 04, 2017 7:31 pm 
Offline

Joined: Tue Apr 07, 2015 8:24 pm
Posts: 132
Location: Seattle
Type helpSailing to view help file in client.

Image

Type oceanmap to view map of all ocean routes and ship names.

Image

Type rivermap to view both river systems and boat names.

Image

Maps update automatically and follow you throughout your trip, type map command at anytime to see current location (X marks the spot).

Five different RP messages (randomly assigned) notify you when a trip is successfully input, at the next sailor emote the trip will begin.
    Script uses your character's name in flavor text via the %char function.

For RP messages, flavor text, and map follow functions to work properly:
    Do not use WoTmud alias for embark and disembark commands.
    Can use zMUD alias, example: #ALIAS eh {embark hummingbird}
    Embark and disembark use #ONINPUT trigger so the command must be typed or used like in the above example.
    Your current location must be in proper room (embark room) on zMUD map when embarking vessel to have map show departure port.

Direct download link: SailingHoM.txt

Active Triggers: 0/43
Input Triggers: 2
Code:
#CLASS {Sailing}
#ALIAS helpSailing {
   #PRIORITY {
      #SAY {%crlf "-----Sailing Help File-----"}
      #SAY {"     [Update: 2/21/2018]"}
      #SHOW {" Type riversail <starting location> <destination>"}
      #SHOW {"  Hint: Can abbreviate locations and destinations down to the first 3 letters."}
      #SHOW {"   Example: riversail illian irinjavar or riversail ill iri"}
      #SHOW {""}
      #SHOW {" Type oceansail <starting location> <destination>"}
      #SHOW {"  Hint: Can abbreviate locations and destinations down to the first 3 letters."}
      #SHOW {"   Example: oceansail mayene tremalking or oceansail may tre"}
      #SHOW {""}
      #SHOW {" Note: Departing from Bandar Eban or departing from Tar Valon use only the first word in each name."}
      #SHOW {"  Example: riverSail tar tear or oceanSail bandar tanchico"}
      #SHOW {""}
      #SHOW {" Type oceanmap or rivermap"}
      #SHOW {"  Note: shows map of water routes, destinations, and boat names."}
      #SHOW {"   Feature: keeps track of ship movement as you progress on your trip, X marks the spot!"}
      #SHOW {""}
      #SHOW {" Type stopsailing"}
      #SHOW {"  Note: will deactivate the Sailing script if something goes wrong or your trip is interrupted."}
      #SHOW {""}
      }
   }
#ALIAS riverSail {
   #VAR sailOrigin {%copy(%1,1,3)}
   #VAR sailDestination {%copy(%2,1,3)}
   #VAR sailInput {%concat(@sailOrigin,@sailDestination)}
   #FORALL @sailRiverList {#IF (%copy(%i,1,3)=%proper(@sailOrigin)) {#VAR sailDepartureLocation {%i}} {}}
   #FORALL @sailRiverList {#IF (%copy(%i,1,3)=%proper(@sailDestination)) {#VAR sailArrivalLocation {%i}} {}}
   #VAR riverTripNotification {Current trip: "@sailDepartureLocation" to "@sailArrivalLocation".}
   #IF (%null(@sailDepartureLocation) OR %null(@sailArrivalLocation)) {
      #SHOW {%crlf Sorry Captain %char, we don't sail to %2 from %1...}
      sailStop
      } {
      #VAR sailIndex {1}
      #VAR sailTrip {%concat("@",@sailInput)}
      #VAR sailNextDirection {%item(@sailTrip,@sailIndex)}
      #VAR sailMoveShip {%item(@sailDir,@sailNextDirection)}
      #T+ {Sailing|RiverSail}
      #T+ {Sailing|SailorEmotes}
      #ALARM +.5 {
         #VAR sailShowMessage {%eval(%concat("@","sailMessage",%random(1,5)))}
         #SHOW {%crlf @sailShowMessage}
         #SAY {" Trip set: "@sailDepartureLocation to @sailArrivalLocation", type rivermap to view trip progress."}
         #SHOW {""}
         }
      }
   }
#ALIAS oceanSail {
   #VAR sailOrigin {%copy(%1,1,3)}
   #VAR sailDestination {%copy(%2,1,3)}
   #VAR sailInput {%concat(@sailOrigin,@sailDestination)}
   #FORALL @sailOceanList {#IF (%copy(%i,1,3)=%proper(@sailOrigin)) {#VAR sailDepartureLocation {%i}} {}}
   #FORALL @sailOceanList {#IF (%copy(%i,1,3)=%proper(@sailDestination)) {#VAR sailArrivalLocation {%i}} {}}
   #VAR oceanTripNotification {Current trip: "@sailDepartureLocation" to "@sailArrivalLocation".}
   #IF (%null(@sailDepartureLocation) OR %null(@sailArrivalLocation)) {
      #SHOW {%crlf Sorry Captain %char, we don't sail to %2 from %1...}
      sailStop
      } {
      #VAR sailIndex {1}
      #VAR sailTrip {%concat("@",@sailInput)}
      #VAR sailNextDirection {%item(@sailTrip,@sailIndex)}
      #VAR sailMoveShip {%item(@sailDir,@sailNextDirection)}
      #T+ {Sailing|OceanSail}
      #T+ {Sailing|SailorEmotes}
      #T+ {sailCaptainTrigger}
      #ALARM +.5 {
         #VAR sailShowMessage {%eval(%concat("@","sailMessage",%random(1,5)))}
         #SHOW {%crlf @sailShowMessage}
         #SAY {" Trip set: "@sailDepartureLocation to @sailArrivalLocation", type oceanmap to view trip progress."}
         #SHOW {""}
         }
      }
   }
#ALIAS stopSailing {
   #SAY {%crlf "Sailing script deactivated!"}
   sailStop
   }
#ALIAS sailStop {
   #VAR sailOrigin {}
   #VAR sailDestination {}
   #VAR sailInput {}
   #VAR sailTrip {}
   #VAR sailIndex {}
   #VAR sailNextDirection {}
   #VAR sailMoveShip {}
   #VAR sailArrivalLocation {}
   #VAR sailDepartureLocation {}
   #VAR oceanTripNotification {}
   #VAR riverTripNotification {}
   #T- {Sailing|RiverSail}
   #T- {Sailing|OceanSail}
   #T- {Sailing|SailorEmotes}
   }
#ALIAS sailEngine {
   #MATH sailIndex @sailIndex+1
   #VAR sailNextDirection {%item(@sailTrip,@sailIndex)}
   #VAR sailMoveShip {%item(@sailDir,@sailNextDirection)}
   #T- {sailCaptainTrigger}
   }
#ALIAS oceanMapStart {
   sailMapReset
   #VAR %concat("oceanOpen",%replace(@sailDepartureLocation," ","")) {"X"}
   }
#ALIAS sailEmote {#IF (%len(@sailMoveShip)) {@sailMoveShip} {}}
#ALIAS sailMapReset {
   #VAR ADockattheEdgeofthePier {~" ~"}
   #VAR ATarredTimberDock {~" ~"}
   #VAR CenterWharf {~" ~"}
   #VAR DocksOnTheAlguenyaRiver {~" ~"}
   #VAR EndofthePier {~" ~"}
   #VAR OnaLongDock {~" ~"}
   #VAR OnthePierofIsleJafar {~" ~"}
   #VAR OvergrownPlainsnearaSmallStream {~" ~"}
   #VAR Southharbor {~" ~"}
   #VAR StoneDocksofIllian {~" ~"}
   #VAR TheCityDocks {~" ~"}
   #VAR TheShoresoftheAryth {~" ~"}
   #VAR WatersEdgeontheCalpene {~" ~"}
   #VAR WhitebridgeDocks {~" ~"}
   #VAR oceanOpen {~" ~"}
   #VAR oceanOpenAltara {~" ~"}
   #VAR oceanOpenAmadicia {~" ~"}
   #VAR oceanOpenBandarEban {~" ~"}
   #VAR oceanOpenFalme {~" ~"}
   #VAR oceanOpenIllian {~" ~"}
   #VAR oceanOpenJafar {~" ~"}
   #VAR oceanOpenMayene {~" ~"}
   #VAR oceanOpenTanchico {~" ~"}
   #VAR oceanOpenTremalking {~" ~"}
   #VAR riverOpenAringill {~" ~"}
   #VAR riverOpenCairhien {~" ~"}
   #VAR riverOpenIllian {~" ~"}
   #VAR riverOpenIrinjavar {~" ~"}
   #VAR riverOpenTarValon {~" ~"}
   #VAR riverOpenTear {~" ~"}
   #VAR riverOpenWhitebridge {~" ~"}
   }
#VAR sailArrivalLocation {}
#VAR sailDepartureLocation {}
#VAR sailDestination {}
#VAR sailDir {sail north|sail east|sail south|sail west}
#VAR sailEmbarkRoom {}
#VAR sailIndex {}
#VAR sailInput {}
#VAR sailOceanList {Amadicia|Bandar Eban|Falme|Illian|Jafar|Mayene|Tanchico|Tear|Tremalking}
#VAR sailRiverList {Aringill|Cairhien|Illian|Irinjavar|Tar Valon|Tear|Whitebridge}
#VAR sailMapDestination {}
#VAR sailMessage1 {The shouts of sailor's curses can be heard as the "@sailShipName" prepares to depart "@sailDepartureLocation".}
#VAR sailMessage2 {A salty breeze whips across the deck as the "@sailShipName" prepares to depart "@sailDepartureLocation".}
#VAR sailMessage3 {Ropes creak and seagulls shriek as the "@sailShipName" prepares to depart "@sailDepartureLocation".}
#VAR sailMessage4 {The First Mate barks orders as the sailors prepare the "@sailShipName" to depart "@sailDepartureLocation".}
#VAR sailMessage5 {The "@sailShipName" shifts and begins to drift as the sailors release it from its moorage at "@sailDepartureLocation".}
#VAR sailMoveShip {}
#VAR sailNextDirection {}
#VAR sailOrigin {}
#VAR sailShipName {}
#VAR sailShowMessage {}
#VAR sailTrip {}
#VAR oceanTripNotification {}
#VAR riverTripNotification {}
#TRIGGER "sailEmbarkTrigger" {^{%char} steps off a gangplank unsteadily.$} {
   #T- {sailEmbarkTrigger}
   #T- {sailArglebargleTrigger}
   #T- {sailNotHereTrigger}
   #IF (%class(@sailEmbarkRoom)=-1) {} {#VAR %eval(@sailEmbarkRoom) {"X"}}
   } "" {case|disable}
#TRIGGER "sailDisembarkTrigger" {^Ok.$} {
   #T- {sailDisembarkTrigger}
   #T- {sailArglebargleTrigger}
   #VAR sailShipName {}
   #VAR sailEmbarkRoom {}
   sailMapReset
   sailStop
   } "" {case|disable}
#TRIGGER "sailNotHereTrigger" {^That ship is not here.$} {
   #T- {sailNotHereTrigger}
   #T- {sailEmbarkTrigger}
   #VAR sailShipName {}
   #VAR sailEmbarkRoom {}
   } "" {case|disable}
#TRIGGER "sailArglebargleTrigger" {Arglebargle, glop-glyf!?!$} {
   #T- {sailArglebargleTrigger}
   #T- {sailDisembarkTrigger}
   #T- {sailEmbarkTrigger}
   #T- {sailNotHereTrigger}
   } "" {case|disable}
#TRIGGER "sailCaptainTrigger" {^You're not the captain of this ship!$} {
   #T- {sailCaptainTrigger}
   sailStop
   #SAY {%crlf Forget to wear your Captain's Hat... erm, Captain %char?}
   #SHOW {""}
   } "" {case|disable}
#ONINPUT {^disembark$} {
   #T+ {sailDisembarkTrigger}
   #T+ {sailArglebargleTrigger}
   }
#ONINPUT {^embark ([a-z]*)$} {
   #T+ {sailEmbarkTrigger}
   #T+ {sailArglebargleTrigger}
   #T+ {sailNotHereTrigger}
   #VAR sailShipName {%proper(%1)}
   #IF (%numwords(@sailShipName)=2) {#VAR sailShipName {%concat(%proper(%word(@sailShipName,1))," ",%proper(%word(@sailShipName,2)))}} {}
   #IF (%numwords(@sailShipName)=3) {#VAR sailShipName {%concat(%proper(%word(@sailShipName,1))," ",%word(@sailShipName,2)," ",%proper(%word(@sailShipName,3)))}} {}
   #VAR sailEmbarkRoom {%replace(%replace(%replace(%roomname()," ",""),"'",""),"-","")}
   }
#CLASS 0
#CLASS {Sailing|RiverSail} {disable}
#TRIGGER {^Sweeps churning the water steer the ship onto the river.$} {
   sailMapReset
   #VAR %concat("riverOpen",%replace(@sailDepartureLocation," ","")) {"X"}
   sailEngine
   } "" {case}
#TRIGGER {^Ropes are pulled to adjust the sail as the ship sails north against the current.$} {
   #IF (@riverOpenAringill=X) {
      #VAR riverOpenAringill {~" ~"}
      #VAR riverOpenTarValon {"X"}
      } {}
   #IF (@riverOpenTear=X) {
      #VAR riverOpenTear {~" ~"}
      #VAR riverOpenAringill {"X"}
      } {}
   #IF (@riverOpenWhitebridge=X) {
      #VAR riverOpenWhitebridge {~" ~"}
      #VAR riverOpenIrinjavar {"X"}
      } {}
   #IF (@riverOpenIllian=X) {
      #VAR riverOpenIllian {~" ~"}
      #VAR riverOpenWhitebridge {"X"}
      } {}
   sailEngine
   } "" {case}
#TRIGGER {^Ropes are pulled to adjust the sail as the ship sails east against the current.$} {
   #VAR riverOpenAringill {~" ~"}
   #VAR riverOpenCairhien {"X"}
   sailEngine
   } "" {case}
#TRIGGER {^Ropes are pulled to adjust the sail as the ship sails south on the current.$} {
   #IF (@riverOpenAringill=X) {
      #VAR riverOpenAringill {~" ~"}
      #VAR riverOpenTear {"X"}
      } {}
   #IF (@riverOpenTarValon=X) {
      #VAR riverOpenTarValon {~" ~"}
      #VAR riverOpenAringill {"X"}
      } {}
   #IF (@riverOpenWhitebridge=X) {
      #VAR riverOpenWhitebridge {~" ~"}
      #VAR riverOpenIllian {"X"}
      } {}
   #IF (@riverOpenIrinjavar=X) {
      #VAR riverOpenIrinjavar {~" ~"}
      #VAR riverOpenWhitebridge {"X"}
      } {}
   sailEngine
   } "" {case}
#TRIGGER {^Ropes are pulled to adjust the sail as the ship sails west on the current.$} {
   #VAR riverOpenCairhien {~" ~"}
   #VAR riverOpenAringill {"X"}
   sailEngine
   } "" {case}
#TRIGGER {^Sails are lowered and sweeps steer the ship towards the Cairhien docks.$} {
   #VAR riverOpenCairhien {~" ~"}
   #VAR DocksOnTheAlguenyaRiver {"X"}
   #VAR sailMapDestination {DocksOnTheAlguenyaRiver}
   #SHOW {Welcome to Cairhien Captain %char, gateway to the Spine of the World and the Aiel Waste.}
   #SHOW {""}
   sailStop
   } "" {case}
#TRIGGER {^Sails are lowered and sweeps steer the ship towards the Tear docks.$} {
   #VAR riverOpenTear {~" ~"}
   #VAR TheCityDocks {"X"}
   #VAR sailMapDestination {TheCityDocks}
   #SHOW {The Stone still stands Captain %char, welcome to Tear.}
   #SHOW {""}
   sailStop
   } "" {case}
#TRIGGER {^Sails are lowered and sweeps steer the ship towards the Aringill docks.$} {
   #VAR riverOpenAringill {~" ~"}
   #VAR ATarredTimberDock {"X"}
   #VAR sailMapDestination {ATarredTimberDock}
   #SHOW {Welcome to Aringill Captain %char, largest port in Andor.}
   #SHOW {""}
   sailStop
   } "" {case}
#TRIGGER {^Sails are lowered and sweeps steer the ship into Southharbor.$} {
   #VAR riverOpenTarValon {~" ~"}
   #VAR Southharbor {"X"}
   #VAR sailMapDestination {Southharbor}
   #SHOW {The Shining Walls of Tar Valon await you Captain %char.}
   #SHOW {""}
   sailStop
   } "" {case}
#TRIGGER {^Sails are lowered and sweeps steer the ship towards the Illian docks.$} {
   #VAR riverOpenIllian {~" ~"}
   #VAR StoneDocksofIllian {"X"}
   #VAR sailMapDestination {StoneDocksofIllian}
   #SHOW {Welcome to Illian Captain %char, home to the Illian Companions.}
   #SHOW {""}
   sailStop
   } "" {case}
#TRIGGER {^Sails are lowered and sweeps steer the ship towards the Whitebridge docks.$} {
   #VAR riverOpenWhitebridge {~" ~"}
   #VAR WhitebridgeDocks {"X"}
   #VAR sailMapDestination {WhitebridgeDocks}
   #SHOW {They say it was created in the Age of Legends Captain %char, welcome to Whitebridge.}
   #SHOW {""}
   sailStop
   } "" {case}
#TRIGGER {^Sails are lowered and sweeps steer the ship towards the Irinjavar shoreline.$} {
   #VAR riverOpenIrinjavar {~" ~"}
   #VAR OvergrownPlainsnearaSmallStream {"X"}
   #VAR sailMapDestination {OvergrownPlainsnearaSmallStream}
   #SHOW {Welcome to Saldaea Captain %char, Maradon lies to the north.}
   #SHOW {""}
   sailStop
   } "" {case}
#CLASS 0
#CLASS {Sailing|OceanSail} {disable}
#TRIGGER {^Sweeps steer the ship away from the beach.$} {
   sailEngine
   oceanMapStart
   } "" {case}
#TRIGGER {^Sweeps steer the ship out of the harbor.$} {
   sailEngine
   oceanMapStart
   } "" {case}
#TRIGGER {^Sweeps steer the ship out of the cove.$} {
   sailEngine
   oceanMapStart
   } "" {case}
#TRIGGER {^Sweeps steer the ship away from the shore.$} {
   sailEngine
   oceanMapStart
   } "" {case}
#TRIGGER {^The ship sails north.$} {
   sailEngine
   #IF (@oceanOpenFalme=X) {
      #VAR oceanOpenFalme {~" ~"}
      #VAR oceanOpenBandarEban {"X"}
      } {}
   #IF (@oceanOpenTanchico=X) {
      #VAR oceanOpenTanchico {~" ~"}
      #VAR oceanOpenFalme {"X"}
      } {}
   #IF (@oceanOpenAmadicia=X) {
      #VAR oceanOpenAmadicia {~" ~"}
      #VAR oceanOpenTanchico {"X"}
      } {}
   } "" {case}
#TRIGGER {^The ship sails east.$} {
   sailEngine
   #IF (@oceanOpenTear=X) {
      #VAR oceanOpenTear {~" ~"}
      #VAR oceanOpenMayene {"X"}
      } {}
   #IF (@oceanOpen=X) {
      #VAR oceanOpen {~" ~"}
      #VAR oceanOpenTear {"X"}
      } {}
   #IF (@oceanOpenIllian=X) {
      #VAR oceanOpenIllian {~" ~"}
      #VAR oceanOpen {"X"}
      } {}
   #IF (@oceanOpenAltara=X) {
      #VAR oceanOpenAltara {~" ~"}
      #VAR oceanOpenIllian {"X"}
      } {}
   #IF (@oceanOpenAmadicia=X) {
      #VAR oceanOpenAmadicia {~" ~"}
      #VAR oceanOpenAltara {"X"}
      } {}
   #IF (@oceanOpenTremalking=X) {
      #VAR oceanOpenTremalking {~" ~"}
      #VAR oceanOpenAmadicia {"X"}
      } {}
   #IF (@oceanOpenJafar=X) {
      #VAR oceanOpenJafar {~" ~"}
      #VAR oceanOpenFalme {"X"}
      } {}
   } "" {case}
#TRIGGER {^The ship sails south.$} {
   sailEngine
   #IF (@oceanOpenTanchico=X) {
      #VAR oceanOpenTanchico {~" ~"}
      #VAR oceanOpenAmadicia {"X"}
      } {}
   #IF (@oceanOpenFalme=X) {
      #VAR oceanOpenFalme {~" ~"}
      #VAR oceanOpenTanchico {"X"}
      } {}
   #IF (@oceanOpenBandarEban=X) {
      #VAR oceanOpenBandarEban {~" ~"}
      #VAR oceanOpenFalme {"X"}
      } {}
   } "" {case}
#TRIGGER {^The ship sails west.$} {
   sailEngine
   #IF (@oceanOpenAmadicia=X) {
      #VAR oceanOpenAmadicia {~" ~"}
      #VAR oceanOpenTremalking {"X"}
      } {}
   #IF (@oceanOpenAltara=X) {
      #VAR oceanOpenAltara {~" ~"}
      #VAR oceanOpenAmadicia {"X"}
      } {}
   #IF (@oceanOpenIllian=X) {
      #VAR oceanOpenIllian {~" ~"}
      #VAR oceanOpenAltara {"X"}
      } {}
   #IF (@oceanOpen=X) {
      #VAR oceanOpen {~" ~"}
      #VAR oceanOpenIllian {"X"}
      } {}
   #IF (@oceanOpenTear=X) {
      #VAR oceanOpenTear {~" ~"}
      #VAR oceanOpen {"X"}
      } {}
   #IF (@oceanOpenMayene=X) {
      #VAR oceanOpenMayene {~" ~"}
      #VAR oceanOpenTear {"X"}
      } {}
   #IF (@oceanOpenFalme=X) {
      #VAR oceanOpenFalme {~" ~"}
      #VAR oceanOpenJafar {"X"}
      } {}
   } "" {case}
#TRIGGER {^The ship sails into the harbor of Mayene.$} {
   #VAR oceanOpenMayene {~" ~"}
   #VAR OnaLongDock {"X"}
   #SHOW {Welcome to Mayene Captain %char, home to the Winged Guard.}
   #SHOW {""}
   sailStop
   } "" {case}
#TRIGGER {^The ship sails towards the shore of Tremalking.$} {
   #VAR oceanOpenTremalking {~" ~"}
   #VAR ADockattheEdgeofthePier {"X"}
   #SHOW {Welcome to Tremalking Captain %char, home of the Sea Folk city of Samarin.}
   #SHOW {""}
   sailStop
   } "" {case}
#TRIGGER {^The ship sails into the harbor of Tear.$} {
   #VAR oceanOpenTear {~" ~"}
   #VAR TheCityDocks {"X"}
   #SHOW {We made it through the Fingers of the Dragon Captain %char, welcome to Tear!}
   #SHOW {""}
   sailStop
   } "" {case}
#TRIGGER {^The ship sails towards Falme.$} {
   #VAR oceanOpenFalme {~" ~"}
   #VAR CenterWharf {"X"}
   #SHOW {We have arrived at the Seanchan controlled city of Falme Captain %char.}
   #SHOW {""}
   sailStop
   } "" {case}
#TRIGGER {^The ship sails towards Bandar Eban.$} {
   #VAR oceanOpenBandarEban {~" ~"}
   #VAR EndofthePier {"X"}
   #SHOW {The home of the Sword and Hand, welcome to Bandar Eban Captain %char.}
   #SHOW {""}
   sailStop
   } "" {case}
#TRIGGER {^The ship sails towards the shore of Jafar.$} {
   #VAR oceanOpenJafar {~" ~"}
   #VAR OnthePierofIsleJafar {"X"}
   #SHOW {Welcome to Jafar Captain %char, The Seanchan call it Aile Jafar.}
   #SHOW {""}
   sailStop
   } "" {case}
#TRIGGER {^The ship sails into a sheltered cove.$} {
   #VAR oceanOpenAmadicia {~" ~"}
   #VAR TheShoresoftheAryth {"X"}
   #SHOW {We are here Captain %char, east of Windbitter's Finger on the Shadow Coast!}
   #SHOW {""}
   sailStop
   } "" {case}
#TRIGGER {^The ship sails towards the shore of Illian.$} {
   #VAR oceanOpenIllian {~" ~"}
   #VAR StoneDocksofIllian {"X"}
   #SHOW {The Hunt for the Horn of Valere starts in Illian, good luck Captain %char!}
   #SHOW {""}
   sailStop
   } "" {case}
#TRIGGER {^The ship sails east to the docks of Tanchico.$} {
   #VAR oceanOpenTanchico {~" ~"}
   #VAR WatersEdgeontheCalpene {"X"}
   #SHOW {The Seanchan and Civil Watch battle openly here in the streets of Tanchico Captain %char.}
   #SHOW {""}
   sailStop
   } "" {case}
#CLASS 0
#CLASS {Sailing|SailorEmotes} {disable}
#TRIGGER {A sailor calls out as he sees a giant fish alongside the ship.} {sailEmote} "" {case|verbatim}
#TRIGGER {A sailor calls out the depth of the river.} {sailEmote} "" {case|verbatim}
#TRIGGER {A sailor climbs into the ship's mast and looks out over the water.} {sailEmote} "" {case|verbatim}
#TRIGGER {A sailor hauls up a bucket of fresh water and splashes it across the deck.} {sailEmote} "" {case|verbatim}
#TRIGGER {A sailor leans on the ship's railing and looks across the water.} {sailEmote} "" {case|verbatim}
#TRIGGER {A sailor neatly coils a rope on the front deck.} {sailEmote} "" {case|verbatim}
#TRIGGER {A sailor sings hoarsely as he works.} {sailEmote} "" {case|verbatim}
#TRIGGER {A sailor stuffs his pipe with tabac and lights it.} {sailEmote} "" {case|verbatim}
#TRIGGER {A sailor takes a mop and starts scrubbing the deck.} {sailEmote} "" {case|verbatim}
#CLASS 0
#CLASS {Sailing|OceanVariables}
#VAR amaban {1|1|1|1|2}
#VAR amafal {1|1|1|2}
#VAR amaill {1|2|2|1}
#VAR amajaf {1|1|1|4|3}
#VAR amamay {1|2|2|2|2|2|1}
#VAR amatan {1|1|2}
#VAR amatea {1|2|2|2|2|1}
#VAR amatre {1|4|3}
#VAR banama {4|3|3|3|3}
#VAR banfal {4|3|2}
#VAR banill {4|3|3|3|2|2|1}
#VAR banjaf {4|3|4|3}
#VAR banmay {4|3|3|3|2|2|2|2|2|1}
#VAR bantan {4|3|3|2}
#VAR bantea {4|3|3|3|2|2|2|2|1}
#VAR bantre {4|3|3|3|4|3}
#VAR falama {4|3|3|3}
#VAR falban {4|1|2}
#VAR falill {4|3|3|2|2|1}
#VAR faljaf {4|4|3}
#VAR falmay {4|3|3|2|2|2|2|2|1}
#VAR faltan {4|3|2}
#VAR faltea {4|3|3|2|2|2|2|1}
#VAR faltre {4|3|3|4|3}
#VAR illama {3|4|4|3}
#VAR illban {3|4|4|1|1|1|2}
#VAR illfal {3|4|4|1|1|2}
#VAR illjaf {3|4|4|1|1|4|3}
#VAR illmay {3|2|2|2|1}
#VAR illtan {3|4|4|1|2}
#VAR illtea {3|2|2|1}
#VAR illtre {3|4|4|4|3}
#VAR jafama {1|2|3|3|3}
#VAR jafban {1|2|1|2}
#VAR jaffal {1|2|2}
#VAR jafill {1|2|3|3|2|2|1}
#VAR jafmay {1|2|3|3|2|2|2|2|2|1}
#VAR jaftan {1|2|3|2}
#VAR jaftea {1|2|3|3|2|2|2|2|1}
#VAR jaftre {1|2|3|3|4|3}
#VAR mayama {3|4|4|4|4|4|3}
#VAR mayban {3|4|4|4|4|4|1|1|1|2}
#VAR mayfal {3|4|4|4|4|4|1|1|2}
#VAR mayill {3|4|4|4|1}
#VAR mayjaf {3|4|4|4|4|4|1|1|4|3}
#VAR maytan {3|4|4|4|4|1|2}
#VAR maytea {3|4|1}
#VAR maytre {3|4|4|4|4|4|4|3}
#VAR tanama {4|3|3}
#VAR tanban {4|1|1|2}
#VAR tanfal {4|1|2}
#VAR tanill {4|3|2|2|1}
#VAR tanjaf {4|1|4|3}
#VAR tanmay {4|3|2|2|2|2|2|1}
#VAR tantea {4|3|2|2|2|2|1}
#VAR tantre {4|3|4|3}
#VAR teaama {3|4|4|4|4|3}
#VAR teaban {3|4|4|4|4|1|1|1|2}
#VAR teafal {3|4|4|4|4|1|1|2}
#VAR teaill {3|4|4|1}
#VAR teajaf {3|4|4|4|4|1|1|4|3}
#VAR teamay {3|2|1}
#VAR teatan {3|4|4|4|1|2}
#VAR teatre {3|4|4|4|4|4|3}
#VAR treama {1|2|3}
#VAR treban {1|2|1|1|1|2}
#VAR trefal {1|2|1|1|2}
#VAR treill {1|2|2|2|1}
#VAR trejaf {1|2|1|1|4|3}
#VAR tremay {1|2|2|2|2|2|2|1}
#VAR tretan {1|2|1|2}
#VAR tretea {1|2|2|2|2|2|1}
#CLASS 0
#CLASS {Sailing|RiverVariables}
#VAR aricai {2|2|1}
#VAR aritar {2|1|1}
#VAR aritea {2|3|3}
#VAR caiari {3|4|4}
#VAR caitar {3|4|1|1}
#VAR caitea {3|4|3|3}
#VAR illiri {1|1|1|1}
#VAR illwhi {1|1|2}
#VAR iriill {3|3|3|3}
#VAR iriwhi {3|3|2}
#VAR tarari {3|3|4}
#VAR tarcai {3|3|2|1}
#VAR tartea {3|3|3|3}
#VAR teaari {1|1|4}
#VAR teacai {1|1|2|1}
#VAR teatar {1|1|1|1}
#VAR whiill {4|3|3}
#VAR whiiri {4|1|1}
#CLASS 0
#CLASS {Sailing|MapVariables}
#VAR ADockattheEdgeofthePier {~" ~"} {~" ~"}
#VAR ATarredTimberDock {~" ~"} {~" ~"}
#VAR CenterWharf {~" ~"} {~" ~"}
#VAR DocksOnTheAlguenyaRiver {~" ~"} {~" ~"}
#VAR EndofthePier {~" ~"} {~" ~"}
#VAR OnaLongDock {~" ~"} {~" ~"}
#VAR OnthePierofIsleJafar {~" ~"} {~" ~"}
#VAR OvergrownPlainsnearaSmallStream {~" ~"} {~" ~"}
#VAR Southharbor {~" ~"} {~" ~"}
#VAR StoneDocksofIllian {~" ~"} {~" ~"}
#VAR TheCityDocks {~" ~"} {~" ~"}
#VAR TheShoresoftheAryth {~" ~"} {~" ~"}
#VAR WatersEdgeontheCalpene {~" ~"} {~" ~"}
#VAR WhitebridgeDocks {~" ~"} {~" ~"}
#VAR oceanOpen {~" ~"} {~" ~"}
#VAR oceanOpenAltara {~" ~"} {~" ~"}
#VAR oceanOpenAmadicia {~" ~"} {~" ~"}
#VAR oceanOpenBandarEban {~" ~"} {~" ~"}
#VAR oceanOpenFalme {~" ~"} {~" ~"}
#VAR oceanOpenIllian {~" ~"} {~" ~"}
#VAR oceanOpenJafar {~" ~"} {~" ~"}
#VAR oceanOpenMayene {~" ~"} {~" ~"}
#VAR oceanOpenTanchico {~" ~"} {~" ~"}
#VAR oceanOpenTear {~" ~"} {~" ~"}
#VAR oceanOpenTremalking {~" ~"} {~" ~"}
#VAR riverOpenAringill {~" ~"} {~" ~"}
#VAR riverOpenCairhien {~" ~"} {~" ~"}
#VAR riverOpenIllian {~" ~"} {~" ~"}
#VAR riverOpenIrinjavar {~" ~"} {~" ~"}
#VAR riverOpenTarValon {~" ~"} {~" ~"}
#VAR riverOpenTear {~" ~"} {~" ~"}
#VAR riverOpenWhitebridge {~" ~"} {~" ~"}
#CLASS 0
#CLASS {Sailing|OceanMap}
#ALIAS oceanMap {
   #SHOW {""}
   #SHOW {""}
   #SHOW {" <font size=7>Ports of the Aryth Ocean and the Sea of Storms</font>"}
   #SHOW {""}
   #SHOW {"            ["@oceanOpenBandarEban"]---["@EndofthePier"]                               Ocean Vessels"}
   #SHOW {"             ¦  Bandar Eban                         -------------"}
   #SHOW {"             ¦                                      Black Swan"}
   #SHOW {"             ¦                                      Dauntless"}
   #SHOW {"      ["@oceanOpenJafar"]---["@oceanOpenFalme"]---["@CenterWharf"] Falme                         Golden Tree"}
   #SHOW {"       ¦     ¦                                      Horn of Valere"}
   #SHOW {"      ["@OnthePierofIsleJafar"]    ¦                                      Silverpike"}
   #SHOW {"     Jafar   ¦  Tanchico                            Silver Sword"}
   #SHOW {"            ["@oceanOpenTanchico"]---["@WatersEdgeontheCalpene"]                               Victory of Jafar"}
   #SHOW {"             ¦         Illian      Tear  Mayene     Windchaser"}
   #SHOW {"             ¦          ["@StoneDocksofIllian"]         ["@TheCityDocks"]   ["@OnaLongDock"]"}
   #SHOW {"             ¦           ¦           ¦     ¦        Clan Vessels"}
   #SHOW {"             ¦           ¦           ¦     ¦        -------------"}
   #SHOW {"      ["@oceanOpenTremalking"]---["@oceanOpenAmadicia"]---["@oceanOpenAltara"]---["@oceanOpenIllian"]---["@oceanOpen"]---["@oceanOpenTear"]---["@oceanOpenMayene"]       Golden Bee (Illian)"}
   #SHOW {"       ¦     ¦                                      Golden Hawk (Mayene)"}
   #SHOW {"       ¦    ["@TheShoresoftheAryth"] Amadicia                            Silver Crescent (Tear)"}
   #SHOW {"      ["@ADockattheEdgeofthePier"]"}
   #SHOW {"   Tremalking"}
   #SHOW {""}
   #SAY {"       "@oceanTripNotification" "}
   #SHOW {""}
   }
#CLASS 0
#CLASS {Sailing|RiverMap}
#ALIAS riverMap {
   #SHOW {""}
   #SHOW {""}
   #SHOW {" <font size=7>Ports of The River Arinelle and The River Erinin</font>"}
   #SHOW {""}
   #SHOW {"   River Arinelle"}
   #SHOW {"   --------------       ["@OvergrownPlainsnearaSmallStream"] Irinjavar      Tar Valon ["@Southharbor"]"}
   #SHOW {"   Swallow               ¦                            ¦"}
   #SHOW {"   Kingfisher            ¦                            ¦    Cairhien"}
   #SHOW {"   Hummingbird          ["@riverOpenIrinjavar"]                          ["@riverOpenTarValon"]     ["@DocksOnTheAlguenyaRiver"]"}
   #SHOW {"   Starling*             ¦                            ¦       ¦"}
   #SHOW {"                         ¦  Whitebridge               ¦       ¦"}
   #SHOW {"   River Erinin         ["@riverOpenWhitebridge"]-----["@WhitebridgeDocks"]          ["@ATarredTimberDock"]-----["@riverOpenAringill"]-----["@riverOpenCairhien"]"}
   #SHOW {"   --------------        ¦                 Aringill   ¦"}
   #SHOW {"   River Flame           ¦                            ¦"}
   #SHOW {"   River Sun            ["@riverOpenIllian"]                          ["@riverOpenTear"]"}
   #SHOW {"   River Queen           ¦                            ¦"}
   #SHOW {"   River Stork           ¦                            ¦"}
   #SHOW {"   River Lady*          ["@StoneDocksofIllian"] Illian              Tear ["@TheCityDocks"]"}
   #SHOW {""}
   #SAY {"       "@riverTripNotification" "}
   #SHOW {""}
   }
#CLASS 0

_________________
House of Medakan zMUD Scripts: Table of Contents

House of Medakan cMUD Scripts: Table of Contents


Last edited by Taziar on Sat Aug 25, 2018 1:35 am, edited 12 times in total.

Top
 Profile  
 
 Post subject: Re: HoM zMUD Scripts
PostPosted: Tue Apr 18, 2017 3:19 pm 
Offline

Joined: Tue Apr 07, 2015 8:24 pm
Posts: 132
Location: Seattle
Type helpTicBar to view help file in client.

Image

Direct download link: TicBarHoM.txt

TicBar Zone Pattern Optional Add-on

Active Triggers: 84/145
Input Triggers: 4
Code:
#CLASS {TicBar}
#ALIAS helpTicBar {
   #PRIORITY {
      #SAY {%crlf "-----TicBar Help File-----"}
      #SAY {"    [Released: 7/20/2018]"}
      #SHOW {" Tic display message option must be turned on!"}
      #SHOW {"  Note: timeout margin of 3 seconds recommended."}
      #SHOW {""}
      #SHOW {" Automatically synchronizes your tick timer on recognizable mud output."}
      #SHOW {" Creates an average over time when sequential tic notifications are detected."}
      #SHOW {"  Note: Consecutive tic messages from the mud will keep tic timer the most accurate."}
      #SHOW {"   Hint: staying in a state of flee lag will result in the calms message at tic."}
      #SHOW {""}
      #SHOW {" Type ticData to view current tic statistics."}
      #SHOW {""}
      #SHOW {" Status Bar positions can be toggled on/off per user preference (all defaults: on)."}
      #SHOW {"  Type toggleBar <type> to turn <type> position on/off."}
      #SHOW {"   Available types:"}
      #SHOW {"    Mood"}
      #SHOW {"    Posture  (Posture hidden until detected)"}
      #SHOW {"    HP"}
      #SHOW {"    AP       (SP/DP hidden until detected)"}
      #SHOW {"    MV"}
      #SHOW {"    FL       (Flee Lag counter)"}
      #SHOW {"    CP       (Charge Pulse counter)"}
      #SHOW {"    Notice"}
      #SHOW {"    Sneak"}
      #SHOW {"    Source   (Source hidden until detected)"}
      #SHOW {"    Exit"}
      #SHOW {"    Effect   (Effects not shown: "%replace(@barExclusionList,|,", ")")"}
      #SHOW {""}
      #SHOW {"  Bar Position Locations:"}
      #SHOW {" Mood-Posture-HP-(SP/DP)-MV-FL-CP-Notice-Sneak-Source-Exit-Effect"}
      #SHOW {""}
      #SHOW {" Type barFont <font> to change the Bar font type."}
      #SHOW {"  Note: only single word font names allowed."}
      #SHOW {""}
      }
   }
#ALIAS ticData {
   #IF (%null(@ticTimeList)) {
      #SAY {%crlf Sorry, insufficient tic data gathered...}
      #SAY {%lf Note: flee 2-4 times for 2 consecutive tics.}
      #SAY {%lf This will give consecutive calms messages to accurately create data.}
      } {
      #SAY {%crlf Minimum tic time: %min(%replace(@ticTimeList,"|",",")) seconds.}
      #SAY {%lf Average tic time: %copy(@ticAve(@ticTimeList),1,5) seconds.}
      #SAY {%lf Maximum tic time: %max(%replace(@ticTimeList,"|",",")) seconds.}
      #SAY {%lf Total number of consecutive recorded tics: %eval(%numitems(@ticTimeList)-1)}
      }
   }
#ALIAS ticOnTicAlias {
   #T- {ticOnTicAlias}
   #VAR ticFleeLag {@barFleeLag}
   #VAR barFleeLag {%eval(@ticFleeLag/@barWilFactor)}
   #VAR ticFleeLag {@barFleeLag}
   barDisplayAlias
   }
#ALIAS toggleBar {
   #IF (%null(%1)) {
      #SAY {%crlf "Usage: toggleBar <type> to toggle bar position on/off."}
      #SAY {"  Available types:"}
      #LOOP 1,13 {#SAY {"   "%if(%len(%i)>2,%proper(%i),%upper(%i))}}
      #ABORT 1
      } {}
   #IF (%ismember(%lower(%1),@showBarList)) {
      #IF (%eval(%concat("@showBar",%1))) {
         #VAR %concat(showBar,%1) {0}
         #SAY {%crlf TicBar %if(%len(%1)>2,%proper(%1),%upper(%1)) position enabled.}
         #T+ {%concat(TicBar,%1)}
         } {
         #VAR %concat(showBar,%1) {1}
         #SAY {%crlf TicBar %if(%len(%1)>2,%proper(%1),%upper(%1)) position disabled.}
         #T- {%concat(TicBar,%1)}
         }
      } {#SAY {%crlf Not a valid type selection...}}
   }
#ALIAS barFont {
   #IF (%null(%1)) {
      #SAY {%crlf Usage: barFont <font>}
      #SAY {"  "Current font: @barFont}
      } {
      #VAR barFont {%1}
      #SAY {%crlf Bar font changed to: @barFont}
      }
   }
#ALIAS barNotice {#IF (%1) {#VAR barNoticeColor {lime}} {#VAR barNoticeColor {dimgray}}}
#ALIAS barSneak {#IF (%1) {#VAR barSneakColor {lime}} {#VAR barSneakColor {dimgray}}}
#ALIAS barSource {#IF (%1) {#VAR barSourceColor {lime}} {#VAR barSourceColor {dimgray}}}
#ALIAS barMood {
   #IF (@showBarMood) {#T+ {TicBarMood}} {#T- {TicBarMood}}
   #IF (%1=Wimpy) {
      #VAR barMood {WIMPY}
      #VAR barMoodColor {lightblue}
      } {}
   #IF (%1=Normal) {
      #VAR barMood {NORMAL}
      #VAR barMoodColor {steelblue}
      } {}
   #IF (%1=Brave) {
      #VAR barMood {BRAVE}
      #VAR barMoodColor {goldenrod}
      } {}
   #IF (%1=Berserk) {
      #VAR barMood {BERSERK}
      #VAR barMoodColor {red}
      } {}
   }
#ALIAS barPosture {
   #IF (%1) {#IF (@showBarPosture) {#T+ {TicBarPosture}} {}} {#T- {TicBarPosture}}
   #IF (%1=Defensive) {
      #VAR barPosture {DEFENSE}
      #VAR barPostureColor {lightblue}
      } {}
   #IF (%1=Normal) {
      #VAR barPosture {NORMAL}
      #VAR barPostureColor {steelblue}
      } {}
   #IF (%1=Offensive) {
      #VAR barPosture {OFFENSE}
      #VAR barPostureColor {goldenrod}
      } {}
   }
#ALIAS barWilColor2 {
   #IF (@barFleeLag>3) {#VAR barFleeLagColor {red}} {
      #VAR barFleeLagColor {orange}
      #IF (@barFleeLag<2) {#VAR barFleeLagColor {white}} {}
      }
   }
#ALIAS barWilColor3 {
   #IF (@barFleeLag>8) {#VAR barFleeLagColor {red}} {
      #VAR barFleeLagColor {orange}
      #IF (@barFleeLag<3) {#VAR barFleeLagColor {white}} {}
      }
   }
#ALIAS barWilColor4 {
   #IF (@barFleeLag>15) {#VAR barFleeLagColor {red}} {
      #VAR barFleeLagColor {orange}
      #IF (@barFleeLag<4) {#VAR barFleeLagColor {white}} {}
      }
   }
#ALIAS barDisplayAlias {
   #VAR barChargePulse {%eval(@barFleeLag+7)}
   #IF (@barChargePulse>12) {#VAR barChargePulse {12}} {}
   #IF (@barChargePulse=12) {
      #VAR barChargePulseColor {red}
      } {
      #VAR barChargePulseColor {orange}
      #IF (@barChargePulse=7) {#VAR barChargePulseColor {white}} {}
      }
   #IF (@barWilFactor=2) {barWilColor2} {}
   #IF (@barWilFactor=3) {barWilColor3} {}
   #IF (@barWilFactor=4) {barWilColor4} {}
   }
#FUNCTION ticAve {%eval(%float(%eval(%replace(%1,"|","+")))/%numitems(%1))}
#FUNCTION barHelpMXP {<color %1 black> %2</color><color %3 black> %4</color><color %5 black> %6 </color>}
#FUNCTION barMXP1 {<font @barFont 10><color %1> %2 </color></font>}
#FUNCTION barMXP2 {<font @barFont 10><color %1> %2</color><color %3>:</color><color %4> %5</color><color %6>%7 </color></font>}
#FUNCTION barMXP3 {<font @barFont 10><color %1> %2</color><color %3>:</color><color %4> %5 </color></font>}
#FUNCTION barMXP4 {<font @barFont 10><color %1> %2</color><color %3> %4</color><color %5> %6</color><color %7> %8 </color></font>}
#FUNCTION barMXP5 {<font @barFont 10><color %1> %2 </color></font>}
#VAR ticFleeInput {0} {0}
#VAR ticFleeLag {0}
#VAR ticIN {}
#VAR ticINAlarm {}
#VAR ticINCount {0}
#VAR ticTime {63}
#VAR ticTimeAverage {} {}
#VAR ticTimeConnection {0} {0}
#VAR ticTimeConnection2 {0} {0}
#VAR ticTimeLength {}
#VAR ticTimeList {} {}
#VAR barAbilityCond {Bursting}
#VAR barAbilityType {} {}
#VAR barCON {}
#VAR barChargePulse {7}
#VAR barChargePulseColor {white}
#VAR barColorAP {red} {red}
#VAR barColorFL {red} {red}
#VAR barColorHP {red} {red}
#VAR barColorMV {red} {red}
#VAR barCurrentAP {}
#VAR barCurrentHP {}
#VAR barCurrentMV {}
#VAR barDEX {}
#VAR barExclusionList {CURE POISON|DARK VISION|NOTICE|NO QUIT|SNEAK|SOURCE|WARDER BOND}
#VAR barExitList {}
#VAR barEffectsList {}
#VAR barEffectsDisplay {}
#VAR barFleeLag {0}
#VAR barFleeLagColor {white}
#VAR barFont {Consolas}
#VAR barHitCond {Healthy}
#VAR barINT {}
#VAR barMaxAP {}
#VAR barMaxHP {}
#VAR barMaxMV {}
#VAR barMood {}
#VAR barMoodColor {}
#VAR barMoveCond {Fresh}
#VAR barNoticeColor {dimgray}
#VAR barPosture {}
#VAR barPostureColor {black}
#VAR barPrevAbilityCond {}
#VAR barPrevHitCond {}
#VAR barPrevMoveCond {}
#VAR barSTR {}
#VAR barSneakColor {dimgray}
#VAR barSourceColor {dimgray}
#VAR barWIL {}
#VAR barWilFactor {0}
#VAR showBarAP {1}
#VAR showBarCharge {1}
#VAR showBarDoor {1}
#VAR showBarExit {1}
#VAR showBarEffect {1}
#VAR showBarFlee {1}
#VAR showBarHP {1}
#VAR showBarList {mood|posture|hp|ap|mv|fl|cp|notice|sneak|source|exit|effect}
#VAR showBarMV {1}
#VAR showBarMood {1}
#VAR showBarNotice {1}
#VAR showBarPosture {1}
#VAR showBarSneak {1}
#VAR showBarSource {1}
#TRIGGER "ticINTrigger" {TICK IN &ticIN SECONDS.$} {
   #T+ {ticOnTicAlias}
   #IF (%class(TicBar|TicPatternZones)=0) {#T+ {TicBar|TicPatternZones}} {}
   #VAR ticINCount {1}
   #VAR ticINAlarm {%eval(@ticIN+@ticIN)}
   #ALARM "ticINAlarm" {+@ticINAlarm} {
      #IF (@ticINCount) {
         #IF (%class(ticOnTicAlias)) {ticOnTicAlias} {}
         } {}
      } "TicBar"
   } "" {case}
#TRIGGER "ticBarTrigger" {Timer now at &ticTime secs.$} {
   #T- {ticBarTrigger}
   #T- {ticHungryTrigger}
   #T- {ticThirstyTrigger}
   #T- {TicBar|TicPatterns}
   #IF (%class(TicBar|TicPatternZones)=1) {#T- {TicBar|TicPatternZones}} {}
   #IF (%class(ticOnTicAlias)=1) {ticOnTicAlias} {}
   #VAR ticINCount {0}
   #VAR ticTimeConnection {%ctime}
   #MATH ticTimeLength {@ticTimeConnection-@ticTimeConnection2}
   #VAR ticTimeConnection2 {%ctime}
   #IF (@ticTimeLength<70 AND @ticTimeLength>59) {
      #VAR ticTimeList {%additem(@ticTimeLength,@ticTimeList)}
      #VAR ticTimeAverage {%copy(@ticAve(@ticTimeList),1,2)}
      } {}
   #IF (@ticTime>69 OR @ticTime<60) {
      #IF (%null(@ticTimeList)) {#TSET {63}} {#TSET {@ticTimeAverage}}
      } {}
   #ALARM "TicBarAlarm" {+1} {
      #T+ {ticBarTrigger}
      #T+ {ticHungryTrigger}
      #T+ {ticThirstyTrigger}
      #T+ {TicBar|TicPatterns}
      #IF (%class(TicBar|TicPatternZones)=1) {#T- {TicBar|TicPatternZones}} {}
      } "TicBar"
   } "" {case}
#TRIGGER "ticRankTrigger" {^This ranks you as } {
   #T- {ticHungryTrigger}
   #T- {ticThirstyTrigger}
   #T+ {ticRanksPrompt}
   } "" {case}
#TRIGGER "ticRanksPrompt" {^{*|o} * >} {
   #T- {ticRanksPrompt}
   #T+ {ticHungryTrigger}
   #T+ {ticThirstyTrigger}
   } "" {case|disable|nocr|prompt}
#TRIGGER "ticHungryTrigger" {You are hungry.$} {#TSET} "" {case}
#TRIGGER "ticThirstyTrigger" {You are thirsty.$} {#TSET} "" {case}
#TRIGGER "ticHeelsTrigger" {You flee head over heels.$} {
   #IF (@ticFleeInput=1) {#T- {TicBar|TicFleeInput}} {}
   #IF (@ticFleeInput>0) {#ADD ticFleeInput -1} {}
   #IF (%class(TicBar|TicFleeInput)=1 AND @ticFleeInput=0) {#T- {ticFleeRoomColor}}
   #ADD barFleeLag 1
   barDisplayAlias
   #T+ {ticOnTicAlias}
   } "" {case}
#TRIGGER "ticPanicTrigger" {PANIC!  You couldn't escape!$} {
   #IF (@ticFleeInput=1) {#T- {TicBar|TicFleeInput}} {}
   #IF (@ticFleeInput>0) {#ADD ticFleeInput -1} {}
   #IF (%class(TicBar|TicFleeInput)=1 AND @ticFleeInput=0) {#T- {ticFleeRoomColor}}
   #ADD barFleeLag 1
   barDisplayAlias
   #T+ {ticOnTicAlias}
   } "" {case}
#TRIGGER "barRentedTrigger" {You were rented for } {
   #T- {barRentedTrigger}
   #T- {barReconnectedTrigger}
   #VAR ticFleeLag {0}
   #VAR barFleeLag {0}
   barMood wimpy
   barNotice 0
   barPosture 0
   barSneak 0
   barSource 0
   } "" {case|disable|verbatim}
#TRIGGER "barReconnectedTrigger" {^Reconnecting.$} {
   #T- {barReconnectedTrigger}
   #T- {barRentedTrigger}
   } "" {case|disable}
#TRIGGER "barStatTrigger" {^Your base abilities are: Str:&%dbarSTR Int:&%dbarINT Wil:&%dbarWIL Dex:&%dbarDEX Con:&%dbarCON} {
   #T- {barStatTrigger}
   #VAR barWilFactor {0}
   #IF (@barWIL>0) {#ADD barWilFactor 2} {}
   #IF (@barWIL>11) {#ADD barWilFactor 1} {}
   #IF (@barWIL>15) {#ADD barWilFactor 1} {}
   #VAR barColorFL {white}
   } "" {case|disable}
#TRIGGER "barDeadTrigger" {^You are dead!  Sorry...$} {
   #VAR ticFleeLag {0}
   #VAR barFleeLag {0}
   barMood wimpy
   barNotice 0
   barPosture 0
   barSneak 0
   barSource 0
   } "" {case}
#TRIGGER "barHitPointTrigger" {You have (%d)~((%d)~) hit and (%d)~((%d)~) movement points.$} {
   #VAR barCurrentHP {%1}
   #VAR barMaxHP {%2}
   #VAR barCurrentMV {%3}
   #VAR barMaxMV {%4}
   #VAR barColorHP {white}
   #VAR barColorMV {white}
   } "" {case}
#TRIGGER "barSpellPointTrigger" {You have (%d)~((%d)~) hit, (%d)~((%d)~) {saidin|saidar|dark power} and (%d)~((%d)~) movement points.$} {
   #VAR barCurrentHP {%1}
   #VAR barMaxHP {%2}
   #VAR barCurrentAP {%3}
   #VAR barMaxAP {%4}
   #VAR barCurrentMV {%5}
   #VAR barMaxMV {%6}
   #VAR barColorAP {white}
   #VAR barColorHP {white}
   #VAR barColorMV {white}
   } "" {case}
#TRIGGER "barMoodTrigger" {^Your mood is: (%w). You will flee below: %d Hit Points$} {barMood %1} "" {case|disable}
#TRIGGER "barPostureTrigger" {^Your posture is: (%w).$} {
   barPosture %1
   #IF (@showBarPosture) {#T+ {TicBarPosture}} {#T- {TicBarPosture}}
   } "" {case|disable}
#TRIGGER "barSubjectedTrigger" {^You are subjected to the following effects:} {
   #T- {barSubjectedTrigger}
   #T- {barMoodTrigger}
   #T- {barPostureTrigger}
   #T+ {barEffectsTrigger}
   barNotice 0
   barSneak 0
   barSource 0
   #VAR barEffectsList {}
   #VAR barEffectsDisplay {}
   } "" {case|disable}
#TRIGGER "barEffectsTrigger" {^- (*) $} {
   #ADDITEM barEffectsList {%1}
   #IF (%ismember(%1,@barExclusionList)) {#DELITEM barEffectsList {%1}} {}
   #IF ("%1"="NOTICE") {barNotice 1} {}   
   #IF ("%1"="SOURCE") {barSource 1} {}   
   #VAR barEffectsDisplay {%replace(%sort(@barEffectsList),"|"," ")}
   } "" {case|disable}
#TRIGGER "barPrompt" {^{o|*}(*)HP:(%w)(*)MV:(%w)*>} {
   #T- {barEffectsTrigger}
   #IF ("%1"=" ") {barSneak 0} {}
   #IF ("%1"=" R ") {barSneak 0} {}
   #IF ("%1"=" R S ") {barSneak 1} {}
   #IF ("%1"=" S ") {barSneak 1} {}
   #IF (%2!=@barHitCond) {
      #T+ {%concat(bar,%2,Trigger)}
      #VAR barHitCond {%2}
      } {
      #VAR barPrevHitCond {@barHitCond}
      }
   #IF (%trim(%delete(%3,1,3))!=@barAbilityCond) {
      #IF (%class(%concat(barAbility,%trim(%delete(%3,1,3)),Trigger))=0) {
         #T+ {%concat(barAbility,%trim(%delete(%3,1,3)),Trigger)}
         #VAR barAbilityCond {%trim(%delete(%3,1,3))}
         } {}
      } {
      #VAR barPrevAbilityCond {@barAbilityCond}
      }
   #IF (%4!=@barMoveCond) {
      #T+ {%concat(bar,%4,Trigger)}
      #VAR barMoveCond {%4}
      } {
      #VAR barPrevMoveCond {@barMoveCond}
      }
   } "" {case|nocr|prompt}
#TRIGGER "barConnectionPrompt" {^{o|*}*HP:%w(*)MV:%w*>} {
   #T- {barConnectionPrompt}
   #IF (@showBarAP AND %begins(%1,"SP:")) {
      #IF (@showbarSource) {#T+ {TicBarSource}} {#T- {TicBarSource}}
      #T+ {TicBarAP}
      #VAR barAbilityType {SP}
      } {
      #T- {TicBarAP}
      #T- {TicBarSource}
      }
   #IF (@showBarAP AND %begins(%1,"DP:")) {
      #T+ {TicBarAP}
      #VAR barAbilityType {DP}
      } {}
   } "" {case|nocr|prompt}
#TRIGGER "barExitTrigger" {^~[ obvious exits: (*) ~]$} {
   #VAR barExitList {%subchar(%if(%pos(~],%1),%left(%1,%pos(~],%1)),%1)," ]","")}
   } "" {case}
#TRIGGER "barExitDark" {It is pitch black...} {
   #VAR barExitList {"?!?!"}
   } "" {case|verbatim}
#TRIGGER "barExitBlind" {You can't see a damned thing, you're blinded!} {
   #VAR barExitList {"?!?!"}
   } "" {case|verbatim}
#TRIGGER "barLoseSource" {You lose all sense of the True Source here.} {barSource 0} "" {case|verbatim}
#TRIGGER "barCantSource" {You can't bear to hold the Source any longer.} {barSource 0} "" {case|verbatim}
#TRIGGER "barSource" {You feel the flows of said?? coursing through your body.$} {barSource 1} "" {case}
#TRIGGER "barStartNotice" {You start paying increased attention to your surroundings.} {
   #T- {barStartNotice}
   #T+ {barStopNotice}
   #T+ {barRestNotice}
   #T+ {barSitNotice}
   #T+ {barSleepNotice}
   barNotice 1
   } "" {case|disable|verbatim}
#TRIGGER "barStopNotice" {You stop paying increased attention to your surroundings.} {
   #T+ {barStartNotice}
   #T- {barStopNotice}
   #T- {barRestNotice}
   #T- {barSitNotice}
   #T- {barSleepNotice}
   barNotice 0
   } "" {case|disable|verbatim}
#TRIGGER "barRestNotice" {You sit down and rest your tired bones.} {
   #T- {barStartNotice}
   #T- {barStopNotice}
   #T- {barRestNotice}
   #T- {barSitNotice}
   #T- {barSleepNotice}
   barNotice 0
   } "" {case|disable|verbatim}
#TRIGGER "barSitNotice" {You sit down.} {
   #T- {barStartNotice}
   #T- {barStopNotice}
   #T- {barRestNotice}
   #T- {barSitNotice}
   #T- {barSleepNotice}
   barNotice 0
   } "" {case|disable|verbatim}
#TRIGGER "barSleepNotice" {You go to sleep.} {
   #T- {barStartNotice}
   #T- {barStopNotice}
   #T- {barRestNotice}
   #T- {barSitNotice}
   #T- {barSleepNotice}
   barNotice 0
   } "" {case|disable|verbatim}
#TRIGGER "barChangeMoodTrigger" {Mood changed to: (%w)$} {barMood %1} "" {case}
#TRIGGER "barChangePostureTrigger" {Posture changed to: (%w)} {
   barPosture %1
   #IF (@showBarPosture) {#T+ {TicBarPosture}} {#T- {TicBarPosture}}
   } "" {case}
#ONINPUT "ticFleeOninput" {^{f|fl|fle|flee}$} {
   #IF (%class(TicBar|TicFleeInput)=1) {
      #ADD ticFleeInput 1
      } {
      #VAR ticFleeInput {0}
      #ADD ticFleeInput 1
      }
   #T+ {TicBar|TicFleeInput}
   #T+ {ticFleeRoomColor}
   } "" {}
#ONINPUT "TicNoticeInput" {^{not|noti|notic|notice}$} {
   #T+ {barStartNotice}
   #T+ {barStopNotice}
   } "" {}
#ONINPUT "TicReleaseInput" {^{rel|rele|relea|releas|release}$} {barSource 0} "" {}
#ONINPUT "TicStatInput" {^stat$} {
   #T+ {barMoodTrigger}
   #T+ {barPostureTrigger}
   #T+ {barSubjectedTrigger}
   } "" {}
#STATUS {@barMXP1(@barMoodColor black,@barMood)} "" "TicBarMood"
#STATUS {@barMXP1(@barPostureColor black,@barPosture)} "" "TicBarPosture"
#STATUS {@barMXP2(@barColorHP black,HP,white black,white black,@barCurrentHP,white black,~(@barMaxHP~))} "" "TicBarHP"
#STATUS {@barMXP2(@barColorAP black,@barAbilityType,white black,white black,@barCurrentAP,white black,~(@barMaxAP~))} "" "TicBarAP"
#STATUS {@barMXP2(@barColorMV black,MV,white black,white black,@barCurrentMV,white black,~(@barMaxMV~))} "" "TicBarMV"
#STATUS {@barMXP3(@barColorFL black,FL,white black,@barFleeLagColor black,@barFleeLag)} "" "TicBarFL"
#STATUS {@barMXP3(white black,CP,white black,@barChargePulseColor black,@barChargePulse)} "" "TicBarCP"
#STATUS {@barMXP5(black @barNoticeColor,NOTICE)} "" "TicBarNotice"
#STATUS {@barMXP5(black @barSneakColor,SNEAK)} "" "TicBarSneak"
#STATUS {@barMXP5(black @barSourceColor,SOURCE)} "" "TicBarSource"
#STATUS {@barMXP1(white black,Exits: @barExitList)} "" "TicBarExit"
#STATUS {@barMXP1(white black,Effects: @barEffectsDisplay)} "" "TicBarEffect"
#CLASS 0
#CLASS {TicBar|TicFleeInput} {disable}
#TRIGGER "ticFleeRoomColor" {%e[36m} {
   #T+ {ticFleeRoomTrigger}
   } "" {color}
#TRIGGER "ticFleeRoomTrigger" {^~[ obvious exits: * ~]$} {
   #T- {ticFleeRoomTrigger}
   #IF (@ticFleeInput=1) {#T- {TicBar|TicFleeInput}} {}
   #ADD ticFleeInput -1
   #ADD barFleeLag 1
   barDisplayAlias
   #T+ {ticOnTicAlias}
   } "" {case|disable}
#TRIGGER "" {Nah... You feel too relaxed to do that..$} {
   #T- {TicBar|TicFleeInput}
   #VAR ticFleeInput {0}
   } "" {case}
#TRIGGER "" {In your dreams, or what?$} {
   #T- {TicBar|TicFleeInput}
   #VAR ticFleeInput {0}
   } "" {case}
#TRIGGER "" {Maybe you should get on your feet first?$} {
   #T- {TicBar|TicFleeInput}
   #VAR ticFleeInput {0}
   } "" {case}
#TRIGGER "" {You are too exhausted.$} {
   #IF (@ticFleeInput=1) {#T- {TicBar|TicFleeInput}} {}
   #ADD ticFleeInput -1
   #ADD barFleeLag 1
   barDisplayAlias
   #T+ {ticOnTicAlias}
   } "" {case}
#TRIGGER "" {You can't ride in there.$} {
   #IF (@ticFleeInput=1) {#T- {TicBar|TicFleeInput}} {}
   #ADD ticFleeInput -1
   #ADD barFleeLag 1
   barDisplayAlias
   #T+ {ticOnTicAlias}
   } "" {case}
#TRIGGER "" {You can't ride there on a horse!$} {
   #IF (@ticFleeInput=1) {#T- {TicBar|TicFleeInput}} {}
   #ADD ticFleeInput -1
   #ADD barFleeLag 1
   barDisplayAlias
   #T+ {ticOnTicAlias}
   } "" {case}
#TRIGGER "" {Your mount is too exhausted.$} {
   #IF (@ticFleeInput=1) {#T- {TicBar|TicFleeInput}} {}
   #ADD ticFleeInput -1
   #ADD barFleeLag 1
   barDisplayAlias
   #T+ {ticOnTicAlias}
   } "" {case}
#TRIGGER "" {You can't see a damned thing, you're blinded!$} {
   #IF (@ticFleeInput=1) {#T- {TicBar|TicFleeInput}} {}
   #ADD ticFleeInput -1
   #ADD barFleeLag 1
   barDisplayAlias
   #T+ {ticOnTicAlias}
   } "" {case}
#TRIGGER "" {It is pitch black...$} {
   #IF (@ticFleeInput=1) {#T- {TicBar|TicFleeInput}} {}
   #ADD ticFleeInput -1
   #ADD barFleeLag 1
   barDisplayAlias
   #T+ {ticOnTicAlias}
   } "" {case}
#CLASS 0
#CLASS {TicBar|EffectTriggers}
#TRIGGER "barArmorON1" {^You feel a flow of energy from * to you, and you feel protected.$} {
   #ADDITEM barEffectsList {ARMOR}
   #VAR barEffectsDisplay {%replace(%sort(@barEffectsList),"|"," ")}
   } "" {case}
#TRIGGER "barArmorON2" {^You weave flows of Spirit around yourself, and you feel protected.$} {
   #ADDITEM barEffectsList {ARMOR}
   #VAR barEffectsDisplay {%replace(%sort(@barEffectsList),"|"," ")}
   } "" {case}
#TRIGGER "barArmorOFF" {^You suddenly feel less protected.$} {
   #DELITEM barEffectsList {ARMOR}
   #VAR barEffectsDisplay {%replace(%sort(@barEffectsList),"|"," ")}
   } "" {case}
#TRIGGER "barBlindON1" {^The air around your eyes seems to catch fire, blinding you!$} {
   #ADDITEM barEffectsList {BLIND}
   #VAR barEffectsDisplay {%replace(%sort(@barEffectsList),"|"," ")}
   } "" {case}
#TRIGGER "barBlindON2" {^The bright flash of the explosion momentarily blinds you.$} {
   #ADDITEM barEffectsList {BLIND}
   #VAR barEffectsDisplay {%replace(%sort(@barEffectsList),"|"," ")}
   } "" {case}
#TRIGGER "barBlindOFF" {^You feel the blindness fade.$} {
   #DELITEM barEffectsList {BLIND}
   #VAR barEffectsDisplay {%replace(%sort(@barEffectsList),"|"," ")}
   } "" {case}
#TRIGGER "barChillON" {^You shiver from an icy cold force sent by} {
   #ADDITEM barEffectsList {CHILL}
   #VAR barEffectsDisplay {%replace(%sort(@barEffectsList),"|"," ")}
   } "" {case}
#TRIGGER "barChillOFF" {^You feel your limbs are now responding again.$} {
   #DELITEM barEffectsList {CHILL}
   #VAR barEffectsDisplay {%replace(%sort(@barEffectsList),"|"," ")}
   } "" {case}
#TRIGGER "barContagionON1" {Beads of cold sweat begin to emerge from your face!$} {
   #ADDITEM barEffectsList {CONTAGION}
   #VAR barEffectsDisplay {%replace(%sort(@barEffectsList),"|"," ")}
   } "" {case}
#TRIGGER "barContagionON" {waves at you, and a cold sweat begins attacking your every muscle.$} {
   #ADDITEM barEffectsList {CONTAGION}
   #VAR barEffectsDisplay {%replace(%sort(@barEffectsList),"|"," ")}
   } "" {case}
#TRIGGER "barContagionOFF" {^You breathe easier again as the cold sweats have faded.$} {
   #DELITEM barEffectsList {CONTAGION}
   #VAR barEffectsDisplay {%replace(%sort(@barEffectsList),"|"," ")}
   } "" {case}
#TRIGGER "barCureBlindON" {^Your eyesight returns.$} {
   #ADDITEM barEffectsList {CURE BLIND}
   #VAR barEffectsDisplay {%replace(%sort(@barEffectsList),"|"," ")}
   } "" {case}
#TRIGGER "barCureBlindOFF" {^Your eyes feel less protected.$} {
   #DELITEM barEffectsList {CURE BLIND}
   #VAR barEffectsDisplay {%replace(%sort(@barEffectsList),"|"," ")}
   } "" {case}
#TRIGGER "barCureFearON" {^You feel your sense of panic slip away.$} {
   #ADDITEM barEffectsList {CURE FEAR}
   #VAR barEffectsDisplay {%replace(%sort(@barEffectsList),"|"," ")}
   } "" {case}
#TRIGGER "barCureFearOFF" {^You feel less sure of yourself.$} {
   #DELITEM barEffectsList {CURE FEAR}
   #VAR barEffectsDisplay {%replace(%sort(@barEffectsList),"|"," ")}
   } "" {case}
#TRIGGER "barFearON" {gazes deeply into your soul.. very chilling.$} {
   #ADDITEM barEffectsList {FEAR}
   #VAR barEffectsDisplay {%replace(%sort(@barEffectsList),"|"," ")}
   } "" {case}
#TRIGGER "barFearOFF" {^You feel less paranoid.$} {
   #DELITEM barEffectsList {FEAR}
   #VAR barEffectsDisplay {%replace(%sort(@barEffectsList),"|"," ")}
   } "" {case}
#TRIGGER "barLightBallON" {^The room becomes brighter as you create a sphere of light above your hand.$} {
   #ADDITEM barEffectsList {LIGHT BALL}
   #VAR barEffectsDisplay {%replace(%sort(@barEffectsList),"|"," ")}
   } "" {case}
#TRIGGER "barLightBallOFF" {^The flows holding the light ball have dissipated.$} {
   #DELITEM barEffectsList {LIGHT BALL}
   #VAR barEffectsDisplay {%replace(%sort(@barEffectsList),"|"," ")}
   } "" {case}
#TRIGGER "barOverchannelON1" {You dangerously draw more power from {saidar|saidin} than before.$} {
   #ADDITEM barEffectsList {OVERCHANNEL}
   #VAR barEffectsDisplay {%replace(%sort(@barEffectsList),"|"," ")}
   } "" {case}
#TRIGGER "barOverchannelON2" {You feel more and more {saidar|saidin} rushing through your body, your entire being feels suffused with the Power.$} {
   #ADDITEM barEffectsList {OVERCHANNEL}
   #VAR barEffectsDisplay {%replace(%sort(@barEffectsList),"|"," ")}
   } "" {case}
#TRIGGER "barPoisonON" {^A strangled cough racks your lungs, causing agony!$} {
   #ADDITEM barEffectsList {POISON}
   #VAR barEffectsDisplay {%replace(%sort(@barEffectsList),"|"," ")}
   } "" {case}
#TRIGGER "barPoisonON2" {Oops, it tasted rather strange!$} {
   #ADDITEM barEffectsList {POISON}
   #VAR barEffectsDisplay {%replace(%sort(@barEffectsList),"|"," ")}
   } "" {case}
#TRIGGER "barPoisonON3" {^You cough and shiver.$} {
   #ADDITEM barEffectsList {POISON}
   #VAR barEffectsDisplay {%replace(%sort(@barEffectsList),"|"," ")}
   } "" {case}
#TRIGGER "barPoisonON4" {swirls about with *, slicing across your body!$} {
   #ADDITEM barEffectsList {POISON}
   #VAR barEffectsDisplay {%replace(%sort(@barEffectsList),"|"," ")}
   } "" {case}
#TRIGGER "barPoisonOFF" {^You feel better.$} {
   #DELITEM barEffectsList {POISON}
   #VAR barEffectsDisplay {%replace(%sort(@barEffectsList),"|"," ")}
   } "" {case}
#TRIGGER "barRefreshON" {^You feel a sudden burst of stamina!$} {
   #ADDITEM barEffectsList {REFRESH}
   #VAR barEffectsDisplay {%replace(%sort(@barEffectsList),"|"," ")}
   } "" {case}
#TRIGGER "barRefreshOFF" {^Your extra burst of stamina fades.$} {
   #DELITEM barEffectsList {REFRESH}
   #VAR barEffectsDisplay {%replace(%sort(@barEffectsList),"|"," ")}
   } "" {case}
#TRIGGER "barStrengthON1" {^Flows of Fire and Spirit work into your muscles, enhancing your strength.$} {
   #ADDITEM barEffectsList {STRENGTH}
   #VAR barEffectsDisplay {%replace(%sort(@barEffectsList),"|"," ")}
   } "" {case}
#TRIGGER "barStrengthON2" {^A surge of adrenaline works into your muscles, enhancing your strength.$} {
   #ADDITEM barEffectsList {STRENGTH}
   #VAR barEffectsDisplay {%replace(%sort(@barEffectsList),"|"," ")}
   } "" {case}
#TRIGGER "barStrengthOFF" {^You feel your extra strength fading.$} {
   #DELITEM barEffectsList {STRENGTH}
   #VAR barEffectsDisplay {%replace(%sort(@barEffectsList),"|"," ")}
   } "" {case}
#TRIGGER "barWardVsDamageON1" {^A carefully woven flow of Earth, Air, and Water forms an aura about your body!$} {
   #ADDITEM barEffectsList {WARDING VS DMG}
   #VAR barEffectsDisplay {%replace(%sort(@barEffectsList),"|"," ")}
   } "" {case}
#TRIGGER "barWardVsDamageON2" {forms a beautiful weave of white light about your body.$} {
   #ADDITEM barEffectsList {WARDING VS DMG}
   #VAR barEffectsDisplay {%replace(%sort(@barEffectsList),"|"," ")}
   } "" {case}
#TRIGGER "barWardVsDamageOFF" {^Your white aura has faded.$} {
   #DELITEM barEffectsList {WARDING VS DMG}
   #VAR barEffectsDisplay {%replace(%sort(@barEffectsList),"|"," ")}
   } "" {case}
#TRIGGER "barWardVsEvilON1" {^A carefully woven spirit forms a blue aura about your body!$} {
   #ADDITEM barEffectsList {WARDING VS EVIL}
   #VAR barEffectsDisplay {%replace(%sort(@barEffectsList),"|"," ")}
   } "" {case}
#TRIGGER "barWardVsEvilON2" {forms a beautiful weave of blue light about your body.$} {
   #ADDITEM barEffectsList {WARDING VS EVIL}
   #VAR barEffectsDisplay {%replace(%sort(@barEffectsList),"|"," ")}
   } "" {case}
#TRIGGER "barWardVsEvilOFF" {^Your blue aura has faded.$} {
   #DELITEM barEffectsList {WARDING VS EVIL}
   #VAR barEffectsDisplay {%replace(%sort(@barEffectsList),"|"," ")}
   } "" {case}
#CLASS 0
#CLASS {TicBar|CondTriggers}
#TRIGGER "barHealthyTrigger" {@barHitCond=Healthy} {
   #T- {barHealthyTrigger}
   #VAR barCurrentHP {@barMaxHP}
   } "" {exp}
#TRIGGER "barScratchedTrigger" {@barHitCond=Scratched} {
   #T- {barScratchedTrigger}
   #IF (@barPrevHitCond=Healthy) {
      #VAR barCurrentHP {%format(0,%eval(@barMaxHP*%float(.97)))}
      } {}
   #IF (@barPrevHitCond=Hurt OR @barPrevHitCond=Wounded) {
      #VAR barCurrentHP {%format(0,%eval(@barMaxHP*%float(.90)))}
      } {}
   } "" {disable|exp}
#TRIGGER "barHurtTrigger" {@barHitCond=Hurt} {
   #T- {barHurtTrigger}
   #IF (@barPrevHitCond=Healthy OR @barPrevHitCond=Scratched) {
      #VAR barCurrentHP {%format(0,%eval(@barMaxHP*%float(.87)))}
      } {}
   #IF (@barPrevHitCond=Wounded OR @barPrevHitCond=Battered) {
      #VAR barCurrentHP {%format(0,%eval(@barMaxHP*%float(.75)))}
      } {}
   } "" {disable|exp}
#TRIGGER "barWoundedTrigger" {@barHitCond=Wounded} {
   #T- {barWoundedTrigger}
   #IF (@barPrevHitCond=Healthy OR @barPrevHitCond=Scratched OR @barPrevHitCond=Hurt) {
      #VAR barCurrentHP {%format(0,%eval(@barMaxHP*%float(.72)))}
      } {}
   #IF (@barPrevHitCond=Battered OR @barPrevHitCond=Beaten) {
      #VAR barCurrentHP {%format(0,%eval(@barMaxHP*%float(.50)))}
      } {}
   } "" {disable|exp}
#TRIGGER "barBatteredTrigger" {@barHitCond=Battered} {
   #T- {barBatteredTrigger}
   #IF (@barPrevHitCond=Hurt OR @barPrevHitCond=Wounded) {
      #VAR barCurrentHP {%format(0,%eval(@barMaxHP*%float(.47)))}
      } {}
   #IF (@barPrevHitCond=Beaten OR @barPrevHitCond=Critical) {
      #VAR barCurrentHP {%format(0,%eval(@barMaxHP*%float(.30)))}
      } {}
   } "" {disable|exp}
#TRIGGER "barBeatenTrigger" {@barHitCond=Beaten} {
   #T- {barBeatenTrigger}
   #IF (@barPrevHitCond=Wounded OR @barPrevHitCond=Battered) {
      #VAR barCurrentHP {%format(0,%eval(@barMaxHP*%float(.27)))}
      } {}
   #IF (@barPrevHitCond=Critical) {
      #VAR barCurrentHP {%format(0,%eval(@barMaxHP*%float(.15)))}
      } {}
   } "" {disable|exp}
#TRIGGER "barCriticalTrigger" {@barHitCond=Critical} {
   #T- {barCriticalTrigger}
   #VAR barCurrentHP {%format(0,%eval(@barMaxHP*%float(.13)))}
   } "" {disable|exp}
#TRIGGER "barAbilityBurstingTrigger" {@barAbilityCond=Bursting} {
   #T- {barAbilityBurstingTrigger}
   #VAR barCurrentAP {@barMaxAP}
   } "" {exp}
#TRIGGER "barAbilityFullTrigger" {@barAbilityCond=Full} {
   #T- {barAbilityFullTrigger}
   #IF (@barPrevAbilityCond=Bursting) {
      #VAR barCurrentAP {%format(0,%eval(@barMaxAP*%float(.97)))}
      } {}
   #IF (@barPrevAbilityCond=Strong) {
      #VAR barCurrentAP {%format(0,%eval(@barMaxAP*%float(.91)))}
      } {}
   } "" {disable|exp}
#TRIGGER "barAbilityStrongTrigger" {@barAbilityCond=Strong} {
   #T- {barAbilityStrongTrigger}
   #IF (@barPrevAbilityCond=Bursting OR @barPrevAbilityCond=Full) {
      #VAR barCurrentAP {%format(0,%eval(@barMaxAP*%float(.87)))}
      } {}
   #IF (@barPrevAbilityCond=Good) {
      #VAR barCurrentAP {%format(0,%eval(@barMaxAP*%float(.51)))}
      } {}
   } "" {disable|exp}
#TRIGGER "barAbilityGoodTrigger" {@barAbilityCond=Good} {
   #T- {barAbilityGoodTrigger}
   #IF (@barPrevAbilityCond=Full OR @barPrevAbilityCond=Strong) {
      #VAR barCurrentAP {%format(0,%eval(@barMaxAP*%float(.47)))}
      } {}
   #IF (@barPrevAbilityCond=Fading) {
      #VAR barCurrentAP {%format(0,%eval(@barMaxAP*%float(.31)))}
      } {}
   } "" {disable|exp}
#TRIGGER "barAbilityFadingTrigger" {@barAbilityCond=Fading} {
   #T- {barAbilityFadingTrigger}
   #IF (@barPrevAbilityCond=Strong OR @barPrevAbilityCond=Good) {
      #VAR barCurrentAP {%format(0,%eval(@barMaxAP*%float(.27)))}
      } {}
   #IF (@barPrevAbilityCond=Trickling) {
      #VAR barCurrentAP {%format(0,%eval(@barMaxAP*%float(.16)))}
      } {}
   } "" {disable|exp}
#TRIGGER "barAbilityTricklingTrigger" {@barAbilityCond=Trickling} {
   #T- {barAbilityTricklingTrigger}
   #IF (@barPrevAbilityCond=Good OR @barPrevAbilityCond=Fading) {
      #VAR barCurrentAP {%format(0,%eval(@barMaxAP*%float(.13)))}
      } {}
   #IF (@barPrevAbilityCond=None) {
      #VAR barCurrentAP {%format(0,%eval((@barINT+@barWIL)/2))}
      } {}
   } "" {disable|exp}
#TRIGGER "barAbilityNoneTrigger" {@barAbilityCond=None} {
   #T- {barAbilityNoneTrigger}
   #VAR barCurrentAP {0}
   } "" {disable|exp}
#TRIGGER "barAbilitySpentTrigger" {@barAbilityCond=Spent} {
   #T- {barAbilitySpentTrigger}
   #VAR barCurrentAP {negative}
   } "" {disable|exp}
#TRIGGER "barFreshTrigger" {@barMoveCond=Fresh} {
   #T- {barFreshTrigger}
   #VAR barCurrentMV {@barMaxMV}
   } "" {exp}
#TRIGGER "barFullTrigger" {@barMoveCond=Full} {
   #T- {barFullTrigger}
   #IF (@barPrevMoveCond=Fresh) {
      #VAR barCurrentMV {%format(0,%eval(@barMaxMV*%float(.98)))}
      } {}
   #IF (@barPrevMoveCond=Strong OR @barPrevMoveCond=Tiring OR @barPrevMoveCond=Winded) {
      #VAR barCurrentMV {%format(0,%eval(@barMaxMV*%float(.90)))}
      } {}
   } "" {disable|exp}
#TRIGGER "barStrongTrigger" {@barMoveCond=Strong} {
   #T- {barStrongTrigger}
   #IF (@barPrevMoveCond=Fresh OR @barPrevMoveCond=Full) {
      #VAR barCurrentMV {%format(0,%eval(@barMaxMV*%float(.88)))}
      } {}
   #IF (@barPrevMoveCond=Tiring OR @barPrevMoveCond=Winded OR @barPrevMoveCond=Weary) {
      #VAR barCurrentMV {%format(0,%eval(@barMaxMV*%float(.75)))}
      } {}
   } "" {disable|exp}
#TRIGGER "barTiringTrigger" {@barMoveCond=Tiring} {
   #T- {barTiringTrigger}
   #IF (@barPrevMoveCond=Full OR @barPrevMoveCond=Strong) {
      #VAR barCurrentMV {%format(0,%eval(@barMaxMV*%float(.73)))}
      } {}
   #IF (@barPrevMoveCond=Winded OR @barPrevMoveCond=Weary OR @barPrevMoveCond=Haggard) {
      #VAR barCurrentMV {%format(0,%eval(@barMaxMV*%float(.50)))}
      } {}
   } "" {disable|exp}
#TRIGGER "barWindedTrigger" {@barMoveCond=Winded} {
   #T- {barWindedTrigger}
   #IF (@barPrevMoveCond=Strong OR @barPrevMoveCond=Tiring) {
      #VAR barCurrentMV {%format(0,%eval(@barMaxMV*%float(.48)))}
      } {}
   #IF (@barPrevMoveCond=Weary OR @barPrevMoveCond=Haggard OR @barPrevMoveCond=Collapsing) {
      #VAR barCurrentMV {%format(0,%eval(@barMaxMV*%float(.30)))}
      } {}
   } "" {disable|exp}
#TRIGGER "barWearyTrigger" {@barMoveCond=Weary} {
   #T- {barWearyTrigger}
   #IF (@barPrevMoveCond=Tiring OR @barPrevMoveCond=Winded) {
      #VAR barCurrentMV {%format(0,%eval(@barMaxMV*%float(.28)))}
      } {}
   #IF (@barPrevMoveCond=Haggard OR @barPrevMoveCond=Collapsing) {
      #VAR barCurrentMV {%format(0,%eval(@barMaxMV*%float(.15)))}
      } {}
   } "" {disable|exp}
#TRIGGER "barHaggardTrigger" {@barMoveCond=Haggard} {
   #T- {barHaggardTrigger}
   #IF (@barPrevMoveCond=Winded OR @barPrevMoveCond=Weary) {
      #VAR barCurrentMV {%format(0,%eval(@barMaxMV*%float(.13)))}
      } {}
   #IF (@barPrevMoveCond=Collapsing) {
      #VAR barCurrentMV {0}
      } {}
   } "" {disable|exp}
#TRIGGER "barCollapsingTrigger" {@barMoveCond=Collapsing} {
   #T- {barCollapsingTrigger}
   #VAR barCurrentMV {negative}
   } "" {disable|exp}
#CLASS 0
#CLASS {TicBar|TicPatterns}
#TRIGGER "" {* begins to dim a little.$} {#TSET} "" {case}
#TRIGGER "" {* disappears into the void.$} {#TSET} "" {case}
#TRIGGER "" {* has gone out!$} {#TSET} "" {case}
#TRIGGER "" {* is about to go out!$} {#TSET} "" {case}
#TRIGGER "" {^A * is definitely fading.$} {#TSET} "" {case}
#TRIGGER "" {^A glowing portal fades from existence.$} {#TSET} "" {case}
#TRIGGER "" {^As you watch * seems to melt into the background, vanishing.$} {#TSET} "" {case}
#TRIGGER "" {^The Wheel of Time turns towards the} {#TSET} "" {case}
#TRIGGER "" {^The Wheel of Time spins between the} {#TSET} "" {case}
#TRIGGER "" {^The corpse of * has decayed into a pile of dust.$} {#TSET} "" {case}
#TRIGGER "" {^The day has begun.$} {#TSET} "" {case}
#TRIGGER "" {^The night has begun.$} {#TSET} "" {case}
#TRIGGER "" {^You breathe easier again as the cold sweats have faded.$} {#TSET} "" {case}
#TRIGGER "" {^You feel better.$} {#TSET} "" {case}
#TRIGGER "" {^You feel less paranoid.$} {#TSET} "" {case}
#TRIGGER "" {^You feel less sure of yourself.$} {#TSET} "" {case}
#TRIGGER "" {^You feel parched from the hot weather.$} {#TSET} "" {case}
#TRIGGER "" {^You feel the blindness fade.$} {#TSET} "" {case}
#TRIGGER "" {^You feel your extra strength fading.$} {#TSET} "" {case}
#TRIGGER "" {^You feel your limbs are now responding again.$} {#TSET} "" {case}
#TRIGGER "" {^The flows holding the light ball have dissipated.$} {#TSET} "" {case}
#TRIGGER "" {^You move slightly, settling your cloak into position.$} {#TSET} "" {case}
#TRIGGER "" {^You suddenly feel less protected.$} {#TSET} "" {case}
#TRIGGER "" {^Your blue aura has faded.$} {#TSET} "" {case}
#TRIGGER "" {^Your ears seem to be all cleared up.$} {#TSET} "" {case}
#TRIGGER "" {^Your extra burst of stamina fades.$} {#TSET} "" {case}
#TRIGGER "" {^Your eyes feel less protected.$} {#TSET} "" {case}
#TRIGGER "" {^Your heartbeat calms down more as you feel less panicked.$} {#TSET} "" {case}
#TRIGGER "" {^Your heartbeat races very rapidly as your forehead throbs.$} {#TSET} "" {case}
#TRIGGER "" {^Your white aura has faded.$} {#TSET} "" {case}
#CLASS 0
#CLASS {TicBar|TicBarConnect} {enable}
#TRIGGER "TicBarConnectTrigger" {%s The Wheel Of Time MUD} {
   #T- {TicBar|TicBarConnect}
   #T+ {barReconnectedTrigger}
   #T+ {barRentedTrigger}
   #T+ {barConnectionPrompt}
   #T+ {barStatTrigger}
   #T+ {barMoodTrigger}
   #T+ {barPostureTrigger}
   #T+ {barSubjectedTrigger}
   } "" {case}
#CLASS 0
#T- {TicBarPosture}
#T- {TicBarSource}
#T- {TicBarAP}

_________________
House of Medakan zMUD Scripts: Table of Contents

House of Medakan cMUD Scripts: Table of Contents


Last edited by Taziar on Sat Aug 25, 2018 2:20 am, edited 22 times in total.

Top
 Profile  
 
 Post subject: Re: HoM zMUD Scripts
PostPosted: Wed Apr 19, 2017 12:53 am 
Offline

Joined: Tue Apr 07, 2015 8:24 pm
Posts: 132
Location: Seattle
Type helpMeleeRound to view help file in client.

Image

Direct download link: MeleeRoundHoM.txt

Active Triggers: 22/22
Code:
#CLASS {MeleeRound}
#ALIAS helpMeleeRound {
   #PRIORITY {
      #SAY {%crlf "-----Melee Round Help File-----"}
      #SAY {"      [Updated: 7/20/2018]"}
      #SHOW {" Colors and tracks melee combat statistics against cross race opponents."}
      #SHOW {"  Script tracks individual character data across sessions."}
      #SHOW {""}
      #SHOW {" attackCount      (show total melee round hits and misses attempted for current session)"}
      #SHOW {" defendCount      (show total melee round hits and misses against current session)"}
      #SHOW {"  Note: attack and defend commands show current session statistics."}
      #SHOW {""}
      #SHOW {" meleeCount       (show total melee round data for current character)"}
      #SHOW {"  Note: meleeCount command show overtime statistics for current character."}
      #SHOW {""}
      #SHOW {" Type: resetMelee to reset ALL data for current character."}
      #SHOW {""}
      #SHOW {" Type: meleeColor <type> <color> [bcolor] background color optional"}
      #SHOW {"  Available meleeColor types: (shown in current set color)"}
      #SHOW {"   "@meleeMXPhelp(%replace(@meleeColorAsterisk,","," "),"Asterisk         (set color of asterisk in a melee line)")}
      #SHOW {"   "@meleeMXPhelp(%replace(@meleeColorCrossRaceHitYou,","," "),"CrossRaceHitYou  (set color of line when a CrossRace player hits you)")}
      #SHOW {"   "@meleeMXPhelp(%replace(@meleeColorYouHitCrossRace,","," "),"YouHitCrossRace  (set color of line when you hit a CrossRace player)")}
      #SHOW {""}
      #SHOW {" Example: meleeColor CrossRaceHitYou red black (sets red foreground with a black background)"}
      #SHOW {""}
      }
   }
#ALIAS meleeColor {
   #IF (%null(%1)) {
      #SHOW {%crlf "Usage: meleeColor <type> <color> [bcolor] background color optional"}
      #SHOW {"  Available meleeColor types: (shown in current set color)"}
      #SHOW {"   "@meleeMXPhelp(%replace(@meleeColorAsterisk,","," "),"Asterisk         (set color of asterisk in a melee line)")}
      #SHOW {"   "@meleeMXPhelp(%replace(@meleeColorCrossRaceHitYou,","," "),"CrossRaceHitYou  (set color of line when a CrossRace player hits you)")}
      #SHOW {"   "@meleeMXPhelp(%replace(@meleeColorYouHitCrossRace,","," "),"YouHitCrossRace  (set color of line when you hit a CrossRace player)")}
      } {
      #IF (%class(%concat("meleeColor",%1))=-1) {
         #SAY {%crlf %1 is an invalid type selection...}
         } {
         #IF (%null(%2)) {
            #SAY {%crlf What color is that?...}
            } {
            #IF (%colorname(%2)=536870911 AND %color(%2)=0) {
               #VAR %concat("meleeColor",%1) {}
               #SAY {%crlf %2 is an invalid color. %concat("meleeColor",%proper(%1)) variable cleared.}
               } {
               #IF (%null(%3)) {
                  #VAR %concat("meleeColor",%1) {%2}
                  #SHOW {%crlf Color set: @meleeMXPcolor(%2)}
                  } {
                  #IF (%colorname(%3)=536870911 AND %color(%3)=0) {
                     #VAR %concat("meleeColor",%1) {}
                     #SAY {%crlf %3 is an invalid color. %concat("meleeColor",%proper(%1)) variable cleared.}
                     } {
                     #VAR %concat("meleeColor",%1) {%concat(%2,",",%3)}
                     #SHOW {%crlf Color set: @meleeMXPcolor(%2 %3)}
                     }
                  }
               }
            }
         }
      }
   }
#ALIAS attackCount {
   #MATH attackCrossRacePercent (@attackCrossRaceHit*100 / @attackCrossRaceTotal)
   #MATH attackCrossRacePercentParry (@attackCrossRaceParry*100 / @attackCrossRaceTotal)
   #MATH attackCrossRacePercentDodge (@attackCrossRaceDodge*100 / @attackCrossRaceTotal)
   #SHOW {""}
   #SHOW {"Cross Race Attack Data:"}
   #SAY {This session you've hit your opponents @attackCrossRaceHit out of @attackCrossRaceTotal total melee rounds (@{attackCrossRacePercent}~% hit)}
   #SAY {This session your opponents have parried @attackCrossRaceParry out of @attackCrossRaceTotal total melee rounds (@{attackCrossRacePercentParry}~% parried)}
   #SAY {This session your opponents have dodged @attackCrossRaceDodge out of @attackCrossRaceTotal total melee rounds (@{attackCrossRacePercentDodge}~% dodged)}
   }
#ALIAS defendCount {
   #SHOW {""}
   #MATH defendCrossRacePercent (@defendCrossRaceHit*100 / @defendCrossRaceTotal)
   #MATH defendCrossRacePercentParry (@defendCrossRaceParry*100 / @defendCrossRaceTotal)
   #MATH defendCrossRacePercentDodge (@defendCrossRaceDodge*100 / @defendCrossRaceTotal)
   #SHOW {"Cross Race Defense Data:"}
   #SAY {This session you've been hit @defendCrossRaceHit out of @defendCrossRaceTotal total melee rounds (@{defendCrossRacePercent}~% hit)}
   #SAY {This session you've parried @defendCrossRaceParry out of @defendCrossRaceTotal total melee rounds (@{defendCrossRacePercentParry}~% parried)}
   #SAY {This session you've dodged @defendCrossRaceDodge out of @defendCrossRaceTotal total melee rounds (@{defendCrossRacePercentDodge}~% dodged)}
   }
#ALIAS meleeCount {
   #SHOW {""}
   #MATH %concat("attack",%char,"CrossRacePercent") (%eval(%concat("@attack",%char,"CrossRaceHit"))*100 / %eval(%concat("@attack",%char,"CrossRaceTotal")))
   #MATH %concat("attack",%char,"CrossRacePercentParry") (%eval(%concat("@attack",%char,"CrossRaceParry"))*100 / %eval(%concat("@attack",%char,"CrossRaceTotal")))
   #MATH %concat("attack",%char,"CrossRacePercentDodge") (%eval(%concat("@attack",%char,"CrossRaceDodge"))*100 / %eval(%concat("@attack",%char,"CrossRaceTotal")))
   #SHOW {Cross Race Attacks since %eval(%concat("@",%char,"MROT")):}
   #SAY {You've hit your opponents %eval(%concat("@attack",%char,"CrossRaceHit")) out of %eval(%concat("@attack",%char,"CrossRaceTotal")) total melee rounds (%eval(%concat("@attack",%char,"CrossRacePercent"))~% hit)}
   #SAY {Your opponents have parried %eval(%concat("@attack",%char,"CrossRaceParry")) out of %eval(%concat("@attack",%char,"CrossRaceTotal")) total melee rounds (%eval(%concat("@attack",%char,"CrossRacePercentParry"))~% parried)}
   #SAY {Your opponents have dodged %eval(%concat("@attack",%char,"CrossRaceDodge")) out of %eval(%concat("@attack",%char,"CrossRaceTotal")) total melee rounds (%eval(%concat("@attack",%char,"CrossRacePercentDodge"))~% dodged)}
   #MATH %concat("defend",%char,"CrossRacePercent") (%eval(%concat("@defend",%char,"CrossRaceHit"))*100 / %eval(%concat("@defend",%char,"CrossRaceTotal")))
   #MATH %concat("defend",%char,"CrossRacePercentParry") (%eval(%concat("@defend",%char,"CrossRaceParry"))*100 / %eval(%concat("@defend",%char,"CrossRaceTotal")))
   #MATH %concat("defend",%char,"CrossRacePercentDodge") (%eval(%concat("@defend",%char,"CrossRaceDodge"))*100 / %eval(%concat("@defend",%char,"CrossRaceTotal")))
   #SHOW {Cross Race Defense since %eval(%concat("@",%char,"MROT")):}
   #SAY {You've been hit %eval(%concat("@defend",%char,"CrossRaceHit")) out of %eval(%concat("@defend",%char,"CrossRaceTotal")) total melee rounds (%eval(%concat("@defend",%char,"CrossRacePercent"))~% hit)}
   #SAY {You've parried %eval(%concat("@defend",%char,"CrossRaceParry")) out of %eval(%concat("@defend",%char,"CrossRaceTotal")) total melee rounds (%eval(%concat("@defend",%char,"CrossRacePercentParry"))~% parried)}
   #SAY {You've dodged %eval(%concat("@defend",%char,"CrossRaceDodge")) out of %eval(%concat("@defend",%char,"CrossRaceTotal")) total melee rounds (%eval(%concat("@defend",%char,"CrossRacePercentDodge"))~% dodged)}
   }
#ALIAS resetMelee {
   #RESET {meleeRound}
   #VAR %concat("attack",%char,"CrossRaceDodge") {0} {_nodef} {MeleeRound|%concat(%char,MeleeRoundVariables)}
   #VAR %concat("attack",%char,"CrossRaceHit") {0} {_nodef} {MeleeRound|%concat(%char,MeleeRoundVariables)}
   #VAR %concat("attack",%char,"CrossRaceParry") {0} {_nodef} {MeleeRound|%concat(%char,MeleeRoundVariables)}
   #VAR %concat("attack",%char,"CrossRacePercent") {0} {_nodef} {MeleeRound|%concat(%char,MeleeRoundVariables)}
   #VAR %concat("attack",%char,"CrossRacePercentDodge") {0} {_nodef} {MeleeRound|%concat(%char,MeleeRoundVariables)}
   #VAR %concat("attack",%char,"CrossRacePercentParry") {0} {_nodef} {MeleeRound|%concat(%char,MeleeRoundVariables)}
   #VAR %concat("attack",%char,"CrossRaceTotal") {0} {_nodef} {MeleeRound|%concat(%char,MeleeRoundVariables)}
   #VAR %concat("defend",%char,"CrossRaceDodge") {0} {_nodef} {MeleeRound|%concat(%char,MeleeRoundVariables)}
   #VAR %concat("defend",%char,"CrossRaceHit") {0} {_nodef} {MeleeRound|%concat(%char,MeleeRoundVariables)}
   #VAR %concat("defend",%char,"CrossRaceParry") {0} {_nodef} {MeleeRound|%concat(%char,MeleeRoundVariables)}
   #VAR %concat("defend",%char,"CrossRacePercent") {0} {_nodef} {MeleeRound|%concat(%char,MeleeRoundVariables)}
   #VAR %concat("defend",%char,"CrossRacePercentDodge") {0} {_nodef} {MeleeRound|%concat(%char,MeleeRoundVariables)}
   #VAR %concat("defend",%char,"CrossRacePercentParry") {0} {_nodef} {MeleeRound|%concat(%char,MeleeRoundVariables)}
   #VAR %concat("defend",%char,"CrossRaceTotal") {0} {_nodef} {MeleeRound|%concat(%char,MeleeRoundVariables)}
   #VAR %concat(%char,"MROT") {%time("m/d/20y")} {_nodef} {MeleeRound|%concat(%char,MeleeRoundVariables)}
   #SAY {Melee Rounds data for %char is now reset.}
   }
#ALIAS attackCrossSuccess {
   #ADD attackCrossRaceHit 1
   #ADD attackCrossRaceTotal 1
   #ADD %concat("attack",%char,"CrossRaceTotal") 1
   #ADD %concat("attack",%char,"CrossRaceHit") 1
   }
#ALIAS attackCrossDodge {
   #ADD attackCrossRaceDodge 1
   #ADD attackCrossRaceTotal 1
   #ADD %concat("attack",%char,"CrossRaceTotal") 1
   #ADD %concat("attack",%char,"CrossRaceDodge") 1
   }
#ALIAS attackCrossParry {
   #ADD attackCrossRaceParry 1
   #ADD attackCrossRaceTotal 1
   #ADD %concat("attack",%char,"CrossRaceTotal") 1
   #ADD %concat("attack",%char,"CrossRaceParry") 1
   }
#ALIAS defendCrossHit {
   #ADD defendCrossRaceHit 1
   #ADD defendCrossRaceTotal 1
   #ADD %concat("defend",%char,"CrossRaceTotal") 1
   #ADD %concat("defend",%char,"CrossRaceHit") 1
   }
#ALIAS defendCrossParry {
   #ADD defendCrossRaceParry 1
   #ADD defendCrossRaceTotal 1
   #ADD %concat("defend",%char,"CrossRaceTotal") 1
   #ADD %concat("defend",%char,"CrossRaceParry") 1
   }
#ALIAS defendCrossDodge {
   #ADD defendCrossRaceDodge 1
   #ADD defendCrossRaceTotal 1
   #ADD %concat("defend",%char,"CrossRaceTotal") 1
   #ADD %concat("defend",%char,"CrossRaceDodge") 1
   }
#ALIAS meleeYouHitCrossRace {
   #PCOL @meleeColorYouHitCrossRace %x1
   #PCOL @meleeColorAsterisk %x2
   #PCOL @meleeColorAsterisk %x3
   #PCOL @meleeColorYouHitCrossRace %x4
   }
#ALIAS meleeCrossRaceHitYou {
   #PCOL @meleeColorAsterisk %x1
   #PCOL @meleeColorAsterisk %x2
   #PCOL @meleeColorCrossRaceHitYou %x3
   }
#FUNCTION meleeMXPcolor {<color %1>%1</color>}
#FUNCTION meleeMXPhelp {<color %1>%2</color>}
#VAR meleeAttack {blast|cleave|crush|hack|hit|lance|pierce|pound|scythe|shoot|slash|slice|smite|stab|sting|strike|whip}
#VAR meleeAttacked {blasts|cleaves|crushes|hacks|hits|lances|pierces|pounds|scythes|shoots|slashes|slices|smites|stabs|stings|strikes|whips}
#VAR meleeAttacking {blasting|cleaving|crushing|hacking|hitting|lancing|piercing|pounding|scything|shooting|slashing|slicing|smiting|stabbing|stinging|striking|whipping}
#VAR meleeBodypart {body|branch|crown|dorsal fin|head|left arm|left fin|left foot|left foreleg|left hand|left leg|left paw|left wing|right arm|right fin|right foot|right foreleg|right hand|right leg|right paw|right wing|roots|tail fin|trunk}
#VAR meleeDamage {into bloody fragments|extremely hard|very hard|hard}
#VAR meleeFlowList {assume|flow effortlessly into|gracefully flow into|spin effortlessly into}
#VAR meleeSwordForms {Arc of the Moon|Bundling Straw|Cat on Hot Sand|Hummingbird Kisses the Honeyrose|Lightning of Three Prongs|Lizard in the Thornbush|Low Wind Rising|Moon Rises Over the Water|Parting the Silk|Ribbon in the Air|Stones Falling from the Cliff|Striking the Spark|The Boar Rushes Down the Mountain|The Cat Dances on the Wall|The Courtier Taps His Fan|The Falcon Swoops|The Falling Leaf|The Heron Spreads Its Wings|The Kingfisher Takes a Silverback|The River Undercuts the Bank|The Swallow Takes Flight|The Wood Grouse Dances|Thistledown Floats on the Wind|Tower of Morning|Water Flows Downhill|Whirlwind on the Mountain|Wind and Rain}
#VAR meleeTickle {barely|tickle|barely tickle}
#VAR meleeTickles {barely|tickles|barely tickles}
#VAR attackCrossRaceDodge {0} {0}
#VAR attackCrossRaceHit {0} {0}
#VAR attackCrossRaceParry {0} {0}
#VAR attackCrossRacePercent {0} {0}
#VAR attackCrossRacePercentDodge {0} {0}
#VAR attackCrossRacePercentParry {0} {0}
#VAR attackCrossRaceTotal {0} {0}
#VAR defendCrossRaceDodge {0} {0}
#VAR defendCrossRaceTotal {0} {0}
#VAR defendCrossRaceHit {0} {0}
#VAR defendCrossRaceParry {0} {0}
#VAR defendCrossRacePercent {0} {0}
#VAR defendCrossRacePercentDodge {0} {0}
#VAR defendCrossRacePercentParry {0} {0}
#VAR meleeColorAsterisk {white}
#VAR meleeColorCrossRaceHitYou {crimson}
#VAR meleeColorYouHitCrossRace {royalblue}
#CLASS 0
#CLASS {MeleeRound|MeleeSwordforms}
#TRIGGER {(You assume {@meleeSwordForms}, {@meleeAttacking}) (~*)%w(~*'s) ({@meleeBodypart}.)$} {
   attackCrossSuccess
   meleeYouHitCrossRace
   } "" {case}
#TRIGGER {(You assume {@meleeSwordForms}, {@meleeAttacking}) (~*)%w(~*'s) ({@meleeBodypart} {@meleeDamage}{.|!})$} {
   attackCrossSuccess
   meleeYouHitCrossRace
   } "" {case}
#TRIGGER {(You flow effortlessly into {@meleeSwordForms}, {@meleeAttacking}) (~*)%w(~*'s) ({@meleeBodypart}.)$} {
   attackCrossSuccess
   meleeYouHitCrossRace
   } "" {case}
#TRIGGER {(You flow effortlessly into {@meleeSwordForms}, {@meleeAttacking}) (~*)%w(~*'s) ({@meleeBodypart} {@meleeDamage}{.|!})$} {
   attackCrossSuccess
   meleeYouHitCrossRace
   } "" {case}
#TRIGGER {(You gracefully flow into {@meleeSwordForms}, {@meleeAttacking}) (~*)%w(~*'s) ({@meleeBodypart}.)$} {
   attackCrossSuccess
   meleeYouHitCrossRace
   } "" {case}
#TRIGGER {(You gracefully flow into {@meleeSwordForms}, {@meleeAttacking}) (~*)%w(~*'s) {@meleeBodypart} {@meleeDamage}{.|!})$} {
   attackCrossSuccess
   meleeYouHitCrossRace
   } "" {case}
#TRIGGER {(You spin effortlessly into {@meleeSwordForms}, {@meleeAttacking}) (~*)%w(~*'s) ({@meleeBodypart}.)$} {
   attackCrossSuccess
   meleeYouHitCrossRace
   } "" {case}
#TRIGGER {(You spin effortlessly into {@meleeSwordForms}, {@meleeAttacking}) (~*)%w(~*'s) ({@meleeBodypart} {@meleeDamage}{.|!})$} {
   attackCrossSuccess
   meleeYouHitCrossRace
   } "" {case}
#CLASS 0
#CLASS {MeleeRound|MeleeCrossRace}
#TRIGGER {(You {@meleeTickle}) (~*)%w(~*'s) ({@meleeBodypart} with your {@meleeAttack}.)$} {
   attackCrossSuccess
   meleeYouHitCrossRace
   } "" {case}
#TRIGGER {(You barely {@meleeAttack}) (~*)%w(~*'s) ({@meleeBodypart}.)$} {
   attackCrossSuccess
   meleeYouHitCrossRace
   } "" {case}
#TRIGGER {(You {@meleeAttack}) (~*)%w(~*'s) ({@meleeBodypart}.)$} {
   attackCrossSuccess
   meleeYouHitCrossRace
   } "" {case}
#TRIGGER {(You {@meleeAttack}) (~*)%w(~*'s) ({@meleeBodypart} {@meleeDamage}{.|!})$} {
   attackCrossSuccess
   meleeYouHitCrossRace
   } "" {case}
#TRIGGER {You try to {@meleeAttack} ~*%w~*, but {he|she} {deflects the blow|parries successfully}.$} {
   attackCrossParry
   } "" {case}
#TRIGGER {You try to {@meleeAttack} ~*%w~*, but {he|she} dodges the attack.$} {
   attackCrossDodge
   } "" {case}
#TRIGGER {~*%w~* swiftly dodges your attempt to {@meleeAttack} {him|her}.$} {
   attackCrossDodge
   } "" {case}
#TRIGGER {(~*)%w(~*) ({@meleeAttacked} your {@meleeBodypart}{.|!})$} {
   defendCrossHit
   meleeCrossRaceHitYou
   } "" {case}
#TRIGGER {(~*)%w(~*) ({@meleeAttacked} your {@meleeBodypart} {@meleeDamage}{.|!})$} {
   defendCrossHit
   meleeCrossRaceHitYou
   } "" {case}
#TRIGGER {(~*)%w(~*) (barely {@meleeAttacked} your {@meleeBodypart}.)$} {
   defendCrossHit
   meleeCrossRaceHitYou
   } "" {case}
#TRIGGER {(~*)%w(~*) ({barely tickles|tickles} your {@meleeBodypart} with {his|her} {@meleeAttack}.)$} {
   defendCrossHit
   meleeCrossRaceHitYou
   } "" {case}
#TRIGGER {~*%w~* tries to {@meleeAttack} you, but you {deflect the blow|parry successfully}.$} {
   defendCrossParry
   } "" {case}
#TRIGGER {~*%w~* tries to {@meleeAttack} you, but you dodge the attack.$} {
   defendCrossDodge
   } "" {case}
#TRIGGER {You swiftly dodge ~*%w~*'s attempt to {@meleeAttack} you.$} {
   defendCrossDodge
   } "" {case}
#CLASS 0
#CLASS {MeleeRound|MeleeRoundConnect} {enable}
#TRIGGER "meleeRoundConnectTrigger" {%s The Wheel Of Time MUD} {
   #T- {MeleeRound|MeleeRoundConnect}
   #PRIORITY {
      #IF (%class(MeleeRound|%concat(%char,MeleeRoundVariables))=-1) {
         #CLASS {MeleeRound|%concat(%char,MeleeRoundVariables)} {disable}
         #CLASS 0
         #VAR %concat("attack",%char,"CrossRaceDodge") {0} {_nodef} {MeleeRound|%concat(%char,MeleeRoundVariables)}
         #VAR %concat("attack",%char,"CrossRaceHit") {0} {_nodef} {MeleeRound|%concat(%char,MeleeRoundVariables)}
         #VAR %concat("attack",%char,"CrossRaceParry") {0} {_nodef} {MeleeRound|%concat(%char,MeleeRoundVariables)}
         #VAR %concat("attack",%char,"CrossRacePercent") {0} {_nodef} {MeleeRound|%concat(%char,MeleeRoundVariables)}
         #VAR %concat("attack",%char,"CrossRacePercentDodge") {0} {_nodef} {MeleeRound|%concat(%char,MeleeRoundVariables)}
         #VAR %concat("attack",%char,"CrossRacePercentParry") {0} {_nodef} {MeleeRound|%concat(%char,MeleeRoundVariables)}
         #VAR %concat("attack",%char,"CrossRaceTotal") {0} {_nodef} {MeleeRound|%concat(%char,MeleeRoundVariables)}
         #VAR %concat("defend",%char,"CrossRaceDodge") {0} {_nodef} {MeleeRound|%concat(%char,MeleeRoundVariables)}
         #VAR %concat("defend",%char,"CrossRaceHit") {0} {_nodef} {MeleeRound|%concat(%char,MeleeRoundVariables)}
         #VAR %concat("defend",%char,"CrossRaceParry") {0} {_nodef} {MeleeRound|%concat(%char,MeleeRoundVariables)}
         #VAR %concat("defend",%char,"CrossRacePercent") {0} {_nodef} {MeleeRound|%concat(%char,MeleeRoundVariables)}
         #VAR %concat("defend",%char,"CrossRacePercentDodge") {0} {_nodef} {MeleeRound|%concat(%char,MeleeRoundVariables)}
         #VAR %concat("defend",%char,"CrossRacePercentParry") {0} {_nodef} {MeleeRound|%concat(%char,MeleeRoundVariables)}
         #VAR %concat("defend",%char,"CrossRaceTotal") {0} {_nodef} {MeleeRound|%concat(%char,MeleeRoundVariables)}
         #VAR %concat(%char,"MROT") {%time("m/d/20y")} {_nodef} {MeleeRound|%concat(%char,MeleeRoundVariables)}
         } {#T+ {MeleeRound|%concat(%char,MeleeRoundVariables)}}
      }
   } "" {case}
#CLASS 0

_________________
House of Medakan zMUD Scripts: Table of Contents

House of Medakan cMUD Scripts: Table of Contents


Last edited by Taziar on Mon Aug 06, 2018 12:42 am, edited 25 times in total.

Top
 Profile  
 
 Post subject: Re: HoM zMUD Scripts
PostPosted: Sun Apr 23, 2017 9:07 pm 
Offline

Joined: Tue Apr 07, 2015 8:24 pm
Posts: 132
Location: Seattle
Type helpRent to view help file in client.

Image

This script relies heavily on your zMUD map, it uses the room locations for the rents and the names of the rooms and the names of the zones they are located in.
Rents must be added and you must be in that room on your map to make everything work correctly when adding equipment to your database.
You can check what equipment you have stored at any time, in any room, even offline!

Make sure to have your map location inside the correct rent room whenever you type the list command, this can and will over-write another rent.
When finished depositing or withdrawing at an inn you need to type list so that the script can save the current items properly into that rent file for that location.

Direct download link: RentHoM.txt

Active Triggers: 0/8
Input Triggers: 1
Code:
#CLASS {Rent}
#ALIAS helpRent {
   #PRIORITY {
      #SAY {%crlf "-----Rent Help File-----"}
      #SAY {"   [Updated: 2/21/2018]"}
      #SHOW {" Saves a list of all equipment deposited in any rent when the list command is used."}
      #SHOW {" Script saves data across all characters automatically adding new names via the %char function."}
      #SHOW {" Uses zMUD map functions %roomname, %roomnum and %zonename to save data for each rent location."}
      #SHOW {""}
      #SHOW {" Type showRent for list of available rents and usage syntax."}
      #SHOW {"  Syntax: showRent <rentnumber> [character, current if omitted]"}
      #SHOW {"   Example: showRent all <Name> will show all items in all rent locations for that character name."}
      #SHOW {""}
      #SHOW {" Type addRent in any room with an innkeeper to create a rent location there."}
      #SHOW {"  Note: Make sure zMUD map is in proper room position."}
      #SHOW {""}
      #SHOW {" Type clearRent <rentNumber> <characterName> to delete a character's rent for that location."}
      #SHOW {""}
      #SHOW {" Type searchRent <item keyword(s)> to search for an item in all rents across all alts."}
      #SHOW {""}
      }
   }
#ALIAS showRent {
   #IF (%null(%1)) {
      #SAY {%crlf "Type: showRent <rentnumber> [character, current if omitted]"}
      #SAY {" ---------Available Rents---------"}
      #LOOP 1,%numitems(@rentRoomNumbers) {#SHOW {%if(%len(%i)=1,"  "%i," "%i)) %item(@rentRoomZone,%i) - %item(@rentRoomNames,%i)}}
      #SHOW {""}
      } {}
   #IF (%null(%2)) {#VAR rentThisChar {%char}} {#VAR rentThisChar {%2}}
   #IF (%1=="all") {
      #SHOW {" -----Available Rents for "%proper(@rentThisChar)"-----"}
      #LOOP 1,%numitems(@rentRoomNumbers) {
         #VAR rentCurrent {%item(@rentRoomNumbers,%i)}
         #IF (%len(%eval(%concat("@",@rentThisChar,@rentCurrent)))==0) {} {
            #SAY {%crlf %item(@rentRoomZone,%i) - %item(@rentRoomNames,%i)}
            #LOOP 1,%numitems(%eval(%concat("@",@rentThisChar,@rentCurrent))) {
               #SHOW {%if(%len(%j)=1,"   "%j,"  "%j)) %item(%eval(%concat("@",@rentThisChar,@rentCurrent)),%j)}
               }
            }
         }
      } {}
   #IF (%int(%1)) {
      #VAR rentCurrent {%item(@rentRoomNumbers,%1)}
      #IF (%item(@rentRoomZone,%1) AND %item(@rentRoomNames,%1)) {#SAY {" "%item(@rentRoomZone,%1) - %item(@rentRoomNames,%1)}} {}
      #IF (%len(%eval(%concat("@",@rentThisChar,@rentCurrent)))==0) {
         #SAY {%crlf "You have no items stored at this location!"}
         } {
         #LOOP 1,%numitems(%eval(%concat("@",@rentThisChar,@rentCurrent))) {
            #SHOW {%if(%len(%i)=1,"  "%i," "%i)) %item(%eval(%concat("@",@rentThisChar,@rentCurrent)),%i)}
            }
         }
      } {}
   }
#ALIAS addRent {
   #IF (%ismember(%roomnum(),@rentRoomNumbers)) {#SAY {%crlf "Rent already in database."}} {
      #VAR rentRoomNumbers %additem(%roomnum(),@rentRoomNumbers)
      #VAR rentRoomNames %additem(%roomname(),@rentRoomNames)
      #VAR rentRoomZone %additem(%zonename(),@rentRoomZone)
      #SAY {%crlf "Rent added!"}
      }
   }
#ALIAS clearRent {
   #IF (%null(%1)) {
      #SAY {%crlf " Usage: clearRent <rentNumber> <characterName>"}
      } {
      #IF (%null(%item(@rentRoomNumbers,%1))) {
         #SAY {%crlf " Not a valid <rentNumber>, type showRent for list."}
         } {
         #IF (%ismember(%proper(%2),@rentCharacterList)) {
            #VAR rentClear {%item(@rentRoomNumbers,%1)}
            #VAR %concat(%lower(%2),@rentClear) {} {_nodef} {Rent|RentContent}
            #SAY {%crlf %item(@rentRoomZone,%1) - %item(@rentRoomNames,%1)"- Rent Cleared!" (%proper(%2))}
            } {#SAY {%crlf " Not a valid <characterName>..."}}
         }
      }
   }
#ALIAS searchRent {
   #IF (%len(%-1)>0) {
      #VAR rentSearchSuccessful {0}
      #VAR rentSearchItem {%lower(%-1)}
      #SAY {%crlf "Searching rents for: "%-1}
      #LOOP 1,%numitems(@rentCharacterList) {
         #LOOP 1,%numitems(@rentRoomNumbers) {
            #IF (%pos(@rentSearchItem,%eval(%concat("@",%item(@rentCharacterList,%i),%item(@rentRoomNumbers,%j))))>0) {
               #VAR rentSearchSuccessful {1}
               #SHOW {%crlf %proper(%item(@rentCharacterList,%i)) - %item(@rentRoomZone,%j) - %item(@rentRoomNames,%j)}
               #LOOP 1,%numitems(%eval(%concat("@",%item(@rentCharacterList,%i),%item(@rentRoomNumbers,%j)))) {
                  #IF (%pos(@rentSearchItem,%item(%eval(%concat("@",%item(@rentCharacterList,%i),%item(@rentRoomNumbers,%j))),%k))>0) {
                     #SAY {%if(%len(%k)=1,"   "%k,"  "%k)) %item(%eval(%concat("@",%item(@rentCharacterList,%i),%item(@rentRoomNumbers,%j))),%k)}
                     } {
                     #SHOW {%if(%len(%k)=1,"   "%k,"  "%k)) %item(%eval(%concat("@",%item(@rentCharacterList,%i),%item(@rentRoomNumbers,%j))),%k)}
                  }
               }
            } {}
         }
      }
      #IF (@rentSearchSuccessful=0) {
         #SAY {%crlf "Did not find any: "@rentSearchItem}
         } {}
      } {
      #SAY {%crlf "Type: searchRent <item keyword(s)>"}
      }
   }
#VAR rentClear {}
#VAR rentCurrent {}
#VAR rentSearchItem {}
#VAR rentSearchSuccessful {}
#VAR rentTempContent {}
#VAR rentThisChar {}
#TRIGGER "rentInnTrigger" {tells you, 'I don't have any items for you here.'$} {
   #T- {rentInnTrigger}
   #T- {rentListTrigger}
   #VAR rentCurrent {%roomnum()}
   #VAR %concat(%lower(%char),@rentCurrent) {} {_nodef} {Rent|RentContent}
   #SAY {%crlf " Rent Cleared!"}
   } "" {case|disable}
#TRIGGER "rentListTrigger" {1.*{item|items} stored for} {
   #T- {rentInnTrigger}
   #T- {rentListTrigger}
   #IF (%ismember(%roomnum(),@rentRoomNumbers)) {
      #T+ {rentPromptTrigger}
      #T+ {rentItemTrigger1}
      #T+ {rentItemTrigger2}
      #T+ {rentItemTrigger3}
      #VAR rentCurrent {%roomnum()}
      #VAR rentTempContent {}
      }
   } "" {disable|case}
#TRIGGER "rentItemTrigger1" {^    ([a-z]*)$} {#PRIORITY {#VAR rentTempContent %additem( "%1", @rentTempContent)}} "" {disable}
#TRIGGER "rentItemTrigger2" {^      ([a-z]*)$} {#PRIORITY {#VAR rentTempContent %additem( "%1", @rentTempContent)}} "" {disable}
#TRIGGER "rentItemTrigger3" {^         ([a-z]*)$} {#PRIORITY {#VAR rentTempContent %additem( "%1", @rentTempContent)}} "" {disable}
#TRIGGER "rentPromptTrigger" {^{o|*} * >} {
   #T- {rentPromptTrigger}
   #T- {rentItemTrigger1}
   #T- {rentItemTrigger2}
   #T- {rentItemTrigger3}
   #VAR %concat(%lower(%char),@rentCurrent) {@rentTempContent} {_nodef} {Rent|RentContent}
   #VAR rentTempContent {}
   #SAY {" Rent Updated!"}
   } "" {case|disable|prompt|nocr}
#TRIGGER "rentListPrompt" {^{o|*} * >} {
   #T- {rentListPrompt}
   #T- {rentInnTrigger}
   #T- {rentListTrigger}
   } "" {case|disable|prompt|nocr}
#ONINPUT "rentListInput" {^{li|lis|list}$} {
   #T+ {rentInnTrigger}
   #T+ {rentListTrigger}
   #T+ {rentListPrompt}
   } "" {}
#CLASS 0
#CLASS {Rent|RentConnect} {enable}
#TRIGGER "RentConnectTrigger" {%s The Wheel Of Time MUD} {
   #T- {Rent|RentConnect}
   #ADDITEM rentCharacterList {%char}
   } "" {case}
#CLASS 0
#CLASS {Rent|RentContent}
#VAR rentCharacterList {}
#VAR rentRoomNames {}
#VAR rentRoomNumbers {}
#VAR rentRoomZone {}
#CLASS 0

_________________
House of Medakan zMUD Scripts: Table of Contents

House of Medakan cMUD Scripts: Table of Contents


Last edited by Taziar on Sat Aug 25, 2018 1:20 am, edited 6 times in total.

Top
 Profile  
 
 Post subject: Re: HoM zMUD Scripts
PostPosted: Sun Apr 23, 2017 9:39 pm 
Offline

Joined: Tue Apr 07, 2015 8:24 pm
Posts: 132
Location: Seattle
Type helpClumsy to view help file in client.

Image

Direct download link: ClumsyHoM.txt

Active Triggers: 3/18
Input Triggers: 2
Code:
#CLASS {Clumsy}
#ALIAS helpClumsy {
   #PRIORITY {
      #SAY {%crlf "----Clumsy Help File----"}
      #SAY {"   [Updated: 7/13/2018]"}
      #SHOW {" Script tracks individual character data across sessions, automatically adding character on connection."}
      #SHOW {"  Note: must use bas or bash, kic or kick in command line or zMUD alias."}
      #SHOW {"    WoTMUD alias will not activate bash or kick clumsy stats."}
      #SHOW {""}
      #SHOW {" Type showClumsy to toggle session message on/off for all characters."}
      #SHOW {" Type showClumsyOT to toggle over time message on/off for current character."}
      #SHOW {""}
      #SHOW {" Type any of the following commands to show individual clumsy data: "}
      #SHOW {"   bashCount"}
      #SHOW {"   chargeCount"}
      #SHOW {"   clumsyCount"}
      #SHOW {"   kickCount"}
      #SHOW {"   stabCount"}
      #SHOW {"   throwCount"}
      #SHOW {"   throwCritCount."}
      #SHOW {""}
      #SHOW {" Type resetClumsy to reset data for current session only."}
      #SHOW {" Type resetClumsyData to reset ALL data for current character."}
      #SHOW {"  Note: Shows date (month/day/year) since resetting data."}
      #SHOW {""}
      }
   }
#ALIAS showClumsy {
   #IF (@showClumsy=1) {#VAR showClumsy {0}} {#VAR showClumsy {1}}
   #IF (@showClumsy=1) {#SAY {Clumsy session message is turned on.}} {#SAY {Clumsy session message is turned off.}}
   }
#ALIAS showClumsyOT {
   #IF (%eval(%concat("@show",%char,"OT"))) {#VAR %concat("show",%char,"OT") {0}} {#VAR %concat("show",%char,"OT") {1}}
   #IF (%eval(%concat("@show",%char,"OT"))) {#SAY {Clumsy over time message for %char is turned on.}} {#SAY {Clumsy over time message for %char is turned off.}}
   }
#ALIAS bashCount {
   #SHOW {%crlf "Bash Data:"}
   #IF (@clumsyTotalBash>0) {#SAY {This session you've landed @clumsyLandBash out of @clumsyTotalBash bashes (@{clumsyPercentageBash}~% landed)}} {#SAY {No current session data available...}}
   #IF (@clumsyTotalBash>0) {#SAY {Since %eval(%concat("@",%char,"OT")) you've landed %eval(%concat("@clumsy",%char,"LandBash")) out of %eval(%concat("@clumsy",%char,"TotalBash")) bashes (%eval(%concat("@clumsy",%char,"PercentageBash"))~% landed)}} {#SAY {No over time data available...}}
   }
#ALIAS chargeCount {
   #SHOW {%crlf "Charge Data:"}
   #IF (@clumsyTotalCharge>0) {#SAY {This session you've landed @clumsyLandCharge out of @clumsyTotalCharge charges (@{clumsyPercentageCharge}~% landed)}} {#SAY {No current session data available...}}
   #IF (%eval(%concat("@clumsy",%char,"TotalCharge"))>0) {#SAY {Since %eval(%concat("@",%char,"OT")) you've landed %eval(%concat("@clumsy",%char,"LandCharge")) out of %eval(%concat("@clumsy",%char,"TotalCharge")) charges (%eval(%concat("@clumsy",%char,"PercentageCharge"))~% landed)}} {#SAY {No over time data available...}}
   }
#ALIAS clumsyCount {
   #SHOW {""}
   bashCount
   chargeCount
   kickCount
   stabCount
   throwCount
   throwCritCount
   }
#ALIAS kickCount {
   #SHOW {%crlf "Kick Data:"}
   #IF (@clumsyTotalKick>0) {#SAY {This session you've landed @clumsyLandKick out of @clumsyTotalKick kicks (@{clumsyPercentageKick}~% landed)}} {#SAY {No current session data available...}}
   #IF (%eval(%concat("@clumsy",%char,"TotalKick"))>0) {#SAY {Since %eval(%concat("@",%char,"OT")) you've landed %eval(%concat("@clumsy",%char,"LandKick")) out of %eval(%concat("@clumsy",%char,"TotalKick")) kicks (%eval(%concat("@clumsy",%char,"PercentageKick"))~% landed)}} {#SAY {No over time data available...}}
   }
#ALIAS stabCount {
   #SHOW {%crlf "Stab Data:"}
   #IF (@clumsyTotalStab>0) {#SAY {This session you've landed @clumsyLandStab out of @clumsyTotalStab stabs (@{clumsyPercentageStab}~% landed)}} {#SAY {No current session data available...}}
   #IF (%eval(%concat("@clumsy",%char,"TotalStab"))>0) {#SAY {Since %eval(%concat("@",%char,"OT")) you've landed %eval(%concat("@clumsy",%char,"LandStab")) out of %eval(%concat("@clumsy",%char,"TotalStab")) stabs (%eval(%concat("@clumsy",%char,"PercentageStab"))~% landed)}} {#SAY {No over time data available...}}
   }
#ALIAS throwCount {
   #SHOW {%crlf "Throw Data:"}
   #IF (@clumsyTotalThrow>0) {#SAY {This session you've landed @clumsyLandThrow out of @clumsyTotalThrow throws (@{clumsyPercentageThrow}~% landed)}} {#SAY {No current session data available...}}
   #IF (%eval(%concat("@clumsy",%char,"TotalThrow"))>0) {#SAY {Since %eval(%concat("@",%char,"OT")) you've landed %eval(%concat("@clumsy",%char,"LandThrow")) out of %eval(%concat("@clumsy",%char,"TotalThrow")) throws (%eval(%concat("@clumsy",%char,"PercentageThrow"))~% landed)}} {#SAY {No over time data available...}}
   }
#ALIAS throwCritCount {
   #SHOW {%crlf "Critical Throw Data:"}
   #IF (@clumsyTotalThrow>0) {#SAY {This session you've landed @clumsyLandThrowCritical critical throws out of @clumsyLandThrow total landed throws (@{clumsyPercentageThrowCritical}~% crits landed)}} {#SAY {No current session data available...}}
   #IF (%eval(%concat("@clumsy",%char,"LandThrow"))>0) {#SAY {Since %eval(%concat("@",%char,"OT")) you've landed %eval(%concat("@clumsy",%char,"LandThrowCritical")) criticals out of %eval(%concat("@clumsy",%char,"LandThrow")) total landed throws (%eval(%concat("@clumsy",%char,"PercentageThrowCritical"))~% crits landed)}} {#SAY {No over time data available...}}
   }
#ALIAS clumsyThrowTriggers {
   #IF (%1=on) {
      #T+ clumsyThrowLand
      #T+ clumsyThrowRip
      #T+ clumsyThrowCrit
      #T+ clumsyThrowDeflect
      #T+ clumsyThrowMiss
      } {}
   #IF (%1=off) {
      #T- clumsyThrowLand
      #T- clumsyThrowRip
      #T- clumsyThrowCrit
      #T- clumsyThrowDeflect
      #T- clumsyThrowMiss
      } {}
   }
#ALIAS clumsyKickTriggers {
   #IF (%1=on) {
      #T+ clumsyKickLand
      #T+ clumsyKickHit
      #T+ clumsyKickMile
      #T+ clumsyKickMiss
      } {}
   #IF (%1=off) {
      #T- clumsyKickLand
      #T- clumsyKickHit
      #T- clumsyKickMile
      #T- clumsyKickMiss
      } {}
   }
#ALIAS clumsyBashTriggers {
   #IF (%1=on) {
      #T+ clumsyBashLand
      #T+ clumsyBashTopple
      } {}
   #IF (%1=off) {
      #T- clumsyBashLand
      #T- clumsyBashTopple
      } {}
   }
#ALIAS resetClumsyData {
   #RESET {Clumsy}
   #VAR %concat("clumsy",%char,"LandBash") {0} {_nodef} {Clumsy|%concat(%char,ClumsyVariables)}
   #VAR %concat("clumsy",%char,"LandCharge") {0} {_nodef} {Clumsy|%concat(%char,ClumsyVariables)}
   #VAR %concat("clumsy",%char,"LandKick") {0} {_nodef} {Clumsy|%concat(%char,ClumsyVariables)}
   #VAR %concat("clumsy",%char,"LandStab") {0} {_nodef} {Clumsy|%concat(%char,ClumsyVariables)}
   #VAR %concat("clumsy",%char,"LandThrow") {0} {_nodef} {Clumsy|%concat(%char,ClumsyVariables)}
   #VAR %concat("clumsy",%char,"LandThrowCritical") {0} {_nodef} {Clumsy|%concat(%char,ClumsyVariables)}
   #VAR %concat("clumsy",%char,"MissBash") {0} {_nodef} {Clumsy|%concat(%char,ClumsyVariables)}
   #VAR %concat("clumsy",%char,"MissCharge") {0} {_nodef} {Clumsy|%concat(%char,ClumsyVariables)}
   #VAR %concat("clumsy",%char,"MissKick") {0} {_nodef} {Clumsy|%concat(%char,ClumsyVariables)}
   #VAR %concat("clumsy",%char,"MissStab") {0} {_nodef} {Clumsy|%concat(%char,ClumsyVariables)}
   #VAR %concat("clumsy",%char,"MissThrow") {0} {_nodef} {Clumsy|%concat(%char,ClumsyVariables)}
   #VAR %concat("clumsy",%char,"PercentageBash") {0} {_nodef} {Clumsy|%concat(%char,ClumsyVariables)}
   #VAR %concat("clumsy",%char,"PercentageCharge") {0} {_nodef} {Clumsy|%concat(%char,ClumsyVariables)}
   #VAR %concat("clumsy",%char,"PercentageDisarm") {0} {_nodef} {Clumsy|%concat(%char,ClumsyVariables)}
   #VAR %concat("clumsy",%char,"PercentageKick") {0} {_nodef} {Clumsy|%concat(%char,ClumsyVariables)}
   #VAR %concat("clumsy",%char,"PercentageStab") {0} {_nodef} {Clumsy|%concat(%char,ClumsyVariables)}
   #VAR %concat("clumsy",%char,"PercentageThrow") {0} {_nodef} {Clumsy|%concat(%char,ClumsyVariables)}
   #VAR %concat("clumsy",%char,"PercentageThrowCritical") {0} {_nodef} {Clumsy|%concat(%char,ClumsyVariables)}
   #VAR %concat("clumsy",%char,"RoundPercent") {0} {_nodef} {Clumsy|%concat(%char,ClumsyVariables)}
   #VAR %concat("clumsy",%char,"RoundTotal") {0} {_nodef} {Clumsy|%concat(%char,ClumsyVariables)}
   #VAR %concat("clumsy",%char,"TotalBash") {0} {_nodef} {Clumsy|%concat(%char,ClumsyVariables)}
   #VAR %concat("clumsy",%char,"TotalCharge") {0} {_nodef} {Clumsy|%concat(%char,ClumsyVariables)}
   #VAR %concat("clumsy",%char,"TotalKick") {0} {_nodef} {Clumsy|%concat(%char,ClumsyVariables)}
   #VAR %concat("clumsy",%char,"TotalStab") {0} {_nodef} {Clumsy|%concat(%char,ClumsyVariables)}
   #VAR %concat("clumsy",%char,"TotalThrow") {0} {_nodef} {Clumsy|%concat(%char,ClumsyVariables)}
   #VAR %concat(%char,"OT") {%time("m/d/20y")} {_nodef} {Clumsy|%concat(%char,ClumsyVariables)}
   #SAY {Clumsy data for %char is now reset.}
   }
#ALIAS resetClumsy {
   #RESET {Clumsy}
   }
#VAR clumsyLandBash {0} {0}
#VAR clumsyLandCharge {0} {0}
#VAR clumsyLandDisarm {0} {0}
#VAR clumsyLandKick {0} {0}
#VAR clumsyLandStab {0} {0}
#VAR clumsyLandThrow {0} {0}
#VAR clumsyLandThrowCritical {0} {0}
#VAR clumsyMissBash {0} {0}
#VAR clumsyMissCharge {0} {0}
#VAR clumsyMissKick {0} {0}
#VAR clumsyMissStab {0} {0}
#VAR clumsyMissThrow {0} {0}
#VAR clumsyPercentageBash {0} {0}
#VAR clumsyPercentageCharge {0} {0}
#VAR clumsyPercentageDisarm {0} {0}
#VAR clumsyPercentageKick {0} {0}
#VAR clumsyPercentageStab {0} {0}
#VAR clumsyPercentageThrow {0} {0}
#VAR clumsyPercentageThrowCritical {0} {0}
#VAR clumsyRoundDisarm {0} {0}
#VAR clumsyRoundPercent {0} {0}
#VAR clumsyRoundTotal {0} {0}
#VAR clumsyTotalBash {0} {0}
#VAR clumsyTotalCharge {0} {0}
#VAR clumsyTotalKick {0} {0}
#VAR clumsyTotalStab {0} {0}
#VAR clumsyTotalThrow {0} {0}
#VAR showClumsy {1}
#TRIGGER "clumsyBashLand" {^Your bash at * sprawling!$} {
   clumsyBashTriggers off
   #ADD clumsyLandBash 1
   #ADD %concat("clumsy",%char,"LandBash") 1
   #MATH clumsyTotalBash @clumsyLandBash+@clumsyMissBash
   #MATH clumsyPercentageBash (@clumsyLandBash*100/@clumsyTotalBash)
   #MATH %concat("clumsy",%char,"TotalBash") %eval(%concat("@clumsy",%char,"LandBash"))+%eval(%concat("@clumsy",%char,"MissBash"))
   #MATH %concat("clumsy",%char,"PercentageBash") (%eval(%concat("@clumsy",%char,"LandBash"))*100/%eval(%concat("@clumsy",%char,"TotalBash")))
   #IF (@showClumsy) {#SAY {This session you've landed @clumsyLandBash out of @clumsyTotalBash bashes (@{clumsyPercentageBash}~% landed)}} {}
   #IF (%eval(%concat("@show",%char,"OT"))) {
      #SAY {Since %eval(%concat("@",%char,"OT")) you've landed %eval(%concat("@clumsy",%char,"LandBash")) out of %eval(%concat("@clumsy",%char,"TotalBash")) bashes (%eval(%concat("@clumsy",%char,"PercentageBash"))~% landed)}
      } {}
   } "" {case|disable}
#TRIGGER "clumsyBashTopple" {^As * your bash, you topple over and fall to the ground!$} {
   clumsyBashTriggers off
   #ADD clumsyMissBash 1
   #ADD %concat("clumsy",%char,"MissBash") 1
   #MATH clumsyTotalBash @clumsyLandBash+@clumsyMissBash
   #MATH clumsyPercentageBash (@clumsyLandBash*100/@clumsyTotalBash)
   #MATH %concat("clumsy",%char,"TotalBash") %eval(%concat("@clumsy",%char,"LandBash"))+%eval(%concat("@clumsy",%char,"MissBash"))
   #MATH %concat("clumsy",%char,"PercentageBash") (%eval(%concat("@clumsy",%char,"LandBash"))*100/%eval(%concat("@clumsy",%char,"TotalBash")))
   #IF (@showClumsy) {#SAY {This session you've missed @clumsyMissBash out of @clumsyTotalBash bashes (@{clumsyPercentageBash}~% landed)}} {}
   #IF (%eval(%concat("@show",%char,"OT"))) {
      #SAY {Since %eval(%concat("@",%char,"OT")) you've missed %eval(%concat("@clumsy",%char,"MissBash")) out of %eval(%concat("@clumsy",%char,"TotalBash")) bashes (%eval(%concat("@clumsy",%char,"PercentageBash"))~% landed)}
      } {}
   } "" {case|disable}
#TRIGGER "clumsyChargeTrigger" {You line up your charge...$} {
   #T+ {clumsyChargeLand}
   #T+ {clumsyChargeOops}
   #ALARM "clumsyChargeAlarm" +10 {
      #T- {clumsyChargeLand}
      #T- {clumsyChargeOops}
      } "Clumsy"
   } "" {case}
#TRIGGER "clumsyChargeLand" {^Chaaaaarrrge!! * bleeds profusely as you skewer * with *!$} {
   #T- {clumsyChargeLand}
   #T- {clumsyChargeOops}
   #ADD clumsyLandCharge 1
   #ADD %concat("clumsy",%char,"LandCharge") 1
   #MATH clumsyTotalCharge @clumsyMissCharge+@clumsyLandCharge
   #MATH clumsyPercentageCharge (@clumsyLandCharge*100/@clumsyTotalCharge)
   #MATH %concat("clumsy",%char,"TotalCharge") %eval(%concat("@clumsy",%char,"MissCharge"))+%eval(%concat("@clumsy",%char,"LandCharge"))
   #MATH %concat("clumsy",%char,"PercentageCharge") (%eval(%concat("@clumsy",%char,"LandCharge"))*100/%eval(%concat("@clumsy",%char,"TotalCharge")))
   #IF (@showClumsy) {#SAY {This session you've landed @clumsyLandCharge out of @clumsyTotalCharge charges (@{clumsyPercentageCharge}~% landed)}} {}
   #IF (%eval(%concat("@show",%char,"OT"))) {
      #SAY {Since %eval(%concat("@",%char,"OT")) you've landed %eval(%concat("@clumsy",%char,"LandCharge")) out of %eval(%concat("@clumsy",%char,"TotalCharge")) charges (%eval(%concat("@clumsy",%char,"PercentageCharge"))~% landed)}
      } {}
   } "" {case|disable}
#TRIGGER "clumsyChargeOops" {^Oops. Your lame efforts cause you to miss.$} {
   #T- {clumsyChargeLand}
   #T- {clumsyChargeOops}
   #ADD clumsyMissCharge 1
   #ADD %concat("clumsy",%char,"MissCharge") 1
   #MATH clumsyTotalCharge @clumsyMissCharge+@clumsyLandCharge
   #MATH clumsyPercentageCharge (@clumsyLandCharge*100/@clumsyTotalCharge)
   #MATH %concat("clumsy",%char,"TotalCharge") %eval(%concat("@clumsy",%char,"MissCharge"))+%eval(%concat("@clumsy",%char,"LandCharge"))
   #MATH %concat("clumsy",%char,"PercentageCharge") (%eval(%concat("@clumsy",%char,"LandCharge"))*100/%eval(%concat("@clumsy",%char,"TotalCharge")))
   #IF (@showClumsy) {#SAY {This session you've clumsied @clumsyMissCharge out of @clumsyTotalCharge charges (@{clumsyPercentageCharge}~% landed)}} {}
   #IF (%eval(%concat("@show",%char,"OT"))) {
      #SAY {Since %eval(%concat("@",%char,"OT")) you've clumsied %eval(%concat("@clumsy",%char,"MissCharge")) out of %eval(%concat("@clumsy",%char,"TotalCharge")) charges (%eval(%concat("@clumsy",%char,"PercentageCharge"))~% landed)}
      } {}   
   } "" {case|disable}
#TRIGGER "clumsyKickLand" {Your boots need polishing again -- blood all over...$} {
   clumsyKickTriggers off
   #ADD clumsyLandKick 1
   #ADD %concat("clumsy",%char,"LandKick") 1
   #MATH clumsyTotalKick @clumsyLandKick+@clumsyMissKick
   #MATH clumsyPercentageKick (@clumsyLandKick*100/@clumsyTotalKick)
   #MATH %concat("clumsy",%char,"TotalKick") %eval(%concat("@clumsy",%char,"LandKick"))+%eval(%concat("@clumsy",%char,"MissKick"))
   #MATH %concat("clumsy",%char,"PercentageKick") (%eval(%concat("@clumsy",%char,"LandKick"))*100/%eval(%concat("@clumsy",%char,"TotalKick")))
   #IF (@showClumsy) {#SAY {This session you've landed @clumsyLandKick out of @clumsyTotalKick kicks (@{clumsyPercentageKick}~% landed)}} {}
   #IF (%eval(%concat("@show",%char,"OT"))) {
      #SAY {Since %eval(%concat("@",%char,"OT")) you've landed %eval(%concat("@clumsy",%char,"LandKick")) out of %eval(%concat("@clumsy",%char,"TotalKick")) kicks (%eval(%concat("@clumsy",%char,"PercentageKick"))~% landed)}
      } {}   
   } "" {case|disable}
#TRIGGER "clumsyKickHit" {Your kick hits * in the solar plexus!$} {
   clumsyKickTriggers off
   #ADD clumsyLandKick 1
   #ADD %concat("clumsy",%char,"LandKick") 1
   #MATH clumsyTotalKick @clumsyLandKick+@clumsyMissKick
   #MATH clumsyPercentageKick (@clumsyLandKick*100/@clumsyTotalKick)
   #MATH %concat("clumsy",%char,"TotalKick") %eval(%concat("@clumsy",%char,"LandKick"))+%eval(%concat("@clumsy",%char,"MissKick"))
   #MATH %concat("clumsy",%char,"PercentageKick") (%eval(%concat("@clumsy",%char,"LandKick"))*100/%eval(%concat("@clumsy",%char,"TotalKick")))
   #IF (@showClumsy) {#SAY {This session you've landed @clumsyLandKick out of @clumsyTotalKick kicks (@{clumsyPercentageKick}~% landed)}} {}
   #IF (%eval(%concat("@show",%char,"OT"))) {
      #SAY {Since %eval(%concat("@",%char,"OT")) you've landed %eval(%concat("@clumsy",%char,"LandKick")) out of %eval(%concat("@clumsy",%char,"TotalKick")) kicks (%eval(%concat("@clumsy",%char,"PercentageKick"))~% landed)}
      } {}   
   } "" {case|disable}
#TRIGGER "clumsyKickMiss" {You miss your kick at * groin, much to * relief...$} {
   clumsyKickTriggers off
   #ADD clumsyMissKick 1
   #ADD %concat("clumsy",%char,"MissKick") 1
   #MATH clumsyTotalKick @clumsyLandKick+@clumsyMissKick
   #MATH clumsyPercentageKick (@clumsyLandKick*100/@clumsyTotalKick)
   #MATH %concat("clumsy",%char,"TotalKick") %eval(%concat("@clumsy",%char,"LandKick"))+%eval(%concat("@clumsy",%char,"MissKick"))
   #MATH %concat("clumsy",%char,"PercentageKick") (%eval(%concat("@clumsy",%char,"LandKick"))*100/%eval(%concat("@clumsy",%char,"TotalKick")))
   #IF (@showClumsy) {#SAY {This session you've clumsied @clumsyMissKick out of @clumsyTotalKick kicks (@{clumsyPercentageKick}~% landed)}} {}
   #IF (%eval(%concat("@show",%char,"OT"))) {
      #SAY {Since %eval(%concat("@",%char,"OT")) you've clumsied %eval(%concat("@clumsy",%char,"MissKick")) out of %eval(%concat("@clumsy",%char,"TotalKick")) kicks (%eval(%concat("@clumsy",%char,"PercentageKick"))~% landed)}
      } {}
   } "" {case|disable}
#TRIGGER "clumsyKickMile" {Your beautiful full-circle kick misses * by a mile.$} {
   clumsyKickTriggers off
   #ADD clumsyMissKick 1
   #ADD %concat("clumsy",%char,"MissKick") 1
   #MATH clumsyTotalKick @clumsyLandKick+@clumsyMissKick
   #MATH clumsyPercentageKick (@clumsyLandKick*100/@clumsyTotalKick)
   #MATH %concat("clumsy",%char,"TotalKick") %eval(%concat("@clumsy",%char,"LandKick"))+%eval(%concat("@clumsy",%char,"MissKick"))
   #MATH %concat("clumsy",%char,"PercentageKick") (%eval(%concat("@clumsy",%char,"LandKick"))*100/%eval(%concat("@clumsy",%char,"TotalKick")))
   #IF (@showClumsy) {#SAY {This session you've clumsied @clumsyMissKick out of @clumsyTotalKick kicks (@{clumsyPercentageKick}~% landed)}} {}
   #IF (%eval(%concat("@show",%char,"OT"))) {
      #SAY {Since %eval(%concat("@",%char,"OT")) you've clumsied %eval(%concat("@clumsy",%char,"MissKick")) out of %eval(%concat("@clumsy",%char,"TotalKick")) kicks (%eval(%concat("@clumsy",%char,"PercentageKick"))~% landed)}
      } {}
   } "" {case|disable}
#TRIGGER "clumsyThrowTrigger" {You throw * at *.$} {
   clumsyThrowTriggers on
   #ALARM "clumsyThrowAlarm" +10 {clumsyThrowTriggers off} "Clumsy"
   } "" {case}
#TRIGGER "clumsyThrowLand" {^* grunts in pain as * is struck by *.$} {
   clumsyThrowTriggers off
   #ADD clumsyLandThrow 1
   #ADD %concat("clumsy",%char,"LandThrow") 1
   #MATH clumsyTotalThrow @clumsyMissThrow+@clumsyLandThrow
   #MATH clumsyPercentageThrow (@clumsyLandThrow*100/@clumsyTotalThrow)
   #MATH %concat("clumsy",%char,"TotalThrow") %eval(%concat("@clumsy",%char,"MissThrow"))+%eval(%concat("@clumsy",%char,"LandThrow"))
   #MATH %concat("clumsy",%char,"PercentageThrow") (%eval(%concat("@clumsy",%char,"LandThrow"))*100/%eval(%concat("@clumsy",%char,"TotalThrow")))
   #IF (@showClumsy) {#SAY {This session you've landed @clumsyLandThrow out of @clumsyTotalThrow throws (@{clumsyPercentageThrow}~% landed)}} {}
   #IF (%eval(%concat("@show",%char,"OT"))) {
      #SAY {Since %eval(%concat("@",%char,"OT")) you've landed %eval(%concat("@clumsy",%char,"LandThrow")) out of %eval(%concat("@clumsy",%char,"TotalThrow")) throws (%eval(%concat("@clumsy",%char,"PercentageThrow"))~% landed)}
      } {}
   } "" {case|disable}
#TRIGGER "clumsyThrowRip" {^* rips through * guts as * collapses to the ground.$} {
   clumsyThrowTriggers off
   #ADD clumsyLandThrow 1
   #ADD %concat("clumsy",%char,"LandThrow") 1
   #MATH clumsyTotalThrow @clumsyMissThrow+@clumsyLandThrow
   #MATH clumsyPercentageThrow (@clumsyLandThrow*100/@clumsyTotalThrow)
   #MATH %concat("clumsy",%char,"TotalThrow") %eval(%concat("@clumsy",%char,"MissThrow"))+%eval(%concat("@clumsy",%char,"LandThrow"))
   #MATH %concat("clumsy",%char,"PercentageThrow") (%eval(%concat("@clumsy",%char,"LandThrow"))*100/%eval(%concat("@clumsy",%char,"TotalThrow")))
   #IF (@showClumsy) {#SAY {This session you've landed @clumsyLandThrow out of @clumsyTotalThrow throws (@{clumsyPercentageThrow}~% landed)}} {}
   #IF (%eval(%concat("@show",%char,"OT"))) {
      #SAY {Since %eval(%concat("@",%char,"OT")) you've landed %eval(%concat("@clumsy",%char,"LandThrow")) out of %eval(%concat("@clumsy",%char,"TotalThrow")) throws (%eval(%concat("@clumsy",%char,"PercentageThrow"))~% landed)}
      } {}
   } "" {case|disable}
#TRIGGER "clumsyThrowCrit" {^* spasms in excruciating pain as * is struck by *.$} {
   clumsyThrowTriggers off
   #ADD clumsyLandThrow 1
   #ADD clumsyLandThrowCritical 1
   #ADD %concat("clumsy",%char,"LandThrow") 1
   #ADD %concat("clumsy",%char,"LandThrowCritical") 1
   #MATH clumsyPercentageThrowCritical (@clumsyLandThrowCritical*100/@clumsyLandThrow)
   #MATH %concat("clumsy",%char,"PercentageThrowCritical") (%eval(%concat("@clumsy",%char,"LandThrowCritical"))*100/%eval(%concat("@clumsy",%char,"LandThrow")))
   #MATH clumsyTotalThrow @clumsyMissThrow+@clumsyLandThrow
   #MATH clumsyPercentageThrow (@clumsyLandThrow*100/@clumsyTotalThrow)
   #MATH %concat("clumsy",%char,"TotalThrow") %eval(%concat("@clumsy",%char,"MissThrow"))+%eval(%concat("@clumsy",%char,"LandThrow"))
   #MATH %concat("clumsy",%char,"PercentageThrow") (%eval(%concat("@clumsy",%char,"LandThrow"))*100/%eval(%concat("@clumsy",%char,"TotalThrow")))
   #IF (@showClumsy) {#SAY {This session you've landed @clumsyLandThrow out of @clumsyTotalThrow throws (@{clumsyPercentageThrow}~% landed)}} {}
   #IF (%eval(%concat("@show",%char,"OT"))) {
      #SAY {Since %eval(%concat("@",%char,"OT")) you've landed %eval(%concat("@clumsy",%char,"LandThrow")) out of %eval(%concat("@clumsy",%char,"TotalThrow")) throws (%eval(%concat("@clumsy",%char,"PercentageThrow"))~% landed)}
      } {}
   } "" {case|disable}
#TRIGGER "clumsyThrowDeflect" {^* deflects * that was thrown at *.$} {
   clumsyThrowTriggers off
   #ADD clumsyMissThrow 1
   #ADD %concat("clumsy",%char,"MissThrow") 1
   #MATH clumsyTotalThrow @clumsyMissThrow+@clumsyLandThrow
   #MATH clumsyPercentageThrow (@clumsyLandThrow*100/@clumsyTotalThrow)
   #MATH %concat("clumsy",%char,"TotalThrow") %eval(%concat("@clumsy",%char,"MissThrow"))+%eval(%concat("@clumsy",%char,"LandThrow"))
   #MATH %concat("clumsy",%char,"PercentageThrow") (%eval(%concat("@clumsy",%char,"LandThrow"))*100/%eval(%concat("@clumsy",%char,"TotalThrow")))
   #IF (@showClumsy) {#SAY {This session you've clumsied @clumsyMissThrow out of @clumsyTotalThrow throws (@{clumsyPercentageThrow}~% landed)}} {}
   #IF (%eval(%concat("@show",%char,"OT"))) {
      #SAY {Since %eval(%concat("@",%char,"OT")) you've clumsied %eval(%concat("@clumsy",%char,"MissThrow")) out of %eval(%concat("@clumsy",%char,"TotalThrow")) throws (%eval(%concat("@clumsy",%char,"PercentageThrow"))~% landed)}
      } {}   
   } "" {case|disable}
#TRIGGER "clumsyThrowMiss" {^* just misses * and falls to the ground.$} {
   clumsyThrowTriggers off
   #ADD clumsyMissThrow 1
   #ADD %concat("clumsy",%char,"MissThrow") 1
   #MATH clumsyTotalThrow @clumsyMissThrow+@clumsyLandThrow
   #MATH clumsyPercentageThrow (@clumsyLandThrow*100/@clumsyTotalThrow)
   #MATH %concat("clumsy",%char,"TotalThrow") %eval(%concat("@clumsy",%char,"MissThrow"))+%eval(%concat("@clumsy",%char,"LandThrow"))
   #MATH %concat("clumsy",%char,"PercentageThrow") (%eval(%concat("@clumsy",%char,"LandThrow"))*100/%eval(%concat("@clumsy",%char,"TotalThrow")))
   #IF (@showClumsy) {#SAY {This session you've clumsied @clumsyMissThrow out of @clumsyTotalThrow throws (@{clumsyPercentageThrow}~% landed)}} {}
   #IF (%eval(%concat("@show",%char,"OT"))) {
      #SAY {Since %eval(%concat("@",%char,"OT")) you've clumsied %eval(%concat("@clumsy",%char,"MissThrow")) out of %eval(%concat("@clumsy",%char,"TotalThrow")) throws (%eval(%concat("@clumsy",%char,"PercentageThrow"))~% landed)}
      } {}   
   } "" {case|disable}
#TRIGGER "clumsyStabTrigger" {You silently approach your victim...$} {
   #T+ {clumsyStabLand}
   #T+ {clumsyStabOoops}
   #ALARM "clumsyStabAlarm" +10 {
      #T- {clumsyStabLand}
      #T- {clumsyStabOoops}
      } "Clumsy"
   } "" {case}
#TRIGGER "clumsyStabLand" {^* makes a strange sound as you place * in * back!$} {
   #T- {clumsyStabLand}
   #T- {clumsyStabOoops}
   #ADD clumsyLandStab 1
   #ADD %concat("clumsy",%char,"LandStab") 1
   #MATH clumsyTotalStab @clumsyLandStab+@clumsyMissStab
   #MATH clumsyPercentageStab (@clumsyLandStab*100/@clumsyTotalStab)
   #MATH %concat("clumsy",%char,"TotalStab") %eval(%concat("@clumsy",%char,"LandStab"))+%eval(%concat("@clumsy",%char,"MissStab"))
   #MATH %concat("clumsy",%char,"PercentageStab") (%eval(%concat("@clumsy",%char,"LandStab"))*100/%eval(%concat("@clumsy",%char,"TotalStab")))
   #IF (@showClumsy) {#SAY {This session you've landed @clumsyLandStab out of @clumsyTotalStab stabs (@{clumsyPercentageStab}~% landed)}} {}
   #IF (%eval(%concat("@show",%char,"OT"))) {
      #SAY {Since %eval(%concat("@",%char,"OT")) you've landed %eval(%concat("@clumsy",%char,"LandStab")) out of %eval(%concat("@clumsy",%char,"TotalStab")) stabs (%eval(%concat("@clumsy",%char,"PercentageStab"))~% landed)}
      } {}   
   } "" {case|disable}
#TRIGGER "clumsyStabOoops" {^Ooops. Your clumsy execution broadcasts your intentions.$} {
   #T- {clumsyStabLand}
   #T- {clumsyStabOoops}
   #ADD clumsyMissStab 1
   #ADD %concat("clumsy",%char,"MissStab") 1
   #MATH clumsyTotalStab @clumsyLandStab+@clumsyMissStab
   #MATH clumsyPercentageStab (@clumsyLandStab*100/@clumsyTotalStab)
   #MATH %concat("clumsy",%char,"TotalStab") %eval(%concat("@clumsy",%char,"LandStab"))+%eval(%concat("@clumsy",%char,"MissStab"))
   #MATH %concat("clumsy",%char,"PercentageStab") (%eval(%concat("@clumsy",%char,"LandStab"))*100/%eval(%concat("@clumsy",%char,"TotalStab")))
   #IF (@showClumsy) {#SAY {This session you've clumsied @clumsyMissStab out of @clumsyTotalStab stabs (@{clumsyPercentageStab}~% landed)}} {}
   #IF (%eval(%concat("@show",%char,"OT"))) {
      #SAY {Since %eval(%concat("@",%char,"OT")) you've clumsied %eval(%concat("@clumsy",%char,"MissStab")) out of %eval(%concat("@clumsy",%char,"TotalStab")) stabs (%eval(%concat("@clumsy",%char,"PercentageStab"))~% landed)}
      } {}
   } "" {case|disable}
#ONINPUT "clumsyKickInput" {^{kic|kick}} {clumsyKickTriggers on} "Clumsy" {}
#ONINPUT "clumsyBashInput" {^{bas|bash}} {clumsyBashTriggers on} "Clumsy" {}
#CLASS 0
#CLASS {Clumsy|ClumsyConnect} {enable}
#TRIGGER "clumsyConnectTrigger" {%s The Wheel Of Time MUD} {
   #T- {Clumsy|ClumsyConnect}
   #IF (%class(Clumsy|%concat(%char,ClumsyVariables))=-1) {
      #CLASS {Clumsy|%concat(%char,ClumsyVariables)} {disable}
      #CLASS 0
      #VAR %concat("clumsy",%char,"LandBash") {0} {_nodef} {Clumsy|%concat(%char,ClumsyVariables)}
      #VAR %concat("clumsy",%char,"LandCharge") {0} {_nodef} {Clumsy|%concat(%char,ClumsyVariables)}
      #VAR %concat("clumsy",%char,"LandKick") {0} {_nodef} {Clumsy|%concat(%char,ClumsyVariables)}
      #VAR %concat("clumsy",%char,"LandStab") {0} {_nodef} {Clumsy|%concat(%char,ClumsyVariables)}
      #VAR %concat("clumsy",%char,"LandThrow") {0} {_nodef} {Clumsy|%concat(%char,ClumsyVariables)}
      #VAR %concat("clumsy",%char,"LandThrowCritical") {0} {_nodef} {Clumsy|%concat(%char,ClumsyVariables)}
      #VAR %concat("clumsy",%char,"MissBash") {0} {_nodef} {Clumsy|%concat(%char,ClumsyVariables)}
      #VAR %concat("clumsy",%char,"MissCharge") {0} {_nodef} {Clumsy|%concat(%char,ClumsyVariables)}
      #VAR %concat("clumsy",%char,"MissKick") {0} {_nodef} {Clumsy|%concat(%char,ClumsyVariables)}
      #VAR %concat("clumsy",%char,"MissStab") {0} {_nodef} {Clumsy|%concat(%char,ClumsyVariables)}
      #VAR %concat("clumsy",%char,"MissThrow") {0} {_nodef} {Clumsy|%concat(%char,ClumsyVariables)}
      #VAR %concat("clumsy",%char,"PercentageBash") {0} {_nodef} {Clumsy|%concat(%char,ClumsyVariables)}
      #VAR %concat("clumsy",%char,"PercentageCharge") {0} {_nodef} {Clumsy|%concat(%char,ClumsyVariables)}
      #VAR %concat("clumsy",%char,"PercentageDisarm") {0} {_nodef} {Clumsy|%concat(%char,ClumsyVariables)}
      #VAR %concat("clumsy",%char,"PercentageKick") {0} {_nodef} {Clumsy|%concat(%char,ClumsyVariables)}
      #VAR %concat("clumsy",%char,"PercentageStab") {0} {_nodef} {Clumsy|%concat(%char,ClumsyVariables)}
      #VAR %concat("clumsy",%char,"PercentageThrow") {0} {_nodef} {Clumsy|%concat(%char,ClumsyVariables)}
      #VAR %concat("clumsy",%char,"PercentageThrowCritical") {0} {_nodef} {Clumsy|%concat(%char,ClumsyVariables)}
      #VAR %concat("clumsy",%char,"RoundPercent") {0} {_nodef} {Clumsy|%concat(%char,ClumsyVariables)}
      #VAR %concat("clumsy",%char,"RoundTotal") {0} {_nodef} {Clumsy|%concat(%char,ClumsyVariables)}
      #VAR %concat("clumsy",%char,"TotalBash") {0} {_nodef} {Clumsy|%concat(%char,ClumsyVariables)}
      #VAR %concat("clumsy",%char,"TotalCharge") {0} {_nodef} {Clumsy|%concat(%char,ClumsyVariables)}
      #VAR %concat("clumsy",%char,"TotalKick") {0} {_nodef} {Clumsy|%concat(%char,ClumsyVariables)}
      #VAR %concat("clumsy",%char,"TotalStab") {0} {_nodef} {Clumsy|%concat(%char,ClumsyVariables)}
      #VAR %concat("clumsy",%char,"TotalThrow") {0} {_nodef} {Clumsy|%concat(%char,ClumsyVariables)}
      #VAR %concat("show",%char,"OT") {1} {_nodef} {Clumsy|%concat(%char,ClumsyVariables)}
      #VAR %concat(%char,"OT") {%time("m/d/20y")} {_nodef} {Clumsy|%concat(%char,ClumsyVariables)}
      } {#T+ {Clumsy|%concat(%char,ClumsyVariables)}}
   } "" {case}
#CLASS 0

_________________
House of Medakan zMUD Scripts: Table of Contents

House of Medakan cMUD Scripts: Table of Contents


Last edited by Taziar on Fri Jul 27, 2018 3:46 am, edited 13 times in total.

Top
 Profile  
 
 Post subject: Re: HoM zMUD Scripts
PostPosted: Tue Apr 25, 2017 11:46 am 
Offline

Joined: Tue Apr 07, 2015 8:24 pm
Posts: 132
Location: Seattle
Type helpClanChest to view help file in client

Image

Direct download link: ClanChestHoM.txt

Active Triggers: 0/5
Code:
#CLASS {ClanChest}
#ALIAS helpClanChest {
   #PRIORITY {
      #SAY {%crlf "-----Clan Chest Help File-----"}
      #SAY {"      [Updated: 2/8/2018]"}
      #SHOW {""}
      #SHOW {" Type saveChest when at quartermaster to save generic list."}
      #SHOW {"  Note: type saveChest <name> to save chest list with name."}
      #SHOW {"   Example: saveChest Companions will save a list under the name Companions."}
      #SHOW {""}
      #SHOW {" Type showChest to view contents of generic save list."}
      #SHOW {"  Note: type showChest <name> to view a previously named list."}
      #SHOW {"   Example: showChest Companions will show the last list you saved with that name."}
      #SHOW {""}
      #SHOW {" Type searchChest <item> to view list of matched items with current item numbers."}
      #SHOW {"  Note: to determine what chest list is searched first showChest <name> to set default."}
      #SHOW {""}
      #SHOW {" Type matchChest <name> when at quartermaster to compare a saved list with current chest contents."}
      #SHOW {"  Note: matching items show in default text color, non-matching items show in zMUD info color."}
      #SHOW {""}
      #SHOW {" Type showChestList to see list of current saved chest names."}
      #SHOW {""}
      #SHOW {" Type deleteChest <name> to delete a saved chest list."}
      #SHOW {""}
      #SHOW {" Script automatically gags any buggy chest slots (Oops! message)."}
      #SHOW {""}
      }
   }
#ALIAS saveChest {
   #SHOW {""}
   #IF (%len(%1)) {
      #IF (%ismember(%proper(%1),@clanChestNameList)) {
         #VAR %concat(chest,%proper(%1)) {}
         #SAY {Saving over existing chest list: %proper(%1)}
         } {
         #ADDITEM clanChestNameList %proper(%1)
         #VAR %concat(chest,%proper(%1)) {} {_nodef} "ClanChest"
         #SAY {Saving new chest list: %proper(%1)}
         }
      #VAR clanChestName {%proper(%1)}
      } {
      #SAY {"Chest List Loading..."}
      #T+ {clansaveChestTrigger}
      }
   #T+ {clanChestTempTrigger}
   #T+ {clanChestPromptTrigger}
   #T+ {clanChestOopsTrigger}
   #T+ {clanChestFinishedTrigger}
   #VAR clansaveChest {}
   #VAR clanChestTemp {}
   #VAR clanAddTemp {1}
   list
   }
#ALIAS showChest {
   #SAY {%crlf " One moment, retrieving chest list..."}
   #SHOW {""}
   #IF (%ismember(%proper(%1),@clanChestNameList)) {
      #VAR clanChestName {%proper(%1)}
      #VAR clanChestTemp {%eval(%concat("@chest",%proper(%1)))}
      #PRIORITY {#FORALL @clanChestTemp {#SHOW {" "%i}}}
      #IF (%numitems(@clanChestTemp)) {} {#SAY {"  No list found!"}}
      } {
      #PRIORITY {#FORALL @clansaveChest {#SHOW {" "%i}}}
      #IF (%numitems(@clansaveChest)) {} {#SAY {"  No list found!"}}
      }
   #SHOW {""}
   }
#ALIAS searchChest {
   #IF (%len(%-1)>0) {
      #VAR clanSearchSuccess {0}
      #VAR clanSearchItem {%lower(%-1)}
      #SAY {%crlf " One moment, searching chest list:"@clanChestname" for: "%-1...}
      #PRIORITY {
         #IF (%pos(@clanSearchItem,@clanChestTemp)>0) {
            #VAR clanSearchSuccess {1}
            #SHOW {""}
            #FORALL @clanChestTemp {
               #IF (%pos(@clanSearchItem,%i)) {
                  #SHOW {"  "%i}
                  } {}
               }
            } {}
         }
      #IF (@clanSearchSuccess=0) {
         #SHOW {""}
         #SAY {" Did not find any: "@clanSearchItem}
         } {}
      #IF (%numitems(@clanChestTemp)) {} {
         #SHOW {""}
         #SAY {"Type: showChest <name> or saveChest to load list to search."}
         }
      } {
      #SAY {%crlf " Type: searchChest <item keyword(s)>"}
      }
   }
#ALIAS showChestList {
   #SHOW {""}
   #SAY {"Saved chest list names:"}
   #SHOW {""}
   #FORALL @clanChestNameList {#SHOW " "%i}
   #SHOW {""}
   }
#ALIAS deleteChest {
   #IF (%ismember(%proper(%1),@clanChestNameList)) {
      #DELITEM clanChestNameList %proper(%1)
      #UNVAR %concat(chest,%proper(%1)) "ClanChest"
      } {
      #SHOW {""}
      #SAY {" "%proper(%1) is not a saved chest list.}
      }
   }
#ALIAS matchChest {
   #SHOW {""}
   #IF (%ismember(%proper(%1),@clanChestNameList)) {
      #VAR clanChestName {%proper(%1)}
      #VAR clanMatchON {1}
      #VAR clansaveChest {}
      #VAR clanChestTemp {}
      #T+ {clansaveChestTrigger}
      #T+ {clanChestPromptTrigger}
      #T+ {clanChestOopsTrigger}
      #T+ {clanChestFinishedTrigger}
      list
      } {
      #SAY {" Usage: matchChest <savedChestName>"}
      }
   #SHOW {""}
   }
#VAR clanAddTemp {0} {0}
#VAR clanMatchON {0} {0}
#VAR clansaveChest {}
#VAR clanChestName {}
#VAR clanChestNameList {}
#VAR clanChestTemp {}
#VAR clanSearchItem {}
#VAR clanSearchSuccess {0} {0}
#TRIGGER "clanChestOopsTrigger" {%d. Oops! Item not found! Try again later.$} {#GAG} "" {case|disable}
#TRIGGER "clansaveChestTrigger" {(%d. [a-z]*)$} {#VAR clansaveChest {%additem("%1",@clansaveChest)}} "" {case|disable}
#TRIGGER "clanChestTempTrigger" {(%d. [a-z]*)$} {#VAR clanChestTemp {%additem("%1",@clanChestTemp)}} "" {case|disable}
#TRIGGER "clanChestPromptTrigger" {~* Press ~<Return~> to continue, q to quit ~*~>} {#CR} "" {case|disable|nocr|prompt}
#TRIGGER "clanChestFinishedTrigger" {{o|*} * >} {
   #T- {clansaveChestTrigger}
   #T- {clanChestTempTrigger}
   #T- {clanChestOopsTrigger}
   #T- {clanChestPromptTrigger}
   #T- {clanChestFinishedTrigger}
   #IF (@clanAddTemp) {
      #VAR clanAddTemp {0}
      #VAR %concat(chest,@clanChestName) {@clanChestTemp}
      } {}
   #IF (@clanMatchON) {
      #VAR clanMatchON {0}
      #VAR clanChestTemp {%eval(%concat("@chest",@clanChestName))}
      #SHOW {""}
      #SAY {"Non matching entries show in zMUD info setting color."}
      #SHOW {""}
      #FORALL @clansaveChest {#IF (%ismember("%i",@clanChestTemp)) {#SHOW {" "%i}} {#SAY {" "%i}}}
      } {}
   } "" {case|disable|nocr|prompt}
#CLASS 0

_________________
House of Medakan zMUD Scripts: Table of Contents

House of Medakan cMUD Scripts: Table of Contents


Last edited by Taziar on Fri Jul 27, 2018 3:19 am, edited 10 times in total.

Top
 Profile  
 
 Post subject: Re: HoM zMUD Scripts
PostPosted: Tue Apr 25, 2017 6:21 pm 
Offline

Joined: Tue Apr 07, 2015 8:24 pm
Posts: 132
Location: Seattle
Type helpWeaveClumsy to view help file in client.

Image

Success rates based on pattern matching success messages of weaves.
Clumsy rates based on following messages:
    You lost control of *!
    Ouch! You couldn't maintain the flows.
    You are interrupted and stop what you are doing.
    You failed.

WoTmud alias will not work but, WoTmud shortcuts will work.
chann, channe, and channel will trigger script to record success or failures.
Examples shown below can be used in any combination:
    chann 'ice spikes' @target
    channe 'ice spikes' taziar
    channel '@weaveName' @target

Can use #ALIAS in zMUD for guaranteed coverage. Alias examples:
    #ALIAS cfb {channel 'fireball' %1}
    Usage: cfb taziar (would channel fireball at taziar)
    Usage: cfb kerryk (would channel fireball at kerryk)

#ALIAS cfb {channel 'fireball' @target3}
    Usage: cfb (would channel fireball at your current @target3 variable)

Direct download link: WeaveClumsyHoM.txt

Active Triggers: 0/29
Input Triggers: 1
Code:
#CLASS {WeaveClumsy}
#ALIAS helpWeaveClumsy {
   #PRIORITY {
      #SAY {%crlf "-----WeaveClumsy Help File-----"}
      #SAY {"      [Updated: 7/19/2018]"}
      #SHOW {" Script automatically adds a new character to the script the first time they connect."}
      #SHOW {""}
      #SHOW {"  Weaves tracked:"}
      #SHOW {"    Blind"}
      #SHOW {"    Call Lightning"}
      #SHOW {"    Chill"}
      #SHOW {"    Contagion"}
      #SHOW {"    Earthquake"}
      #SHOW {"    Fear"}
      #SHOW {"    Fireball"}
      #SHOW {"    Flame Strike"}
      #SHOW {"    Hammer of Air"}
      #SHOW {"    Hurricane"}
      #SHOW {"    Ice Spikes"}
      #SHOW {""}
      #SHOW {" Type showWeave <weave name> to toggle the fail message on/off for that weave name on current character."}
      #SHOW {"  Example: showWeave fireball"}
      #SHOW {""}
      #SHOW {" Type weaveCount <weave name> to display current stats for that weave name on current character."}
      #SHOW {"  Example: weaveCount hammer of air"}
      #SHOW {""}
      #SHOW {" Type resetWeave <weave name> to reset data for the weave on current character."}
      #SHOW {"  Example: resetWeave ice spikes"}
      #SHOW {""}
      }
   }
#ALIAS showWeave {
   #SHOW {""}
   #VAR weaveClumsySelected {%replace(%-1," ","")}
   #IF (%null(%1)) {
      #SAY {" Usage: showWeave <weave name>"}
      } {
      #IF (%len(%1)>1 AND %ismember(@weaveClumsySelected,@weaveClumsyNames)=0) {
         #SAY {Sorry, %proper(%1) %if(%len(%2),%proper(%2)" ","")%if(%len(%3),%proper(%3)" ","")is not a weave that is tracked with the WeaveClumsy Script.}
         } {   
         #IF (%eval(%concat("@showWeave",%char,@weaveClumsySelected))) {
            #VAR %concat("showWeave",%char,@weaveClumsySelected) {0}
            } {
            #VAR %concat("showWeave",%char,@weaveClumsySelected) {1}
            }
         #IF (%eval(%concat("@showWeave",%char,@weaveClumsySelected))) {
            #SAY {WeaveClumsy message for %proper(%1) %if(%len(%2),%proper(%2)" ","")%if(%len(%3),%proper(%3)" ","")is turned on.}
            } {
            #SAY {WeaveClumsy message for %proper(%1) %if(%len(%2),%proper(%2)" ","")%if(%len(%3),%proper(%3)" ","")is turned off.}
            }
         }
      }
   }
#ALIAS weaveCount {
   #SHOW {""}
   #VAR weaveClumsySelected {%replace(%-1," ","")}
   #IF (%null(%1)) {
      #SAY {" Usage: weaveCount <weave name>"}
      } {
      #IF (%len(%1)>1 AND %ismember(@weaveClumsySelected,@weaveClumsyNames)=0) {
         #SAY {Sorry, %proper(%1) %if(%len(%2),%proper(%2)" ","")%if(%len(%3),%proper(%3)" ","") is not a weave that is tracked with the WeaveClumsy Script.}
         } {   
         #MATH %concat("weave",%char,"Total",@weaveClumsySelected) %eval(%concat("@weave",%char,"Fail",@weaveClumsySelected))+%eval(%concat("@weave",%char,"Success",@weaveClumsySelected))
         #MATH %concat("weave",%char,"Percentage",@weaveClumsySelected) (%eval(%concat("@weave",%char,"Success",@weaveClumsySelected))*100 / %eval(%concat("@weave",%char,"Total",@weaveClumsySelected)))
         #IF (%eval(%concat("@showWeave",%char,@weaveClumsySelected))) {
            #SAY {You have succeeded %eval(%concat("@weave",%char,"Success",@weaveClumsySelected)) out of %eval(%concat("@weave",%char,"Total",@weaveClumsySelected)) attempts to weave %proper(%1) %if(%len(%2),%proper(%2)" ","")%if(%len(%3),%proper(%3)" ","")(%eval(%concat("@weave",%char,"Percentage",@weaveClumsySelected))~% Successful)}
            }
         #IF (@weaveClumsySelected="hammerofair") {
            #MATH %concat("weave",%char,"BashPercentage") (%eval(%concat("@weave",%char,"Success",@weaveClumsySelected)) * 100 / %eval(%concat("@weave",%char,"BashSuccess")))
            #IF (%eval(%concat("@showWeave",%char,@weaveClumsySelected))) {
               #SAY {With %eval(%concat("@weave",%char,"BashSuccess")) total number of bashes equaling a percentage of (%eval(%concat("@weave",%char,"BashPercentage"))~% Successful)}
               } {}
            }
         }
      }
   }
#ALIAS resetWeave {
   #SHOW {""}
   #VAR weaveClumsySelected {%replace(%-1," ","")}
   #IF (%null(%1)) {
      #SAY {" Usage: resetWeave <weave name>"}
      } {
      #IF (%len(%1)>1 AND %ismember(@weaveClumsySelected,@weaveClumsyNames)=0) {
         #SAY {Sorry, %proper(%1) %if(%len(%2),%proper(%2)" ","")%if(%len(%3),%proper(%3)" ","") is not a weave that is tracked with the WeaveClumsy Script.}
         } {
         #VAR %concat("weave",%char,"Fail",@weaveClumsySelected) {0} {_nodef} {WeaveClumsy|%concat(%char,"WeaveClumsyVariables")}
         #VAR %concat("weave",%char,"Success",@weaveClumsySelected) {0} {_nodef} {WeaveClumsy|%concat(%char,"WeaveClumsyVariables")}
         #VAR %concat("weave",%char,"Total",@weaveClumsySelected) {0} {_nodef} {WeaveClumsy|%concat(%char,"WeaveClumsyVariables")}
         #VAR %concat("weave",%char,"Percentage",@weaveClumsySelected) {0} {_nodef} {WeaveClumsy|%concat(%char,"WeaveClumsyVariables")}
         #IF (@weaveClumsySelected=hammerofair) {#VAR %concat("weave",%char,"BashSuccess") {0} {_nodef} {WeaveClumsy|%concat(%char,"WeaveClumsyVariables")}} {}
         #IF (@weaveClumsySelected=hammerofair) {#VAR %concat("weave",%char,"BashPercentage") {0} {_nodef} {WeaveClumsy|%concat(%char,"WeaveClumsyVariables")}} {}
         #SAY {%proper(%1) %if(%len(%2),%proper(%2)" ","")%if(%len(%3),%proper(%3)" ","") data has been reset.}
         }
      }
   }
#ALIAS weaveClumsySuccess {
   #ADD %concat("weave",%char,"Success",@weaveClumsySelected) 1
   #MATH %concat("weave",%char,"Total",@weaveClumsySelected) %eval(%concat("@weave",%char,"Fail",@weaveClumsySelected))+%eval(%concat("@weave",%char,"Success",@weaveClumsySelected))
   #MATH %concat("weave",%char,"Percentage",@weaveClumsySelected) (%eval(%concat("@weave",%char,"Success",@weaveClumsySelected))*100 / %eval(%concat("@weave",%char,"Total",@weaveClumsySelected)))
   #IF (%eval(%concat("@showWeave",%char,@weaveClumsySelected))) {
      #SAY {You have succeeded %eval(%concat("@weave",%char,"Success",@weaveClumsySelected)) out of %eval(%concat("@weave",%char,"Total",@weaveClumsySelected)) attempts to weave %proper(@weaveClumsyCurrent) (%eval(%concat("@weave",%char,"Percentage",@weaveClumsySelected))~% Successful)}
      }
   #IF (@weaveClumsySelected="hammerofair") {weaveClumsyBash} {}
   weaveClumsyTrigs off
   }
#ALIAS weaveClumsyFail {
   #ADD %concat("weave",%char,"Fail",@weaveClumsySelected) 1
   #MATH %concat("weave",%char,"Total",@weaveClumsySelected) %eval(%concat("@weave",%char,"Fail",@weaveClumsySelected))+%eval(%concat("@weave",%char,"Success",@weaveClumsySelected))
   #MATH %concat("weave",%char,"Percentage",@weaveClumsySelected) (%eval(%concat("@weave",%char,"Success",@weaveClumsySelected))*100 / %eval(%concat("@weave",%char,"Total",@weaveClumsySelected)))
   #IF (%eval(%concat("@showWeave",%char,@weaveClumsySelected))) {
      #SAY {You have failed %eval(%concat("@weave",%char,"Fail",@weaveClumsySelected)) out of %eval(%concat("@weave",%char,"Total",@weaveClumsySelected)) attempts to weave %proper(@weaveClumsyCurrent) (%eval(%concat("@weave",%char,"Percentage",@weaveClumsySelected))~% Successful)}
      }
   weaveClumsyTrigs off
   }
#ALIAS weaveClumsyBash {
   #ADD %concat("weave",%char,"BashSuccess") 1
   #MATH %concat("weave",%char,"BashPercentage") (%eval(%concat("@weave",%char,"BashSuccess")) * 100 / %eval(%concat("@weave",%char,"Successhammerofair")))
   #IF (%eval(%concat("@showWeave",%char,@weaveClumsySelected))) {
      #SAY {With %eval(%concat("@weave",%char,"BashSuccess")) total number of bashes equaling a percentage of (%eval(%concat("@weave",%char,"BashPercentage"))~% Successful)}
      } {}
   }
#ALIAS weaveClumsyTrigs {
   #IF (%1=on) {
      #T+ {WeaveClumsy|WeaveClumsySuccessTriggers}
      #T+ {WeaveClumsy|WeaveClumsyFailTriggers}
      } {}
   #IF (%1=off) {
      #T- {WeaveClumsy|WeaveClumsySuccessTriggers}
      #T- {WeaveClumsy|WeaveClumsyFailTriggers}
      } {}
   }
#VAR weaveClumsyCurrent {}
#VAR weaveClumsySelected {}
#VAR weaveClumsyNames {blind|calllightning|chill|contagion|earthquake|fear|fireball|flamestrike|hammerofair|hurricane|icespikes}
#ONINPUT {^{chann|channe|channel} '&weaveClumsyCurrent'} {
   #VAR weaveClumsySelected %replace(@weaveClumsyCurrent," ","")
   #IF (%ismember(@weaveClumsySelected,@weaveClumsyNames)) {weaveClumsyTrigs on} {}
   }
#CLASS 0
#CLASS {WeaveClumsy|WeaveClumsySuccessTriggers} {disable}
#TRIGGER {^* has been blinded!$} {weaveClumsySuccess} "" {case}
#TRIGGER {^You call lightning from the sky which strikes * dead on.$} {weaveClumsySuccess} "" {case}
#TRIGGER {^Your lightning from the sky strikes *, dropping * sizzling corpse to the ground.$} {weaveClumsySuccess} "" {case}
#TRIGGER {^* shivers from the icy cold force sent by you.$} {weaveClumsySuccess} "" {case}
#TRIGGER {^Beads of cold sweat emerge from *'s face!$} {weaveClumsySuccess} "" {case}
#TRIGGER {^The earth trembles and shivers beneath your feet..!$} {weaveClumsySuccess} "" {case}
#TRIGGER {^* looks very strange, glaring about with a sense of panic.$} {weaveClumsySuccess} "" {case}
#TRIGGER {^Fire coalesces into a ball at your hands, which you launch at *.$} {weaveClumsySuccess} "" {case}
#TRIGGER {^Fire coalesces in your hands, but fizzles a bit as you launch it at *.$} {weaveClumsySuccess} "" {case}
#TRIGGER {^Your fireball blasts into *, dropping * charred corpse to the ground.$} {weaveClumsySuccess} "" {case}
#TRIGGER {^Streaks of fire burn through *, leaving only a blackened corpse.$} {weaveClumsySuccess} "" {case}
#TRIGGER {^Streaks of fire flow from your hands, burning *.$} {weaveClumsySuccess} "" {case}
#TRIGGER {^You mold flows of Air into a tight stream, and smite *.$} {weaveClumsySuccess} "" {case}
#TRIGGER {^You mold flows of Air into a tight stream, sending * sprawling!$} {weaveClumsySuccess} "" {case}
#TRIGGER {^A violent storm erupts and fierce winds blow through the area.$} {weaveClumsySuccess} "" {case}
#TRIGGER {^Spikes of solid ice form in your hands, which you launch at *.$} {weaveClumsySuccess} "" {case}
#TRIGGER {^Spikes of ice form in your hands, but melt a bit as you launch them at *.$} {weaveClumsySuccess} "" {case}
#TRIGGER {^Your icy spikes shred * guts, causing * insides to flow outside.$} {weaveClumsySuccess} "" {case}
#CLASS 0
#CLASS {WeaveClumsy|WeaveClumsyFailTriggers} {disable}
#TRIGGER {^You lost control of *!$} {weaveClumsyFail} "" {case}
#TRIGGER {Ouch! You couldn't maintain the flows.} {weaveClumsyFail} "" {case|verbatim}
#TRIGGER {^You are interrupted and stop what you are doing.$}  {weaveClumsyFail} "" {case}
#TRIGGER {^Cancelled.$} {weaveClumsyTrigs off} "" {case}
#TRIGGER {You aren't in touch with said?? to channel it.$} {weaveClumsyTrigs off} "" {case}
#TRIGGER {You can't get close enough to them in the heat of battle.} {weaveClumsyTrigs off} "" {case|verbatim}
#TRIGGER {Impossible! You can't concentrate enough!} {weaveClumsyTrigs off} "" {case|verbatim}
#TRIGGER {Nobody here by that name.} {weaveClumsyTrigs off} "" {case|verbatim}
#TRIGGER {You can't summon enough energy to weave the flow.}  {weaveClumsyTrigs off} "" {case|verbatim}
#TRIGGER {You failed.} {weaveClumsyFail} "" {case|verbatim}
#CLASS 0
#CLASS {WeaveClumsy|WeaveClumsyConnect} {enable}
#TRIGGER "weaveClumsyConnectTrigger" {%s The Wheel Of Time MUD} {
   #T- {WeaveClumsy|WeaveClumsyConnect}
   #IF (%class(WeaveClumsy|%concat(%char,WeaveClumsyVariables))=-1) {
      #PRIORITY {
         #CLASS {WeaveClumsy|%concat(%char,"WeaveClumsyVariables")} {disable}
         #CLASS 0
         #FORALL @weaveClumsyNames {
            #VAR %concat("weave",%char,"Fail",%proper(%i)) {0} {_nodef} {WeaveClumsy|%concat(%char,"WeaveClumsyVariables")}
            #VAR %concat("weave",%char,"Success",%proper(%i)) {0} {_nodef} {WeaveClumsy|%concat(%char,"WeaveClumsyVariables")}
            #VAR %concat("weave",%char,"Total",%proper(%i)) {0} {_nodef} {WeaveClumsy|%concat(%char,"WeaveClumsyVariables")}
            #VAR %concat("weave",%char,"Percentage",%proper(%i)) {0} {_nodef} {WeaveClumsy|%concat(%char,"WeaveClumsyVariables")}
            #VAR %concat("showWeave",%char,%proper(%i)) {1} {_nodef} {WeaveClumsy|%concat(%char,"WeaveClumsyVariables")}
            }
         #VAR %concat("weave",%char,"BashSuccess") {0} {_nodef} {WeaveClumsy|%concat(%char,"WeaveClumsyVariables")}
         #VAR %concat("weave",%char,"BashPercentage") {0} {_nodef} {WeaveClumsy|%concat(%char,"WeaveClumsyVariables")}
         }
      } {
      #T+ {WeaveClumsy|%concat(%char,WeaveClumsyVariables)}
      }
   } "" {case}
#CLASS 0

_________________
House of Medakan zMUD Scripts: Table of Contents

House of Medakan cMUD Scripts: Table of Contents


Last edited by Taziar on Sat Aug 25, 2018 2:55 am, edited 7 times in total.

Top
 Profile  
 
 Post subject: Re: HoM zMUD Scripts
PostPosted: Tue Apr 25, 2017 7:37 pm 
Offline

Joined: Tue Apr 07, 2015 8:24 pm
Posts: 132
Location: Seattle
Custom Script: Yeri's Ignore Script
Original post on wotmod.org forums is here

Yeri Script! (aka: don't be one of those types... don't get Yeri'd!)

Will ignore chats, narrates, hisses, drawls, says, and bellows in main window. (if using my communications script it won't mask anything in that window)

Type helpYeri to view help file.

Type yeriName NAME to add character to Yeri list.

Type yeriList to see list of currently Yeri'd characters.

Type yeriReset to reset all names of previously Yeri'd characters.
Note: will automatically reset on each connection to mud.

Example wrote:
yeriName Taziar

Taziar added to your Yeri'd character list.

Taziar chats '<Has been Yeri'd>'


Code:
#CLASS {Yeri}
#ALIAS helpYeri {
   #SHOW {""}
   #SHOW {""}
   #SHOW {"-----Yeri Script Commands-----"}
   #SHOW {""}
   #SHOW {"Type yeriName NAME to add a character to the Yeri list."}
   #SHOW {"Example: yeriName Taziar to Yeri all of Taziar's communications."}
   #SHOW {""}
   #SHOW {"Type yeriList to see current list of Yeri'd names."}
   #SHOW {""}
   #SHOW {"Type yeriReset to delete all names of previously Yeri'd characters."}
   #SHOW {"Note: Will automatically reset list at reconnection."}
   #SHOW {""}
   }
#ALIAS yeriName {
   #ADDITEM yeriCharacterList %1
   #ECHO {""}
   #ECHO {%proper(%1) added to your Yeri'd character list.}
   }
#ALIAS yeriReset {
   #VAR yeriCharacterList {""}
   yeriList
   }
#ALIAS yeriList {
   #IF (@yeriCharacterList) {
      #ECHO {""}
      #FORALL @yeriCharacterList {#ECHO {%i}}
      } {
      #ECHO {""}
      #ECHO {You are currently Yeri-ing no one...}
      }
   }
#VAR yeriCharacterList {}
#TRIGGER {(%w) chats '(*)'} {#IF (%ismember(%1,@yeriCharacterList)) {#PSUB "<Has been Yeri'd>" %x2} {}}
#TRIGGER {(%w) narrates '(*)'} {#IF (%ismember(%1,@yeriCharacterList)) {#PSUB "<Has been Yeri'd>" %x2} {}}
#TRIGGER {(%w) says '(*)'} {#IF (%ismember(%1,@yeriCharacterList)) {#PSUB "<Has been Yeri'd>" %x2} {}}
#TRIGGER {(%w) hisses '(*)'} {#IF (%ismember(%1,@yeriCharacterList)) {#PSUB "<Has been Yeri'd>" %x2} {}}
#TRIGGER {(%w) drawls '(*)'} {#IF (%ismember(%1,@yeriCharacterList)) {#PSUB "<Has been Yeri'd>" %x2} {}}
#TRIGGER {(%w) bellows '(*)'} {#IF (%ismember(%1,@yeriCharacterList)) {#PSUB "<Has been Yeri'd>" %x2} {}}
#TRIGGER {^Welcome to the Wheel of Time!  Type 'help' for information.$} {yeriReset}
#CLASS 0


Back to: Table of Contents

_________________
House of Medakan zMUD Scripts: Table of Contents

House of Medakan cMUD Scripts: Table of Contents


Top
 Profile  
 
 Post subject: Re: HoM zMUD Scripts
PostPosted: Tue Apr 25, 2017 7:46 pm 
Offline

Joined: Tue Apr 07, 2015 8:24 pm
Posts: 132
Location: Seattle
Custom Script: Terinor's Random Colors
Colors the successful messages of a bash, charge, or stab in a rainbow of colors. Each time the output is randomly different.

Type tbc <color> to set the script to be the same as your background color.
-Note: if you dislike a certain color just delete it from the terinorRainbow stringlist variable.

Code:
#CLASS {terinorColorsRandom}
#ALIAS tbc {
   #VAR terinorBC %1
   #ECHO {%1 is now set as your Terinor Background Color.}
   }
#ALIAS selectColor {
    #VAR terinorRandomColor %item(@terinorRainbow, %random(1, %numitems(@terinorRainbow)))
   }
#VAR terinorBC {}
#VAR terinorRainbow {blue|green|cyan|red|magenta|yellow|bold,blue|bold,green|bold,cyan|bold,red|bold,magenta|bold,yellow}
#VAR terinorRandomColor {}
#VAR terinorColor1 {}
#VAR terinorColor2 {}
#VAR terinorColor3 {}
#VAR terinorColor4 {}
#VAR terinorColor5 {}
#VAR terinorColor6 {}
#VAR terinorColor7 {}
#VAR terinorColor8 {}
#VAR terinorColor9 {}
#VAR terinorColor10 {}
#VAR terinorColor11 {}
#VAR terinorColor12 {}
#TRIGGER {Chaaaaarrrge!! %1 bleeds profusely as you skewer %2 with %3!} {
   #LOOP 1,10 {
      selectColor
      #VAR terinorColor%{i} {@terinorRandomColor}
   }
   #SUB {%ansi(@terinorColor1,@terinorBC)Chaaaaarrrge!! %ansi(@terinorColor2,@terinorBC)%1 %ansi(@terinorColor3,@terinorBC)bleeds %ansi(@terinorColor4,@terinorBC)profusely %ansi(@terinorColor5,@terinorBC)as %ansi(@terinorColor6,@terinorBC)you %ansi(@terinorColor7,@terinorBC)skewer %ansi(@terinorColor8,@terinorBC)%2 %ansi(@terinorColor9,@terinorBC)with %ansi(@terinorColor10,@terinorBC)%3!}
   }
#TRIGGER {%1 makes a strange sound as you place %2 in %3 back!} {
   #LOOP 1,12 {
      selectColor
      #VAR terinorColor%{i} {@terinorRandomColor}
   }
   #SUB {%ansi(@terinorColor1,@terinorBC)%1 %ansi(@terinorColor2,@terinorBC)makes %ansi(@terinorColor3,@terinorBC)a %ansi(@terinorColor4,@terinorBC)strange %ansi(@terinorColor5,@terinorBC)sound %ansi(@terinorColor6,@terinorBC)as %ansi(@terinorColor7,@terinorBC)you %ansi(@terinorColor8,@terinorBC)place %ansi(@terinorColor9,@terinorBC)%2 %ansi(@terinorColor10,@terinorBC)in %ansi(@terinorColor11,@terinorBC)%3 %ansi(@terinorColor12,@terinorBC)back!}
   }
#TRIGGER {Your bash at %1 sends %2 sprawling!} {
   #LOOP 1,7 {
      selectColor
      #VAR terinorColor%{i} {@terinorRandomColor}
   }
   #SUB {%ansi(@terinorColor1,@terinorBC)Your %ansi(@terinorColor2,@terinorBC)bash %ansi(@terinorColor3,@terinorBC)at %ansi(@terinorColor4,@terinorBC)%1 %ansi(@terinorColor5,@terinorBC)sends %ansi(@terinorColor6,@terinorBC)%2 %ansi(@terinorColor7,@terinorBC)sprawling!}
   }
#CLASS 0


Back to: Table of Contents

_________________
House of Medakan zMUD Scripts: Table of Contents

House of Medakan cMUD Scripts: Table of Contents


Top
 Profile  
 
Display posts from previous:  Sort by  
Post new topic Reply to topic  [ 39 posts ]  Go to page 1, 2, 3, 4  Next

All times are UTC - 5 hours [ DST ]


Who is online

Users browsing this forum: No registered users and 1 guest


You cannot post new topics in this forum
You cannot reply to topics in this forum
You cannot edit your posts in this forum
You cannot delete your posts in this forum

Search for:
Jump to:  
cron
Powered by phpBB® Forum Software © phpBB Group