Download Key16.zip file extract the folder and place a copy inside the WoTMUD folder in your zMUD directory. If your game settings folder is not titled WoTMUD then you will need to edit the file path for each button in the script to have the images display.
Code: Select all
#CLASS {Target}
#ALIAS helpTarget {
#PRIORITY {
#SAY {%crlf "-----Target Help File-----"}
#SAY {" [Updated: 8/3/2018]"}
#SHOW {" Manually set targets 1-4 with the following commands:"}
#SHOW {" Type tg1 <name> to set <name> as @target1."}
#SHOW {" Type tg2 <name> to set <name> as @target2."}
#SHOW {" Type tg3 <name> to set <name> as @target3."}
#SHOW {" Type tg4 <name> to set <name> as @target4."}
#SHOW {" Example: tg1 austin will set @target1 to Austin"}
#SHOW {""}
#SHOW {" Target special abilities:"}
#SHOW {" @target1 is designated kill and used to spam, targets 2-4 use cycle command function."}
#SHOW {" Press CTRL-F1 to cycle through and set target1 from target2, target3, or target4."}
#SHOW {" Note: can also cycle and set by typing tg1 without a target name."}
#SHOW {" Hint: CTRL-F2, CTRL-F3, and CTRL-F4 sets @target1 to current @target2-4 respectively."}
#SHOW {""}
#SHOW {" @target2 fills automatically when detecting a proper case, single word name in prompt."}
#SHOW {" Examples: * HP:Healthy MV:Fresh - Austin: Critical > "}
#SHOW {" * HP:Battered MV:Full - the blighted tree: Critical - Austin: Battered > "}
#SHOW {""}
#SHOW {" @target3 fills automatically when detecting most recent WANTED."}
#SHOW {" Notes: @target3 changes whenever a WANTED enters, flees, or leaves the room"}
#SHOW {" and the first WANTED name in the room contents list when entering or looking."}
#SHOW {""}
#SHOW {" @target4 is a multi functional target:"}
#SHOW {" Typing k <name> to attack something auto sets <name> as @target4 variable."}
#SHOW {" Notes: ki <name>, kil <name>, and kill <name> do NOT change the @target4 variable"}
#SHOW {" @target4 auto populates when a player's condition in the prompt is Critical."}
#SHOW {""}
#SHOW {" CrossRace and WANTED names capture automatically to targets 5 through 12."}
#SHOW {" Note: targets 5-12 use the cycle command function."}
#SHOW {""}
#SHOW {" Type helpTargetButton to view Target Button Help Options."}
#SHOW {" Type helpTargetMacro to view Target Macro Help Options."}
#SHOW {" Type helpTargetCrossRace to view Target CrossRace Help Options."}
#SHOW {" Type helpTargetWanted to view Target WANTED Help Options."}
#SHOW {""}
}
}
#ALIAS helpTargetButton {
#PRIORITY {
#SAY {%crlf "-----Target Button Help Options-----"}
#SHOW {" Type toggle14 to toggle main target buttons on/off."}
#SHOW {" Type toggle58 to toggle crossRace target buttons 5-8 on/off."}
#SHOW {" Type toggle912 to toggle WANTED target buttons 9-12 on/off."}
#SHOW {" Type toggle1316 to toggle macro buttons on/off. (ADD|DIV|MULT|SUB)"}
#SHOW {""}
#SHOW {" Type btnColor <button> <color> to change the color of a button."}
#SHOW {" Note: button color uses ansi foreground and background mapping as set in Prefs."}
#SHOW {" To set color add foreground color number with background color number."}
#SHOW {" Examples: btnColor F1 15 to set F1 to white foreground and black background."}
#SHOW {" Hint: btnColor all <color> to change all buttons to the same color."}
#SHOW {" Button color can also be changed individually inside the settings window editor."}
#SHOW {""}
#SHOW {" Available buttons: F1|F2|F3|F4|F5|F6|F7|F8|F9|F10|F11|F12|MULT|DIV|SUB|ADD"}
#SHOW {""}
#SHOW {" Type btnColorDS <color> to change the color of DS captured name in buttons F5-F8."}
#SHOW {" Note: default set as red text with black background (btnColorDS 12)"}
#SHOW {""}
#SHOW {" Type btnColorLS <color> to change the color of LS captured name in buttons F5-F8."}
#SHOW {" Note: default set as cyan text with black background (btnColorLS 11)"}
#SHOW {""}
#SHOW {" Type btnColorW <color> to change the color of WANTED captured names in buttons F9-F12."}
#SHOW {" Note: default set as magenta text with black background (btnColorW 13)"}
#SHOW {""}
}
}
#ALIAS helpTargetMacro {
#PRIORITY {
#SAY {%crlf "-----Target Macro Help Options-----"}
#SHOW {" Target command cycle alias:"}
#SHOW {" targetCycleAction cycles through target command actions list."}
#SHOW {" targetCycleWeave cycles through target command weaves list."}
#SHOW {" Hint: place above alias in a macro for quick command cycling"}
#SHOW {""}
#SHOW {" listTarget <type> shows list of current target cycle commands."}
#SHOW {" Types: action, weave"}
#SHOW {""}
#SHOW {" addTarget <type> <command> to add a command to the specified list."}
#SHOW {" Example: addTarget action throw (adds throw to list of action commands)"}
#SHOW {""}
#SHOW {" subTarget <type> <command> to remove a command from the specified list."}
#SHOW {" Example: subTarget weave blind (removes blind from list of weave commands)"}
#SHOW {""}
#SHOW {" setTarget <command> to manually set cycle target command."}
#SHOW {" Hint: for weaves use ' around weave name as normal."}
#SHOW {" Examples: setTarget channel 'ice spikes'"}
#SHOW {" setTarget bash"}
#SHOW {""}
#SHOW {" Macros (ADD|DIV|END|HOME|MULT|PGDN|PGUP|SUB) variables are located in the script: Characters."}
#SHOW {""}
#SHOW {" F-Key Macros automatically set to activate buttons (F1|F2|F3|F4|F5|F6|F7|F8|F9|F10|F11|F12)"}
#SHOW {" Note: to bypass Fkeys and use your own macros or alias use: targetF# (targetF1, targetF2, ect...)"}
#SHOW {""}
}
}
#ALIAS helpTargetCrossRace {
#PRIORITY {
#SAY {%crlf "-----Target CrossRace Help Options-----"}
#SHOW {" Colored names inside asterisks automatically captured as they come across the screen."}
#SHOW {" Note: sets the next available crossRace target with the crossrace name."}
#SHOW {""}
#SHOW {" Target buttons 5 through 8 are reserved for crossRace name capture."}
#SHOW {" Note: once buttons fill with targets, starting at 5 and continuing to 8,"}
#SHOW {" new names no longer capture and buttons must be reset to change targets."}
#SHOW {""}
#SHOW {" Type reset58 to reset crossRace target buttons 5 through 8 to defaults."}
#SHOW {""}
#SHOW {" Type btnColorDS <color> to change the color of DS captured name in buttons F5-F8."}
#SHOW {" Note: default set as red text with black background (btnColorDS 4 or btnColorDS black,red)"}
#SHOW {""}
#SHOW {" Type btnColorLS <color> to change the color of LS captured name in buttons F5-F8."}
#SHOW {" Note: default set as blue text with black background (btnColorLS 3 or btnColorLS black,blue)"}
#SHOW {""}
}
}
#ALIAS helpTargetWanted {
#PRIORITY {
#SAY {%crlf "-----Target WANTED Help Options-----"}
#SHOW {" Viewing the who list will automatically save current online WANTED names."}
#SHOW {" Note: WANTED tag in who list are colored in the current @wantedColor."}
#SHOW {" Who list does not set any targets, only stores current list of WANTEDs."}
#SHOW {""}
#SHOW {" Manual addition of names to WANTED list:"}
#SHOW {" Type addWanted <name> to add a name."}
#SHOW {" Type subWanted <name> to remove a name."}
#SHOW {" Type listWanted to see list of added names."}
#SHOW {""}
#SHOW {" Where command output (WANTED names) colored in the current @wantedColor."}
#SHOW {" Note: sets the next available WANTED target(9-12) with WANTED name"}
#SHOW {""}
#SHOW {" Entering or looking in a room will color WANTED names in the current @wantedColor."}
#SHOW {" Note: sets the next available WANTED target(9-12) with WANTED name and,"}
#SHOW {" sets the @target3 variable with the first detected name in room list."}
#SHOW {""}
#SHOW {" Whenever a WANTED enters, attempts to flee, or leaves the room it sets @target3."}
#SHOW {""}
#SHOW {" Type colorWanted <color> [bcolor] to set WANTED color."}
#SHOW {" Current WANTED color: " @wantedMXPcolor(@wantedColor)}
#SHOW {" Note: background color is optional"}
#SHOW {""}
#SHOW {" Target buttons 9 through 12 are reserved for WANTED name capture."}
#SHOW {" Note: once buttons fill with targets, starting at 9 and continuing to 12,"}
#SHOW {" new names no longer capture and buttons must be reset to change targets."}
#SHOW {""}
#SHOW {" Type reset912 to reset WANTED target buttons 9 through 12 to defaults."}
#SHOW {""}
#SHOW {" Type btnColorW <color> to change the color of WANTED captured names in buttons F9-F12."}
#SHOW {" "Note: current WANTED button color is set to <color @btnColorW>@btnColorW</color>.}
#SHOW {""}
}
}
#ALIAS toggle14 {
#IF (@showButton14) {
#VAR showButton14 {0}
#SAY {%crlf Target Buttons 1-4 enabled.}
#LOOP 1,4 {#T+ {%concat(buttonF,%i)}}
} {
#VAR showButton14 {1}
#SAY {%crlf Target Buttons 1-4 disabled.}
#LOOP 1,4 {#T- {%concat(buttonF,%i)}}
}
}
#ALIAS toggle58 {
#IF (@showButton58) {
#VAR showButton58 {0}
#SAY {%crlf Target Buttons 5-8 enabled.}
#LOOP 5,8 {#T+ {%concat(buttonF,%i)}}
} {
#VAR showButton58 {1}
#SAY {%crlf Target Buttons 5-8 disabled.}
#LOOP 5,8 {#T- {%concat(buttonF,%i)}}
}
}
#ALIAS toggle912 {
#IF (@showButton912) {
#VAR showButton912 {0}
#SAY {%crlf Target Buttons 9-12 enabled.}
#LOOP 9,12 {#T+ {%concat(buttonF,%i)}}
} {
#VAR showButton912 {1}
#SAY {%crlf Target Buttons 9-12 disabled.}
#LOOP 9,12 {#T- {%concat(buttonF,%i)}}
}
}
#ALIAS toggle1316 {
#IF (@showButton1316) {
#VAR showButton1316 {0}
#SAY {%crlf Buttons 13-16 enabled.}
#FORALL {ADD|DIV|MULT|SUB} {#T+ {%concat(button,%i)}}
} {
#VAR showButton1316 {1}
#SAY {%crlf Buttons 13-16 disabled.}
#FORALL {ADD|DIV|MULT|SUB} {#T- {%concat(button,%i)}}
}
}
#ALIAS reset58 {
#T+ {targetDarkTrigger}
#T+ {targetHumanTrigger}
#LOOP 5,8 {#VAR %concat(target,%i) {}}
#LOOP 5,8 {#CALL {%btncol(%concat(buttonF,%i),15)}}
#VAR targetCrossList {}
}
#ALIAS reset912 {
#LOOP 9,12 {#VAR %concat(target,%i) {}}
#LOOP 9,12 {#CALL {%btncol(%concat(buttonF,%i),@btnColorW)}}
#VAR wantedButtonList {}
}
#ALIAS tg1 {
#IF (%null(%1)) {
#IF (@targetCycleCount=2) {
#VAR target1 {@target2}
#VAR targetCycleCount {3}
} {
#IF (@targetCycleCount=3) {
#VAR target1 {@target3}
#VAR targetCycleCount {4}
} {
#IF (@targetCycleCount=4) {
#VAR target1 {@target4}
#VAR targetCycleCount {2}
} {}
}
}
} {
#VAR target1 {%proper(%1)}
#SAY {@target1 is now set as your target1.}
}
}
#ALIAS tg2 {
#IF (%null(%1)) {
#VAR target2 {2}
#SAY {%crlf No target name detected, @target2 is now reset.}
} {
#VAR target2 {%proper(%1)}
#SAY {@target2 is now set as your target2.}
}
}
#ALIAS tg3 {
#IF (%null(%1)) {
#VAR target3 {3}
#SAY {%crlf No target name detected, @target3 is now reset.}
} {
#VAR target3 {%proper(%1)}
#SAY {@target3 is now set as your target3.}
}
}
#ALIAS tg4 {
#IF (%null(%1)) {
#VAR target4 {4}
#SAY {%crlf No target name detected, @target4 is now reset.}
} {
#VAR target4 {%proper(%1)}
#SAY {@target4 is now set as your target4.}
}
}
#ALIAS btnColor {
#IF (%null(%1)) {
#SHOW {%crlf "Usage: btnColor <button> <color> (use [all] in <button> field for all buttons)"}
} {
#IF (%null(%2)) {
#SAY {%crlf What color is that?...}
} {
#IF (%ismember(%upper(%1),@btnList)) {
#CALL {%btncol(%concat(button,%1),%2)}
#SAY {%crlf Button %upper(%1) color set to %2.}
} {
#IF (%upper(%1)=ALL) {#FORALL @btnList {#CALL {%btncol(%concat(button,%i),%2)}}} {}
#SAY {%crlf All Button color's are set to %2!}
}
}
}
}
#ALIAS btnColorDS {
#IF (%null(%1)) {
#SHOW {%crlf "Usage: btnColorDS <color>"}
} {
#VAR btnColorDS {%1}
#SAY {%crlf DS buttons capture color set to %1.}
}
}
#ALIAS btnColorLS {
#IF (%null(%1)) {
#SHOW {%crlf "Usage: btnColorLS <color>"}
} {
#VAR btnColorLS {%1}
#SAY {%crlf LS buttons capture color set to %1.}
}
}
#ALIAS btnColorW {
#IF (%null(%1)) {
#SHOW {%crlf "Usage: btnColorW <color>"}
} {
#VAR btnColorW {%1}
#SAY {%crlf WANTED buttons capture color set to %1.}
}
}
#ALIAS targetF1 {kill @target1}
#ALIAS targetF2 {@targetCommand @target2}
#ALIAS targetF3 {@targetCommand @target3}
#ALIAS targetF4 {@targetCommand @target4}
#ALIAS targetF5 {
#IF (%null(@target5)) {
#SAY {%crlf "No *CrossRaceName* has been captured for target5"}
} {
@targetCommand @target5
}
}
#ALIAS targetF6 {
#IF (%null(@target6)) {
#SAY {%crlf "No *CrossRaceName* has been captured for target6"}
} {
@targetCommand @target6
}
}
#ALIAS targetF7 {
#IF (%null(@target7)) {
#SAY {%crlf "No *CrossRaceName* has been captured for target7"}
} {
@targetCommand @target7
}
}
#ALIAS targetF8 {
#IF (%null(@target8)) {
#SAY {%crlf "No *CrossRaceName* has been captured for target8"}
} {
@targetCommand @target8
}
}
#ALIAS targetF9 {
#IF (%null(@target9)) {
#SAY {%crlf "No WANTED name has been captured for target9"}
} {
@targetCommand @target9
}
}
#ALIAS targetF10 {
#IF (%null(@target10)) {
#SAY {%crlf "No WANTED name has been captured for target10"}
} {
@targetCommand @target10
}
}
#ALIAS targetF11 {
#IF (%null(@target11)) {
#SAY {%crlf "No WANTED name has been captured for target11"}
} {
@targetCommand @target11
}
}
#ALIAS targetF12 {
#IF (%null(@target12)) {
#SAY {%crlf "No WANTED name has been captured for target12"}
} {
@targetCommand @target12
}
}
#ALIAS targetADD {@charADD}
#ALIAS targetDIV {@charDIV}
#ALIAS targetMULT {@charMULT}
#ALIAS targetSUB {@charSUB}
#ALIAS addTarget {
#IF (%null(%1)) {
#SAY {%crlf Usage: addTarget <type> <command>}
#SHOW {%lf Available types: action, weave}
} {
#IF (%proper(%1)=Action) {
#ADDITEM targetActionList {%-2}
#SAY {%crlf %-2 saved to target %lower(%1) commands.}
} {
#IF (%proper(%1)=Weave) {
#ADDITEM targetWeaveList {%-2}
#SAY {%crlf %-2 saved to target %lower(%1) commands.}
} {
#SAY {%crlf Invalid type! Types: action, weave}
}
}
}
}
#ALIAS listTarget {
#IF (%proper(%1)=Action OR %proper(%1)=Weave) {
#SAY {%crlf Current saved %lower(%1) commands:}
#FORALL %concat("@target",%1,List) {#SHOW {%lf %i}}
} {#SAY {%crlf Invalid type! Available types: action, weave}}
}
#ALIAS setTarget {
#IF (%null(%1)) {
#SAY {%crlf Usage: setTarget <command>}
} {
#VAR targetCommand {%-1}
#SAY {%crlf %-1 set as target command.}
}
}
#ALIAS subTarget {
#IF (%null(%1)) {
#SAY {%crlf Usage: subTarget <type> <command>}
#SHOW {%lf Available types: action, weave}
} {
#IF (%proper(%1)=Action) {
#IF (%ismember("%-2",@targetActionList)) {
#DELITEM targetActionList {%-2}
#SAY {%crlf %-2 deleted from target action commands.}
} {
#SAY {%crlf Invalid action, not found in list.}
}
} {
#IF (%proper(%1)=Weave) {
#IF (%ismember("%-2",@targetWeaveList)) {
#DELITEM targetWeaveList {%-2}
#SAY {%crlf %-2 deleted from target weave commands.}
} {
#SAY {%crlf Invalid weave, not found in list.}
}
} {
#SAY {%crlf Invalid type! Available types: action, weave}
}
}
}
}
#ALIAS targetCycleAction {
#IF (%numitems(@targetActionList)>%ismember(@targetAction,@targetActionList)) {
#VAR targetAction {%eval(%item(@targetActionList,%ismember(@targetAction,@targetActionList)+1))}
} {
#VAR targetAction {%item(@targetActionList,1)}
}
#VAR targetCommand {@targetAction}
#SAY %crlf Targets action command set to: @targetAction
}
#ALIAS targetCycleWeave {
#IF (%numitems(@targetWeaveList)>%ismember(@targetWeave,@targetWeaveList)) {
#VAR targetWeave {%eval(%item(@targetWeaveList,%ismember(@targetWeave,@targetWeaveList)+1))}
} {
#VAR targetWeave {%item(@targetWeaveList,1)}
}
#VAR targetCommand {%concat(channel," ","'",@targetWeave,"'")}
#SAY %crlf Targets channel command set to: @targetWeave
}
#VAR btnColorDS {red}
#VAR btnColorLS {dodgerblue}
#VAR btnColorW {darkorange}
#VAR btnList {ADD|DIV|F1|F2|F3|F4|F5|F6|F7|F8|F9|F10|F11|F12|MULT|SUB}
#VAR showButton1316 {1}
#VAR showButton14 {1}
#VAR showButton58 {1}
#VAR showButton912 {1}
#VAR target1 {1}
#VAR target10 {}
#VAR target11 {}
#VAR target12 {}
#VAR target2 {2}
#VAR target3 {3}
#VAR target4 {4}
#VAR target5 {}
#VAR target6 {}
#VAR target7 {}
#VAR target8 {}
#VAR target9 {}
#VAR targetAction {backstab}
#VAR targetActionList {backstab|bash|charge|kill}
#VAR targetCommand {kill}
#VAR targetCrossList {}
#VAR targetCycleCount {2}
#VAR targetPlayerName {} {}
#VAR targetWeave {blind}
#VAR targetWeaveList {blind|call lightning|ice spikes}
#TRIGGER "targetExitsTrigger" {^~[ obvious exits: *~]$} {
#T+ {targetPrompt}
#T+ {targetRoomDS}
#T+ {targetRoomLS}
#T+ {wantedRoomTarget}
#T+ {wantedRoomTrigger}
} "" {case}
#TRIGGER "targetDarkTrigger" {~*%e[31m([A-Z]%w)%e[0m~*} {
#IF (%ismember(%1,@targetCrossList)) {} {
#ADDITEM targetCrossList {%1}
#LOOP 5,8 {#CALL {%btncol(%concat(buttonF,%i),@btnColorDS)}}
#IF (%numitems(@targetCrossList)<5) {
#VAR %concat(target,%eval(%ismember(%1,@targetCrossList)+4)) {%1}
} {}
}
} "" {case|color}
#TRIGGER "targetHumanTrigger" {~*%e[36m([A-Z]%w)%e[0m~*} {
#IF (%ismember(%1,@targetCrossList)) {} {
#ADDITEM targetCrossList {%1}
#LOOP 5,8 {#CALL {%btncol(%concat(buttonF,%i),@btnColorLS)}}
#IF (%numitems(@targetCrossList)<5) {
#VAR %concat(target,%eval(%ismember(%1,@targetCrossList)+4)) {%1}
} {}
}
} "" {case|color}
#TRIGGER "targetRoomDS" {%e[33m~*%e[31m([A-Z]%w)%e[33m~*} {
#IF (%ismember(%1,@targetCrossList)) {} {
#ADDITEM targetCrossList {%1}
#LOOP 5,8 {#CALL {%btncol(%concat(buttonF,%i),@btnColorDS)}}
#IF (%numitems(@targetCrossList)<5) {
#VAR %concat(target,%eval(%ismember(%1,@targetCrossList)+4)) {%1}
} {}
}
} "" {case|color|disable}
#TRIGGER "targetRoomLS" {%e[33m~*%e[36m([A-Z]%w)%e[33m~*} {
#IF (%ismember(%1,@targetCrossList)) {} {
#ADDITEM targetCrossList {%1}
#LOOP 5,8 {#CALL {%btncol(%concat(buttonF,%i),@btnColorLS)}}
#IF (%numitems(@targetCrossList)<5) {
#VAR %concat(target,%eval(%ismember(%1,@targetCrossList)+4)) {%1}
} {}
}
} "" {case|color|disable}
#TRIGGER "targetPlayerNamePrompt" {^{o|*} * - ([A-Z]%w): ([A-Z]%w) >} {
#IF (%1=@targetPlayerName) {} {
#VAR targetPlayerName {%1}
#VAR target2 {%1}
}
#IF (%2=Critical) {#VAR target4 {%1}} {}
} "" {case|nocr|prompt}
#TRIGGER "targetPlayerAssistPrompt" {^{o|*} * - *: %w - ([A-Z]%w): ([A-Z]%w) >} {
#IF (%1=@targetPlayerName) {} {
#VAR targetPlayerName {%1}
#VAR target2 {%1}
}
#IF (%2=Critical) {#VAR target4 {%1}} {}
} "" {case|nocr|prompt}
#TRIGGER "targetPrompt" {^{o|*} * >} {
#IF (%class(wantedWhoTrigger)=1) {#VAR wantedList {%sort(@WantedList)}}
#T- {targetPrompt}
#T- {targetRoomDS}
#T- {targetRoomLS}
#T- {wantedRoomTarget}
#T- {wantedRoomTrigger}
#T- {wantedTavernTrigger}
#T- {wantedWhereTrigger}
#T- {wantedWhoTrigger}
#T- {wantedWhoManual}
#T- {wantedTavernManual}
} "" {case|disable|nocr|prompt}
#ONINPUT {^k &target4$} {kill @target4}
#KEY CTRL-F1 {tg1}
#KEY CTRL-F2 {#VAR target1 {@target2}}
#KEY CTRL-F3 {#VAR target1 {@target3}}
#KEY CTRL-F4 {#VAR target1 {@target4}}
#BUTTON {1} "@target1" {targetF1} {} {} {} {} {wotmud\Key16\F1Key16.bmp} {} {} {} {} {} {} {} {} {push} {} {Target} {} {F1} {buttonF1} {4}
#BUTTON {2} "@target2" {targetF2} {} {} {} {} {wotmud\Key16\F2Key16.bmp} {} {} {} {} {} {} {} {} {push} {} {Target} {} {F2} {buttonF2} {4}
#BUTTON {3} "@target3" {targetF3} {} {} {} {} {wotmud\Key16\F3Key16.bmp} {} {} {} {} {} {} {} {} {push} {} {Target} {} {F3} {buttonF3} {4}
#BUTTON {4} "@target4" {targetF4} {} {} {} {} {wotmud\Key16\F4Key16.bmp} {} {} {} {} {} {} {} {} {push} {} {Target} {} {F4} {buttonF4} {4}
#BUTTON {5} "@target5" {targetF5} {} {} {} {} {wotmud\Key16\F5Key16.bmp} {} {} {} {} {} {} {} {} {push} {} {Target} {} {F5} {buttonF5} {4}
#BUTTON {6} "@target6" {targetF6} {} {} {} {} {wotmud\Key16\F6Key16.bmp} {} {} {} {} {} {} {} {} {push} {} {Target} {} {F6} {buttonF6} {4}
#BUTTON {7} "@target7" {targetF7} {} {} {} {} {wotmud\Key16\F7Key16.bmp} {} {} {} {} {} {} {} {} {push} {} {Target} {} {F7} {buttonF7} {4}
#BUTTON {8} "@target8" {targetF8} {} {} {} {} {wotmud\Key16\F8Key16.bmp} {} {} {} {} {} {} {} {} {push} {} {Target} {} {F8} {buttonF8} {4}
#BUTTON {9} "@target9" {targetF9} {} {} {} {} {wotmud\Key16\F9Key16.bmp} {} {} {} {} {} {} {} {} {push} {} {Target} {} {F9} {buttonF9} {4}
#BUTTON {10} "@target10" {targetF10} {} {} {} {} {wotmud\Key16\F10Key16.bmp} {} {} {} {} {} {} {} {} {push} {} {Target} {} {F10} {buttonF10} {4}
#BUTTON {11} "@target11" {targetF11} {} {} {} {} {wotmud\Key16\F11Key16.bmp} {} {} {} {} {} {} {} {} {push} {} {Target} {} {F11} {buttonF11} {4}
#BUTTON {12} "@target12" {targetF12} {} {} {} {} {wotmud\Key16\F12Key16.bmp} {} {} {} {} {} {} {} {} {push} {} {Target} {} {F12} {buttonF12} {4}
#BUTTON {13} "@charDIV" {targetDIV} {} {} {} {} {wotmud\Key16\DIVKey16.bmp} {} {} {} {} {} {} {} {} {push} {} {Target} {} {DIV} {buttonDIV} {4}
#BUTTON {14} "@charMULT" {targetMULT} {} {} {} {} {wotmud\Key16\MULTKey16.bmp} {} {} {} {} {} {} {} {} {push} {} {Target} {} {MULT} {buttonMULT} {4}
#BUTTON {15} "@charSUB" {targetSUB} {} {} {} {} {wotmud\Key16\SUBKey16.bmp} {} {} {} {} {} {} {} {} {push} {} {Target} {} {SUB} {buttonSUB} {4}
#BUTTON {16} "@charADD" {targetADD} {} {} {} {} {wotmud\Key16\ADDKey16.bmp} {} {} {} {} {} {} {} {} {push} {} {Target} {} {ADD} {buttonADD} {4}
#CLASS 0
#CLASS {Target|WANTED}
#ALIAS addWanted {
#IF (%null(%1)) {
#SAY {%crlf Usage: addWanted <name>}
} {
#IF (%ismember(%proper(%1),%eval(%concat("@",%char,WantedList)))) {
#SAY {%crlf %proper(%1) is already set as a WANTED.}
} {
#ADDITEM %concat(%char,WantedList) {%proper(%1)}
#ADDITEM WantedList {%proper(%1)}
#SAY {%crlf %proper(%1) saved to %char"'s WANTED list."}
}
}
}
#ALIAS listWanted {
#SAY {%crlf %char"'s WANTED list:"}
#IF (%null(%concat("@",%char,WantedList))) {
#SHOW {No names found, addWanted <name> to populate list.}
} {
#FORALL %eval(%concat("@",%char,WantedList)) {#SHOW {" " <color @wantedColor>%i</color>}}
}
}
#ALIAS subWanted {
#IF (%null(%1)) {
#SAY {%crlf Usage: subWanted <name> %crlf}
} {
#IF (%ismember(%proper(%1),%eval(%concat("@",%char,WantedList)))) {
#DELITEM %concat(%char,WantedList) {%proper(%1)}
#DELITEM WantedList {%proper(%1)}
#SAY {%crlf %proper(%1) deleted from %char"'s WANTED List."}
} {
#SAY {%crlf Invalid name, not found in list.}
}
}
}
#ALIAS colorWanted {
#IF (%null(%1)) {
#SHOW {""}
#SAY {" Usage: colorWanted <color> [bcolor] [background color optional]"}
#SHOW {" Current WANTED color: " @wantedMXPcolor(@wantedColor)}
#SHOW {""}
} {
#IF (%colorname(%1)=536870911 AND %color(%1)=0) {
#VAR wantedColor {}
#SAY {" "%1 is an invalid color. Scan color variable cleared.}
} {
#IF (%null(%2)) {
#VAR wantedColor {%1}
#SHOW {%crlf WANTED color set: @wantedMXPcolor(%1)}
} {
#IF (%colorname(%2)=536870911 AND %color(%2)=0) {
#VAR wantedColor {}
#SAY {" "%2 is an invalid color. WANTED color variable cleared.}
} {
#VAR wantedColor {%concat(%1,",",%2)}
#SHOW {%crlf WANTED color set: @wantedMXPcolor(%2 %3)}
}
}
}
}
}
#FUNCTION wantedMXPcolor {<color %1>%1</color>}
#VAR wantedColor {darkorange}
#VAR wantedList {}
#VAR wantedButtonList {}
#VAR wantedMaster {General|Lady|Lord}
#TRIGGER "wantedArrivesTrigger" {([A-Z]%w) has arrived from *.$} {
#IF (%ismember(%1,@wantedList)) {
#PCOL {@wantedColor} %x1
#VAR target3 {%1}
} {}
} "" {case}
#TRIGGER "wantedSuddenlyTrigger" {([A-Z]%w) has suddenly arrived.$} {
#IF (%ismember(%1,@wantedList)) {
#PCOL {@wantedColor} %x1
#VAR target3 {%1}
} {}
} "" {case}
#TRIGGER "wantedFleesTrigger" {([A-Z]%w) panics, and attempts to flee!$} {
#IF (%ismember(%1,@wantedList)) {
#PCOL {@wantedColor} %x1
#VAR target3 {%1}
} {}
} "" {case}
#TRIGGER "wantedLeavesTrigger" {([A-Z]%w) leaves *.$} {
#IF (%ismember(%1,@wantedList)) {
#PCOL {@wantedColor} %x1
#VAR target3 {%1}
} {}
} "" {case}
#TRIGGER "wantedRoomTarget" {^([A-Z]%w) (%x)(*)$} {
#IF (%ismember(%1,@wantedList)) {
#VAR target3 {%1}
#T- {wantedRoomTarget}
} {
#IF (%ismember(%1,@wantedMaster)) {
#IF (%ismember(%2,@wantedList)) {
#VAR target3 {%1}
#T- {wantedRoomTarget}
}
}
}
} "" {case|disable}
#TRIGGER "wantedRoomTrigger" {^([A-Z]%w) (%x)(*)$} {
#IF (%ismember(%1,@wantedList)) {
#PCOL {@wantedColor} %x1
#IF (%ismember(%1,@wantedButtonList)) {} {
#ADDITEM wantedButtonList {%1}
#IF (%numitems(@wantedButtonList)<5) {
#VAR %concat(target,%eval(%ismember(%1,@wantedButtonList)+8)) {%1}
#CALL {%btncol(%concat(buttonF,%eval(%ismember(%1,@wantedButtonList)+8)),@btnColorW)}
} {}
}
} {
#IF (%ismember(%2,@wantedList)) {
#PCOL {@wantedColor} %x2
#IF (%ismember(%2,@wantedButtonList)) {} {
#ADDITEM wantedButtonList {%1}
#IF (%numitems(@wantedButtonList)<5) {
#VAR %concat(target,%eval(%ismember(%1,@wantedButtonList)+8)) {%1}
#CALL {%btncol(%concat(buttonF,%eval(%ismember(%1,@wantedButtonList)+8)),@btnColorW)}
} {}
}
} {}
}
} "" {case|disable}
#TRIGGER "wantedWhereTrigger" {^([A-Z]%w)%s- *$} {
#IF (%ismember(%1,@wantedList)) {
#PCOL {@wantedColor} %x1
#IF (%ismember(%1,@wantedButtonList)) {} {
#ADDITEM wantedButtonList {%1}
#IF (%numitems(@wantedButtonList)<5) {
#VAR %concat(target,%eval(%ismember(%1,@wantedButtonList)+8)) {%1}
#CALL {%btncol(%concat(buttonF,%eval(%ismember(%1,@wantedButtonList)+8)),@btnColorW)}
} {}
}
} {}
} "" {case|disable}
#TRIGGER "wantedWhoTrigger" {^%s([A-Z]%w) (*) (WANTED)$} {
#IF (%ismember(%1,@wantedMaster)) {
#ADDITEM wantedList {%word("%2",1)}
} {
#ADDITEM wantedList {%1}
}
#PCOL {@wantedColor} %x3
} "" {case|disable}
#TRIGGER "wantedTavernTrigger" {^%d%s([A-Z]%w) (*) (WANTED)$} {
#IF (%ismember(%1,@wantedMaster)) {
#ADDITEM wantedList {%word("%2",1)}
} {
#ADDITEM wantedList {%1}
}
#PCOL {@wantedColor} %x3
} "" {case|disable}
#TRIGGER "wantedWhoManual" {^%s([A-Z]%w) (%x)(*)$} {
#IF (%ismember(%1,%eval(%concat("@",%char,WantedList)))) {
#PCOL {@wantedColor} %x1
} {
#IF (%ismember(%1,@wantedMaster)) {
#IF (%ismember(%2,%eval(%concat("@",%char,WantedList)))) {
#PCOL {@wantedColor} %x2
}
}
}
} "" {case|disable}
#TRIGGER "wantedTavernManual" {^%d%s([A-Z]%w) (%x)(*)$} {
#IF (%ismember(%1,%eval(%concat("@",%char,WantedList)))) {
#PCOL {@wantedColor} %x1
} {
#IF (%ismember(%1,@wantedMaster)) {
#IF (%ismember(%2,%eval(%concat("@",%char,WantedList)))) {
#PCOL {@wantedColor} %x2
}
}
}
} "" {case|disable}
#TRIGGER "wantedPlayers" {Players} {
#T- {wantedPlayers}
#T+ {targetPrompt}
#VAR wantedList {%eval(%concat("@",%char,WantedList))}
} "" {case|disable|verbatim}
#TRIGGER "wantedPlayersZone" {Players in your Zone} {
#T- {wantedPlayersZone}
#T+ {targetPrompt}
} "" {case|disable|verbatim}
#ONINPUT "wantedWhereInput" {^{whe|wher|where}$} {
#T+ {wantedPlayersZone}
#T+ {wantedWhereTrigger}
}
#ONINPUT "wantedWhoInput" {^{wh|who}$} {
#T+ {wantedPlayers}
#T+ {wantedWhoManual}
#T+ {wantedTavernManual}
#T+ {wantedWhoTrigger}
#T+ {wantedTavernTrigger}
}
#CLASS 0
#CLASS {Target|TargetConnect} {enable}
#TRIGGER "targetConnectTrigger" {%s The Wheel Of Time MUD} {
#T+ {targetDarkTrigger}
#T+ {targetHumanTrigger}
#IF (%class(Target|WANTED|%concat(%char,Wanted))=-1) {
#CLASS {Target|WANTED|%concat(%char,Wanted)} {disable}
#VAR %concat(%char,WantedList) {} {_nodef}
#CLASS 0
} {
#T+ {Target|WANTED|%concat(%char,Wanted)}
#VAR wantedList {%eval(%concat("@",%char,WantedList))}
}
#IF (%class(Characters)=-1) {} {
#T- {Target|TargetConnect}
#VAR charF1 {targetF1}
#VAR charF10 {targetF10}
#VAR charF11 {targetF11}
#VAR charF12 {targetF12}
#VAR charF2 {targetF2}
#VAR charF3 {targetF3}
#VAR charF4 {targetF4}
#VAR charF5 {targetF5}
#VAR charF6 {targetF6}
#VAR charF7 {targetF7}
#VAR charF8 {targetF8}
#VAR charF9 {targetF9}
}
} "" {case}
#KEY F1 {targetF1}
#KEY F10 {targetF10}
#KEY F11 {targetF11}
#KEY F12 {targetF12}
#KEY F2 {targetF2}
#KEY F3 {targetF3}
#KEY F4 {targetF4}
#KEY F5 {targetF5}
#KEY F6 {targetF6}
#KEY F7 {targetF7}
#KEY F8 {targetF8}
#KEY F9 {targetF9}
#CLASS 0
